guild_vs4	mapflag	loadevent

-	script	KoE	-1,{
OnInit:
	disablenpc "Exit#KoE";
	donpcevent "::OnRevKoE";
	end;

OnPCLoadMapEvent:
if( !.koe_start && strharinfo(3) == "guild_vs4" ){
	mes "You cant enter/teleport/warp in this map after KoE end.";
	close2;
	warp "SavePoint",0,0;
}
end;

OnWhisperGlobal:
	if( getgmlevel() < 99 ) end;
	else if( compare( @whispervar0$,"on" ) ) goto L_start;
	else if( compare( @whispervar0$,"off" ) ) goto L_end;
	else if( compare( @whispervar0$,"reset" ) ) goto OnGuildBreak;
	else end;

OnTreasureBox:
	setarray .@X[0],159,154,154,159;
	setarray .@Y[0],135,135,130,130;
	killmonsterall "payg_cas05";
	for( set .@i,0; .@i < getarraysize( .@X ); set .@i,.@i + 1 )
		monster "payg_cas05",.@X[.@i],.@Y[.@i],"--ja--",1903,1,"";
	end;

L_start:
OnMon1700:
OnTue1700:
OnWed1700:
OnThu1700:
OnFri1700:
OnSat1700:
	if( !.koe_start ){
		koe_toggle(1);
		set .@Min,rand( 30,45 );
		announce "The King of Emperium - "+getcastlename("guild_vs4")+" has begun!",bc_all,0xFFCCFF;
		set .koe_start, 1;
		atcommand "@skillon";
		disablenpc "Exit#KoE";
		// setcastledata "guild_vs4",1,0;
		donpcevent "::OnRevKoE";
		maprespawnguildid "guild_vs4",getcastledata( "guild_vs4",1 ), 6;
		monster "guild_vs4",50,50,"Emperium",1288,1,strnpcinfo(0)+"::OnEmpDead";

		sleep ( .@Min * 60000 );
		koe_toggle(0);
		donpcevent
		strnpcinfo(0)+"::OnTreasureBox";
		announce "The King of Emperium is over!",bc_all,0xFFCCFF;
		set .koe_start, 0;
		atcommand "@skilloff";
		killmonsterall "guild_vs4";
		enablenpc "Exit#KoE";
		sleep 3000;
		mapannounce "guild_vs4","You got 1 minute to claim the prize.",bc_map,0xFFCCFF;
		sleep 57000;
		disablenpc "Exit#KoE";
		maprespawnguildid "guild_vs4",getcastledata( "guild_vs4",1 ), 3;
	}
	end;

OnEmpDead:
	setcastledata "guild_vs4",1,getcharid(2);
	donpcevent "::OnRevKoE";
	announce "The current King of Emperium is the [ "+strcharinfo(2)+" ] guild.",bc_all,0xFFCCFF;
	maprespawnguildid "guild_vs4",getcastledata( "guild_vs4",1 ), 6;
	if( .koe_start ){
		sleep 2000;
		// mapwarp "guild_vs4","guild_vs4",50,50;
		monster "guild_vs4",50,50,"Emperium",1288,1,strnpcinfo(0)+"::OnEmpDead";
	}
	end;

L_end:
	if( .koe_start )
		awake strnpcinfo(0);
	end;

OnGuildBreak:
	setcastledata "guild_vs4",1,0;
	donpcevent "::OnRevKoE";
	announce "KOE Ownership removed.",bc_all,0xFFCCFF;
	if( mobcount("guild_vs4",strnpcinfo(0)+"::OnEmpDead") ){
		killmonsterall "guild_vs4";
		monster "guild_vs4",50,50,"Emperium",1288,1,strnpcinfo(0)+"::OnEmpDead";
	}
	end;
}

// KoE Entrance + Treasure Room
volterra,112,148,4	script	King of Emperium#Warp	722,{
    mes "[The King]";
	if( !getcharid(2) ){
		mes "You must have a guild to participate in the ^FF0000King of Emperium Tournament^000000.";
		close;
	}
    mes "Hello.";
    mes "Would you like to participate in the ^FF0000King of Emperium Tournament^000000?";
	if( !getvariableofnpc( .koe_start,"KoE" ) && getcharid(0) != getguildmasterid( getcastledata( "guild_vs4",1 ) )){
		mes "But there is no KOE right now.";
		close;
	}
	switch( select( (( getvariableofnpc( .koe_start,"KoE" ) )?"Participate":"" ),( !getvariableofnpc( .koe_start,"KoE" ) && getcharid(0) == getguildmasterid( getcastledata( "guild_vs4",1 ) )?"Treasure Room":"" ) )){
		Case 1:
			setarray .@X[0],49,50,50,7;
			setarray .@Y[0],92,92,7,49;
			set .@Random,rand( getarraysize(.@X) );
			warp "guild_vs4",.@X[.@Random],.@Y[.@Random];
			end;
		Case 2:
			warp "payg_cas05",153,136;
			end;
		default: close;
	}
OnRevKoE:
	flagemblem getcastledata( "guild_vs4",1 );
	end;
}

// KoE Exit + Reward
guild_vs4,49,56,5	script	Exit#KoE	51,{
	mes "[Exit]";
	mes "See ya.";
	if( getcharid(2) == getcastledata( "guild_vs4",1 ) ){
		getitem 20103, 10; // configure prize here
		getitem 25020, 2; // configure prize here
		set #CASHPOINTS, #CASHPOINTS + 50; // configure cash here
		message strcharinfo(0),"You'll receive 10 Event Coins, 2 Event Box and 50 Cash Points!";
	}
	next;
	warp "Save",0,0;
	close;
}

// Flags
-	script	koe_flag	-1,{
	set .@gid, getcastledata( "guild_vs4",1 );
	if( .@gid == 0 ) end;
	mes "[King of Emperium]";
	mes "The Current King of Emperium is the [ ^0055FF"+ getguildname(.@gid) +"^000000 ] guild.";
	close;

OnRevKoE:
	flagemblem getcastledata( "guild_vs4",1 );
	end;
}


// Duplicated Flags
guild_vs4,4,50,6	duplicate(koe_flag)	King of Emperium#1	722
guild_vs4,95,50,2	duplicate(koe_flag)	King of Emperium#2	722
guild_vs4,49,95,4	duplicate(koe_flag)	King of Emperium#3	722
guild_vs4,49,4,0	duplicate(koe_flag)	King of Emperium#4	722


// Mapflags
guild_vs4	mapflag	gvg
guild_vs4	mapflag	nobranch
guild_vs4	mapflag	nomemo
guild_vs4	mapflag	nopenalty
guild_vs4	mapflag	noreturn
guild_vs4	mapflag	nosave	SavePoint
guild_vs4	mapflag	noteleport
guild_vs4	mapflag	gvg_noparty
guild_vs4	mapflag	nowarp
guild_vs4	mapflag	nowarpto
guild_vs4	mapflag	gvg_castle

payg_cas05,161,136,0	script	KoE#Exit	111,{
	mes " ";
	mes "There's a small lever. Will you pull it? ";
	next;
	if(select("Pull.:Do not.") == 2) close;
	warp "prontera",155,185;
	end;
}