with import <nixpkgs> {};
# { stdenv, dpkg, makeWrapper, buildFHSUserEnvBubblewrap, makeDesktopItem
# , alsaLib, dbus, expat, fontconfig, glib, libglvnd, libpulseaudio
# , libudev0-shim, libxkbcommon, libxml2, libxslt, nspr, nss
# , xlibs
# }:

let
  version = "8.0";

  ptFiles = stdenv.mkDerivation {
    name = "PacketTracer";
    inherit version;

    src = ./PacketTracer_800_amd64_build212_final.deb;

    nativeBuildInputs = [ dpkg makeWrapper ];

    dontUnpack = true;
    installPhase = ''
      dpkg-deb -x $src $out
      makeWrapper "$out/opt/pt/bin/PacketTracer" "$out/bin/packettracer" \
          --prefix LD_LIBRARY_PATH : "$out/opt/pt/bin"
    '';
  };

  desktopItem = makeDesktopItem {
    name = "cisco-pt.desktop";
    desktopName = "Packet Tracer";
    icon = "${ptFiles}/opt/pt/art/app.png";
    exec = "packettracer %f";
    mimeType = "application/x-pkt;application/x-pka;application/x-pkz;";
  };

in buildFHSUserEnvBubblewrap {
  name = "packettracer";
  unshareNet = true;
  runScript = "${ptFiles}/bin/packettracer";
  extraInstallCommands = ''
    mkdir -p "$out/share/applications"
    cp "${desktopItem}"/share/applications/* "$out/share/applications/"
  '';

  targetPkgs = pkgs: [
    alsaLib dbus expat fontconfig glib libglvnd libpulseaudio
    libudev0-shim libxkbcommon libxml2 libxslt nspr nss
    xlibs.libICE xlibs.libSM xlibs.libX11 xlibs.libXScrnSaver
  ];
}