PBR
{
    import "Lights.lesl"

    uniforms
    {
        // Camera
        mat4 model;
        mat4 view;
        mat4 projection;
        vec3 camPos;

        // Material
        vec3 albedo;
        float metallic;
        float roughness;
        float ao;
        float alpha;

        // Lights
        vec3 lightPositions[4];
        vec3 lightColors[4];
    }

    vertex
    {
        inputs
        {

        }

        outputs
        {
            vec3 Normal;
            vec3 WorldPosition;
            vec2 UV;
        }

        process
        {
            void main()
            {
                Normal = normalize((model * vec4(aNormal, 0.0)).xyz);
                WorldPosition = (model * vec4(aPos, 1.0)).xyz;
                UV = aTexCoords;
                gl_Position = projection * view * model * vec4(aPos, 1.0);
            }
        }
    }

    fragment
    {
        inputs
        {
            vec3 Normal;
            vec3 WorldPosition;
            vec2 UV;
        }

        outputs
        {
            vec4 outColor;
        }

        process
        {
            const float PI = 3.14159265359;

            float DistributionGGX(vec3 N, vec3 H, float roughness)
            {
                float a = roughness * roughness;
                float a2 = a * a;
                float NdotH = max(dot(N, H), 0.0);
                float NdotH2 = NdotH * NdotH;

                float nom = a2;
                float denom = (NdotH2 * (a2 - 1.0) + 1.0);
                denom = PI * denom * denom;

                return nom / denom;
            }

            float GeometrySchlickGGX(float NdotV, float roughness)
            {
                float r = (roughness + 1.0);
                float k = (r * r) / 8.0;
                float nom = NdotV;
                float denom = NdotV * (1.0 - k) + k;

                return nom / denom;
            }

            float GeometrySmith(vec3 N, vec3 V, vec3 L, float roughness)
            {
                float NdotV = max(dot(N, V), 0.0);
                float NdotL = max(dot(N, L), 0.0);
                float ggx2 = GeometrySchlickGGX(NdotV, roughness);
                float ggx1 = GeometrySchlickGGX(NdotL, roughness);

                return ggx1 * ggx2;
            }

            vec3 fresnelSchlick(float cosTheta, vec3 F0)
            {
                return F0 + (1.0 - F0) * pow(clamp(1.0 - cosTheta, 0.0, 1.0), 5.0);
            }

            void main()
            {
                vec3 N = normalize(Normal);
                vec3 V = normalize(camPos - WorldPosition);

                vec3 F0 = vec3(0.04);
                F0 = mix(F0, albedo, metallic);

                vec3 Lo = vec3(0.0);

                for(int i = 0; i < 4; i++)
                {
                    vec3 L = normalize(lightPositions[i] - WorldPosition);
                    vec3 H = normalize(V + L);
                    float distance = length(lightPositions[i] - WorldPosition);
                    float attenuation = 1.0 / (distance * distance);
                    vec3 radiance = lightColors[i] * attenuation;

                    // Cook-Torrance BRDF
                    float NDF = DistributionGGX(N, H, roughness);
                    float G = GeometrySmith(N, V, L, roughness);
                    vec3 F = fresnelSchlick(max(dot(H, V), 0.0), F0);

                    vec3 numerator = NDF * G * F;
                    float denominator = 4.0 * max(dot(N, V), 0.0) * max(dot(N, L), 0.0) + 0.001;
                    vec3 specular = numerator / denominator;

                    vec3 kS = F;
                    vec3 kD = vec3(1.0) - kS;
                    kD *= 1.0 - metallic;

                    float NdotL = max(dot(N, L), 0.0);
                    Lo += (kD * albedo / PI + specular) * radiance * NdotL;
                }

                vec3 ambient = vec3(0.03) * albedo * ao;
                vec3 color = ambient + Lo;

                // HDR tonemapping e gamma correction
                color = color / (color + vec3(1.0));
                color = pow(color, vec3(1.0/2.2));

                Light light;
                light.color = vec3(1.0);
                light.position = lightPositions[0];
                light.intensity = 1.0;

                outColor = vec4(ProcessLights(color, Normal, WorldPosition, light), alpha);
            }
        }
    }
}