AoC 2025 day 3 (dc)

# Command: dc -e$NUM_BATTERIES -fdc-p1.dc <input

sb                          # b = num batteries (passed in)
[+q]sQ

0 ?                         # bank sum
[
    # Initialize array
    0Sa                     # clear array

    1                       # i = 1
    [
        d3R A~              # last bank i i
        3R:a                # arr(i) = last; bank i
        r1+ dlb!<L          # i++, loop until i == num
    ] dsLx s.

    # Process bank, getting best batteries
    [
        A~                  # last_jolts rest sum

        lb                  # i=num jolts ...
        [
            d3R             # jolts i i
            r;a d3Rd        # jolts jolts arr(i) arr(i) i
            3R>Q            # quit if jolts<arr(i); jolts arr(i) i

            3R d3R r:a      # arr(i) = jolts; i jolts=old arr(i)

            1- d0<I
        ] dsIx +s.

        d0<B
    ] dsBx                  # 0 ans

    # Calculate total joltage in array
    lb                      # i=num jolts sum
    [
        d;a 3RA*+           # jolts=10*jolts+arr(i) i sum
        r1- d0<I
    ] dsIx ++               # sum += jolts + 0 (as i=0)

    ? z1<M
] dsMx

p                           # print sum