if listexists 'Dist'
  if not listexists 'Targets'
    createlist 'Targets'
  else
    @clearlist 'Targets'
  endif
  if not listexists 'Queue'
    createlist 'Queue'
  else
    @clearlist 'Queue'
  endif
  if not listexists 'Players'
    createlist 'Players'
  else
    @clearlist 'Players'
  endif
  while @getenemy 'murderer' 'criminal' 'grey' 'humanoid' 'transformation' 'next'
    //'innocent'
    if not @inrange 'enemy' 18
      break
    endif
    @setalias 'current' 'enemy'
    if @inlist 'Players' 'current'
      break
    endif
    if @inparty 'current' or @infriendlist 'current'
      pushlist 'Players' 'current'
      continue
    endif
    if @name 'current' == 'Barracoon'
      pushlist 'Players' 'current'
      continue
    endif
    waitforproperties 'current' 500
    if property 'The Priest Of Mondain' 'current' or property 'The Wandering Healer' 'current'
      pushlist 'Players' 'current'
      continue
    endif
    //==HP==:
    if @diffhits 'current' > 0
      if list 'Queue' > 0
        if @diffhits 'current' > diffhits Queue[0]
          pushlist 'Queue' 'current' 'front'
        endif
      else
        pushlist 'Queue' 'current' 'front'
      endif
    endif
    //======
    if yellowhits 'current'
      headmsg "Yellowhits" 42 'current'
    endif
    if paralyzed 'current'
      headmsg "Paralyzed" 85 'current'
    endif
    pushlist 'Targets' 'current'
    pushlist 'Players' 'current'
  endwhile
  if list 'Queue' > 0
    @setalias 'enemy' Queue[0]
    @setalias 'last' Queue[0]
    headmsg "Low HP Enemy" 33 'enemy'
  else
    if list 'Targets' > 0
      for 0 to 'Dist'
        for 0 to 'Targets'
          if @findobject Targets[] 'any' 'ground' 0 Dist[]
            @setalias 'enemy' 'found'
            @setalias 'last' 'found'
            headmsg "Closest Enemy" 33 'found'
            stop
          endif
        endfor
      endfor
    else
      headmsg "No Enemy" 33 'self'
    endif
  endif
else
  if not listexists 'Dist'
    createlist 'Dist'
    pushlist 'Dist' 0
    pushlist 'Dist' 1
    pushlist 'Dist' 2
    pushlist 'Dist' 3
    pushlist 'Dist' 4
    pushlist 'Dist' 5
    pushlist 'Dist' 6
    pushlist 'Dist' 7
    pushlist 'Dist' 8
    pushlist 'Dist' 9
    pushlist 'Dist' 10
    pushlist 'Dist' 11
    pushlist 'Dist' 12
    pushlist 'Dist' 13
    pushlist 'Dist' 14
    pushlist 'Dist' 15
    pushlist 'Dist' 16
    pushlist 'Dist' 17
    pushlist 'Dist' 18
  endif
  replay
endif