reeh_JahScript Across Three ESPs

Improved Followers.esp:
Begin reeh_jahScript

	short nolore
	float myx
	float myy
	float myz
	float warpTimer
	short p_speed
	short OnPCHitMe
	short flyCheck

	if ( GetJournalIndex "MV_RunawaySlave"	< 10 )
		return
	endif

	if ( GetJournalIndex "MV_RunawaySlave" >= 105 )
		return
	endif

	if ( GetDisabled == 1 )
		return
	endif

	if ( GetJournalIndex "MV_RunawaySlave" >= 105 )
		if ( CellChanged == 1 )
			disable "reeh_jah"
		endif
	endif

	if ( OnDeath == 1 )
		Journal "MV_RunawaySlave" 90
	endif

	if ( GetCurrentAiPackage == 3 )

		if (OnPCHitMe == 1)
			StopCombat
			set OnPCHitMe to 0
			Say "Vo\a\m\Flw_AM002.mp3" "Careful with that, friend."
		endif

		set p_speed to ( ( Player->GetSpeed ) + 85 )
		SetSpeed, p_speed

		if ( GetWeaponDrawn )
		elseif ( GetSpellReadied )
			return
		elseif ( GetDistance Player > 800 )
			set warpTimer to warpTimer + GetSecondsPassed
			if ( warpTimer > 10 )
				set warpTimer to 0
				set myx to ( Player->GetPos x )
				set myy to ( Player->GetPos y )
				set myz to ( Player->GetPos z )
				SetPos x myx
				SetPos y myy
				SetPos z myz
			endif
		endif

		if ( Player->GetEffect sEffectLevitate == 1 )
			if ( flyCheck == 0 )
				cast pbo_comp_lev player; levitate self 0 0 0 spells
				addspell pbo_comp_lev2; levitate ability 35-200
				set flyCheck to 1
			endif
		else
			if ( flyCheck == 1 )
				removespell pbo_comp_lev2
				set flyCheck to 0
			endif
		endif

		if ( flyCheck == 1 )
			if ( GetWeaponDrawn == 0 )
				set myz to ( Player->GetPos z )
				SetPos z myz
			endif
		endif

		if ( GetJournalIndex "MV_RunawaySlave" >= 20 )
			if ( GetJournalIndex "MV_RunawaySlave" < 90 )

				if ( GetDistance "Im_Kilaya" <= 512 )
					Journal "MV_RunawaySlave" 97
					setSpeed 55
				endif

				if (GetDistance "Savile Imayn" <=512 )
					Journal "MV_RunawaySlave" 103
					setSpeed 55
				endif

			endif
		endif
	else
		setSpeed 55
		return
	endif

end
-----
gr_ScriptImprovements.esp:
Begin reeh_jahScript
;better death checking
;makes sure he stops following you at end of quest
;makes sure he starts following in the first place
;improved his reaction based on who you take him to

short nolore
short isdead

if ( isdead == 1 )
	if ( OnActivate == 1 )
		if ( GetDeadCount reeh_jah == 0 )
			return
		else
			activate
		endif
	endif
	return
endif

if ( GetJournalIndex "MV_RunawaySlave" < 20 )
	return
endif

if ( gethealth <= 1 )
	sethealth 0
	Journal "MV_RunawaySlave" 90
	set isdead to 1
	return
elseif ( OnDeath == 1 )
	Journal "MV_RunawaySlave" 90
	set isdead to 1
	return
endif

if ( MenuMode == 1 )
	return
endif

if ( GetDisabled == 1 )
	setdelete 1
	return
endif

if ( GetJournalIndex "MV_RunawaySlave" >= 105 )
	if ( CellChanged == 1 )
		disable
	endif
	return
endif

if ( GetJournalIndex "MV_RunawaySlave" >= 30 )
	if ( GetJournalIndex "MV_RunawaySlave" < 36 )
		if ( GetCurrentAiPackage != 3 )
			AiFollow player 0 0 0 0
		endif
	endif
endif

if ( GetCurrentAiPackage != 3 )
	return
endif

if ( GetJournalIndex "MV_RunawaySlave" < 90 )
	if ( GetDistance "Im_Kilaya" <= 512 )
		moddisposition 25
		say "vo\a\m\Flw_AM003.mp3" "Thank you."
		Journal "MV_RunawaySlave" 97
		AiWander 384 5 0 0 60 20 10 10 0 0 0 0
	endif
	if ( GetDistance "Savile Imayn" <= 512 )
		moddisposition -50
		Journal "MV_RunawaySlave" 103
		AiWander 0 0 0 0 0 0 0 0 0 0 0 0
		ForceSneak
	endif
endif

end
-----
gr_Keys (Daduke compatible):
Begin reeh_jahScript

short nolore
short button
short doOnce
short isdead

if ( isdead == 1 )
	if ( OnActivate == 1 )
		if ( GetDeadCount reeh_jah == 0 )
			return
		else
			activate
		endif
	endif
	return
endif

if ( GetJournalIndex "MV_RunawaySlave" < 20 )
	return
endif

if ( gethealth <= 1 )
	sethealth 0
	Journal "MV_RunawaySlave" 90
	set isdead to 1
	return
elseif ( OnDeath == 1 )
	Journal "MV_RunawaySlave" 90
	set isdead to 1
	return
endif

if ( MenuMode == 1 )
	return
endif

if ( GetDisabled == 1 )
	setdelete 1
	return
endif

if ( GetJournalIndex "MV_RunawaySlave" >= 105 )
	if ( CellChanged == 1 )
		disable
	endif
	return
endif

if ( GetJournalIndex "MV_RunawaySlave" >= 30 )
	if ( GetJournalIndex "MV_RunawaySlave" < 36 )
		if ( GetCurrentAiPackage != 3 )
			AiFollow player 0 0 0 0
		endif
	endif
endif

if ( GetJournalIndex "MV_RunawaySlave" < 103 )
	if ( doOnce == 0 )
		if ( getdistance player <= 256 )
			if ( player->getitemcount key_tel_aruhn_slave1 > 0 )
				messagebox "You have the key to Reeh-Jah's slave bracer. Do you wish to remove the bracer?" "Yes" "No"
				set doOnce to 1
			endif
		endif
	endif
	if ( doOnce == 1 )
		set button to GetButtonPressed
		if ( button == -1 )
			return
		elseif ( button == 0 )
			drop slave_bracer_left 1
			moddisposition 25
			say "vo\a\m\Hlo_AM135.mp3" "Blessed we are."
			set doonce to 2
		elseif ( button == 1 )
			set doonce to 2
		endif
	endif
endif

if ( GetCurrentAiPackage != 3 )
	return
endif

if ( GetJournalIndex "MV_RunawaySlave" < 90 )
	if ( GetDistance "Im_Kilaya" <= 512 )
		moddisposition 25
		say "vo\a\m\Flw_AM003.mp3" "Thank you."
		Journal "MV_RunawaySlave" 97
		AiWander 384 5 0 0 60 20 10 10 0 0 0 0
	endif
	if ( GetDistance "Savile Imayn" <= 512 )
		moddisposition -50
		Journal "MV_RunawaySlave" 103
		AiWander 0 0 0 0 0 0 0 0 0 0 0 0
		ForceSneak
	endif
endif

end
-----
Make of this what you will.