2D shader for sprite coloring by mask

Shader "Custom/Sprite Colored mask"
{
    Properties
    {
        [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
        [PerRendererData] _MainTexCut ("CutOff", 2D) = "white" {}
        _Color ("Tint", Color) = (1,1,1,1)
        [MaterialToggle] PixelSnap ("Pixel snap", Float) = 0

    _ColorMaskTex ("Color mask texture", 2D) = "white" {}
    _MainColor ("Main color (red)", Color) = (1,0,0,0)
    _AddColor ("Additional 1st color (green)", Color) = (0,1,0,0)
    _ExtColor ("Additional 2nd color (blue)", Color) = (0,0,1,0)

    }

    SubShader
    {
        Tags
        {
            "Queue"="Transparent"
            "IgnoreProjector"="True"
            "RenderType"="Transparent"
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }

        Cull Off
        Lighting Off
        ZWrite Off
        Fog { Mode Off }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {
        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile DUMMY PIXELSNAP_ON
            #include "UnityCG.cginc"

            struct appdata_t
            {
                float4 vertex   : POSITION;
                float4 color    : COLOR;
                float2 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex   : SV_POSITION;
                fixed4 color    : COLOR;
                half2 texcoord  : TEXCOORD0;
            };

            fixed4 _Color;

            v2f vert(appdata_t IN)
            {
                v2f OUT;
                OUT.vertex = UnityObjectToClipPos(IN.vertex);
                OUT.texcoord = IN.texcoord;
                OUT.color = IN.color * _Color;
                #ifdef PIXELSNAP_ON
                OUT.vertex = UnityPixelSnap (OUT.vertex);
                #endif

                return OUT;
            }

            sampler2D _MainTex;
            float4 _MainTex_ST;

            sampler2D _ColorMaskTex;
            float4 _MainColor;
            float4 _AddColor;
            float4 _ExtColor;

            fixed4 frag(v2f IN) : COLOR
            {
                float4 MainTex = tex2D(_MainTex, IN.texcoord) * IN.color;
                fixed4 SkinTex = tex2D(_ColorMaskTex, IN.texcoord);
                float4 res = float4(MainTex.rgb * (1 - SkinTex.r - SkinTex.g - SkinTex.b) +
                    lerp (MainTex.rgb, _MainColor.rgb, _MainColor.a * SkinTex.a) * SkinTex.r +
                    lerp (MainTex.rgb, _AddColor.rgb, _AddColor.a * SkinTex.a) * SkinTex.g +
                    lerp (MainTex.rgb, _ExtColor.rgb, _ExtColor.a * SkinTex.a) * SkinTex.b,
                    MainTex.a);
                res.a = MainTex.a;
                return res;
            }
        ENDCG
        }
    }
}