global proc BenBoxSA(){
// BentoBox for Maya 2016 by Benjamin Kelly
// Language: MEL
// last updated: 03/30/2017
// MHI-specific variant


global string $BenBoxSA;
if ( `window -exists $BenBoxSA` ){
deleteUI -window $BenBoxSA;}

$BenBoxSA = `window -s off -mxb off -mnb off -tlb on -title "Bento Box" -widthHeight 152 282 -bgc 0.5 0.5 0.5 BentoBoxSA`;
window -e -widthHeight 152 282 BentoBoxSA;

string $form = `formLayout`;

string $btnSepar = `button -label " Separate Assets" -bgc 0.95 0.6 0.4 -w 150 -h 28 -c "BB_SeparateAssets()"`;
popupMenu -p $btnSepar;
menuItem -bld 1 -l "Seperate Assets" -c "BB_SeparateAssets();";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"Separate Assets\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Separate Assets Commands\");";
string $btnRender = `button -label " RenderCam" -bgc 0.3 0.65 0.98 -w 150 -h 28 -c "BB_RenderCam();"`;
popupMenu -p $btnRender;
menuItem -bld 1 -l "RenderCam" -c "BB_RenderCam();";
menuItem -l " Select Camera" -c "BB_SelectCam();";
menuItem -l " Isolate Select" -c "BB_IsolateSelect();";
menuItem -l " PerspCam" -c "BB_PerspCam();";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"RenderCam\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"RenderCam Commands\");";
string $btnStory = `button -label " Storyboard Control" -bgc 0.4 0.82 0.9 -w 150 -h 28 -c "BB_CamControl();"`;
popupMenu -p $btnStory;
menuItem -bld 1 -l "Storyboard Control" -c "BB_CamControl();";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"Storyboard Control\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Storyboard Control Commands\");";
string $btnReuse = `button -label " Reuse Scene" -bgc 0.85 0.5 0.5 -w 150 -h 28 -c "BB_ReuseScene()"`;
popupMenu -p $btnReuse;
menuItem -bld 1 -l "Reuse Scene" -c "BB_ReuseScene();";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"Reuse Scene\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Reuse Scene Commands\");";
string $btnGeoResA = `button -label " Geo Res" -bgc 0.45 0.45 0.67 -w 120 -h 28 -c "BB_HighRes(0);"`;
popupMenu -p $btnGeoResA;
menuItem -bld 1 -l "Geo Res" -c "BB_HighRes(0);";
menuItem -l " Geo Res (All)" -c "BB_HighResALL();";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"Toggle Geo Res\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Geo Res Commands\");";
string $btnGeoResB = `button -label " ALL" -bgc 0.39 0.39 0.61 -w 30 -h 28 -c "BB_HighResALL();"`;
popupMenu -p $btnGeoResB;
menuItem -bld 1 -l "Geo Res" -c "BB_HighRes(0);";
menuItem -l " Geo Res (All)" -c "BB_HighResALL();";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"Toggle Geo Res\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Geo Res Commands\");";
string $btnMass = `button -label " Mass Parent" -bgc 0.6 0.85 0.6 -w 150 -h 28 -c "BB_MassParent();"`;
popupMenu -p $btnMass;
menuItem -bld 1 -l "Mass Parent" -c "BB_MassParent();";
menuItem -l " Add Rivet" -c "rivet();";
menuItem -l " Create Locator on Spot" -c "BB_SpotLoc();";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"Mass Parent\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Mass Parent Commands\");";
string $btnAlign = `button -label " Align" -bgc 0.8 0.75 0.4 -w 150 -h 28 -c "BB_Align();"`;
popupMenu -p $btnAlign;
menuItem -bld 1 -l "Align" -c "BB_Align();";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"Align\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Align Commands\");";
string $btnShade = `button -label " Refresh Shader" -bgc 0.37 0.7 0.57 -w 150 -h 28 -c "BB_RefreshShader();"`;
popupMenu -p $btnShade;
menuItem -bld 1 -l "Refresh Shader" -c "BB_RefreshShader();";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"Refresh Shader\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Shader Commands\");";
string $btnReset = `button -label " Reset Frame Count" -bgc 0.7 0.5 0.8 -w 150 -h 28 -c "BB_ResetFrameCount();"`;
popupMenu -p $btnReset;
menuItem -bld 1 -l "Reset Frame Count" -c "BB_ResetFrameCount();";
menuItem -l " Add 10f to Start" -c "BB_AddFrameCount(\"st\");";
menuItem -l " Add 10f to End" -c "BB_AddFrameCount(\"en\");";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"Reset Frame Count\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Frame Count Commands\");";
string $btnClean = `button -label " Clean" -bgc 0.52 0.52 0.55 -w 80 -h 28 -c "BB_CleanScene();"`;
// popupMenu -p $btnClean;
//menuItem -bld 1 -l "Clean Workspace" -c "BB_CleanScene();";
//menuItem -l " Load Workspace" -c "BB_LoadScene();";
//menuItem -l " Save Workspace" -c "BB_SaveScene();";
//menuItem -d 1;
//menuItem -l "Help" -image "help.png" -c "infoBox(\"Clean Workspace\");";
//menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Workspace Commands\");";
string $btnLoad = `button -label " Load" -bgc 0.52 0.52 0.55 -w 70 -h 28 -c "BB_LoadScene();"`;
popupMenu -p $btnLoad;
//menuItem -bld 1 -l "Clean Workspace" -c "BB_CleanScene();";
menuItem -bld 1 -l " Load Workspace" -c "BB_LoadScene();";
menuItem -l " Save Workspace" -c "BB_SaveScene();";
menuItem -d 1;
menuItem -l "Help" -image "help.png" -c "infoBox(\"Clean Workspace\");";
menuItem -itl 1 -l "Get MEL Commands..." -image "shelfTab.png" -c "infoBox(\"Workspace Commands\");";

string $imgSepar = `image -i "unconstrainedDrag.xpm" `;
string $imgRender = `image -i "Camera.xpm" `;
string $imgStory = `image -i "CameraAE.xpm" `;
string $imgReuse = `image -i "redo_s.xpm" `;
string $imgGeoRes = `image -i "out_layeredShader.xpm" `;
string $imgMass = `image -i "copyUVMode.xpm" `;
string $imgAlign = `image -i "out_pointLight.xpm" `;
string $imgShade = `image -i "UseDefaultMaterial.xpm" `;
string $imgReset = `image -i "FilmGate.xpm" `;
string $imgClean = `image -i "clearAll.xpm" `;
string $imgLoad = `image -i "currentNamespaceParent.xpm" `;


formLayout -e

-af	$imgSepar top 5
-af	$imgSepar left 5
-af	$btnSepar top 1
-af	$btnSepar left 1

-af	$imgRender top 35
-af	$imgRender left 7
-af	$btnRender top 29
-af	$btnRender left 1

-af	$imgStory top 64
-af	$imgStory left 7
-af	$btnStory top 57
-af	$btnStory left 1

-af	$imgReuse top 89
-af	$imgReuse left 5
-af	$btnReuse top 85
-af	$btnReuse left 1

-af	$imgGeoRes top 118
-af	$imgGeoRes left 5
-af	$btnGeoResA top 113
-af	$btnGeoResA left 1
-af	$btnGeoResB top 113
-af	$btnGeoResB left 121

-af	$imgMass top 146
-af	$imgMass left 6
-af	$btnMass top 141
-af	$btnMass left 1

-af	$imgAlign top 174
-af	$imgAlign left 5
-af	$btnAlign top 169
-af	$btnAlign left 1

-af	$imgShade top 203
-af	$imgShade left 7
-af	$btnShade top 197
-af	$btnShade left 1

-af	$imgReset top 231
-af	$imgReset left 7
-af	$btnReset top 225
-af	$btnReset left 1

-af	$imgClean top 258
-af	$imgClean left 6
-af	$btnClean top 253
-af	$btnClean left 1
-af	$imgLoad top 361
-af	$imgLoad left 88
-af	$btnLoad top 253
-af	$btnLoad left 81

$form;
showWindow $BenBoxSA;


//fix Tween Machine
if (`shelfButton -ex "shelf_anim_04_tween_machine_button"` == 1){shelfButton -e -stp "mel" -c "source \"B:/maya/current/src/mel/anim/tweenMachine.mel\"; tweenMachine;" "shelf_anim_04_tween_machine_button";}

}


global proc infoBox(string $BBhelp){
string $BBmessage;
if ($BBhelp == "Separate Assets"){$BBmessage = "-- Separate Assets v1.2 --\n\n Spreads out all the assets clustered together at origin for easier selecting. \n Places each Transform_Ctrl in increments of 7 on the Translate X and Z.";}
if ($BBhelp == "RenderCam"){$BBmessage = "-- RenderCam v2.0 --\n\n Creates a new window using the shot camera and hides control visibility. \n\n\n-- Select Camera -- \n\n Literally just selects the camera. Not everything is wizardry magic.\n\n\n-- Isolate Select --\n\n Isolates the selected asset in the current viewport.\n This version also retains the selected control.\n\n\n-- PerspCam --\n\n Creates a window using the persp camera.";}
if ($BBhelp == "Storyboard Control"){$BBmessage = "-- Storyboard Control v1.3 --\n\n Creates a control box with a slider and toggle for the storyboard,\n and and a rule-of-thirds field guide toggle.\n\n Re-run the script upon opening a new scene to refresh the controls.";}
if ($BBhelp == "Reuse Scene"){$BBmessage = "-- Reuse Scene v2.0 -- \n\n Changes the audio, storyboard, and frame count to the scene entered in the prompt.\n Be sure to use the proper format when entering the scene number.\n\n e.g: 321_032_001";}
if ($BBhelp == "Toggle Geo Res"){$BBmessage = "-- Toggle Geo Res v4.0 -- \n\n Toggles between Proxy and High-res geo for selected objects. \n\n\n-- Toggle Geo Res (ALL) --\n\n Toggles geo resolution for all objects.";}
if ($BBhelp == "Mass Parent"){$BBmessage = "-- Mass Parent v1.2 -- \n\n Parents multiple selected objects to a single object. \n Select the PARENT first and then all of the childrens.\n\n\n-- Rivet --\n\n Adds a locator between two selected edges that always stay attached to the geo. \n\n\n-- Create Locator on Spot --\n\n Creates a locator on the current selection.";}
if ($BBhelp == "Align"){$BBmessage = "-- Align v2.0 -- \n\n If single object selected:\n - Aligns an object's Transform_Ctrl to its COG_Ctrl \n\n If multiple objects selected:\n - Aligns all selected objects to the first selected object";}
if ($BBhelp == "Refresh Shader"){$BBmessage = "-- Refresh Shader v2.0 --\n\n Restores broken shader on selected geo until scene is closed.\n\n";}
if ($BBhelp == "Reset Frame Count"){$BBmessage = "-- Reset Frame Count v1.1 -- \n\n Resets the frame count based on the audio length. \n\n\n-- Add 10f --\n\n Adds 10 frames of buffer to the start or end of a scene.";}
if ($BBhelp == "Clean Workspace"){$BBmessage = "-- Clean Workspace v1.3--\n\n Preps scene for saving by closing all Maya panels and setting the display mode\n to wireframe.\n\n\n-- Load Workspace --\n\n Loads the workspace settings saved via the Save Workspace script.\n\n\n-- Save Workspace -- \n\n Saves the current viewport layout plus any floating windows and their positions. \n Excludes the Anim Library and some other BD Tools. \n\n (Will also save the AnimSchoolPicker if the plugin is loaded.)";}

if ($BBhelp == "Separate Assets Commands"){$BBmessage = "BB_SeparateAssets();";}
if ($BBhelp == "RenderCam Commands"){$BBmessage = "BB_RenderCam();\nBB_SelectCam();\nBB_IsolateSelect();\nBB_PerspCam();";}
if ($BBhelp == "Storyboard Control Commands"){$BBmessage = "BB_CamControl();\nBB_HighResALL;";}
if ($BBhelp == "Geo Res Commands"){$BBmessage = "BB_HighRes(0);\nBB_HighResALL;";}
if ($BBhelp == "Mass Parent Commands"){$BBmessage = "BB_MassParent();\nrivet();\nBB_SpotLoc();";}
if ($BBhelp == "Align Commands"){$BBmessage = "BB_Align();";}
if ($BBhelp == "Shader Commands"){$BBmessage = "BB_RefreshShader();";}
if ($BBhelp == "Frame Count Commands"){$BBmessage = "BB_ResetFrameCount();\nBB_AddFrameCount(\"st\");\nBB_AddFrameCount(\"en\");";}
if ($BBhelp == "Workspace Commands"){$BBmessage = "BB_CleanScene();\nBB_LoadScene();\nBB_SaveScene();";}
confirmDialog -message $BBmessage -title $BBhelp -button "Okay";
}

BenBoxSA;



global proc BB_SeparateAssets(){
// -- Separate Assets --
// Language: MEL
// Version 1.2
//
// Spreads out all the assets clustered together at origin for easier selecting.
// Places each Transform_Ctrl in increments of 7 on the Translate X and Z.

global int $sCount;
global int $counterX = 0;
global int $counterZ = 0;
//Align all objects with :Transform_Ctrl
if(`objExists "*:Transform_Ctrl"`){
select -r "*:Transform_Ctrl";
string $transList[] =`ls -selection`;
//begin fix loop
for($i = 0; $i < size($transList); $i = $i + 1){
if ($transList[$i] == "VGT_IchabeezerMansion_INT:Transform_Ctrl"){}
if ($transList[$i] == "VGT_KoiPond_EXT:Transform_Ctrl"){}
if ($transList[$i] == "VGT_HumanNeighborhoodA_EXT:Transform_Ctrl"){}
else {
//get namespace by removing :Base_Ctrl from string
int $ssA = 1;
int $ssB = (`size($transList[$i])` - 15);
$transList[$i] = `substring $transList[$i] $ssA $ssB`;
setTranslate($transList[$i]);
}
}
if ($sCount == 1){print ("1 asset separated. \n");}
else {print ($sCount + " assets separated. \n");}
} else {warning "No assets detected. \n";}
select -cl ;
$counterX = 0;
$counterZ = 0;
$sCount = 0;
}

global proc setTranslate(string $ob) {
global int $sCount;
global int $counterX;
global int $counterZ;
if(`objExists ($ob + ":Transform_Ctrl")`) {
//get true location relative to worldSpace
float $wsArray[] = `xform -worldSpace -q -t ($ob + ":Transform_Ctrl")`;
//if at origin, then move
if ($wsArray[0] > -0.005 && $wsArray[0] < 0.005 && $wsArray[1] > -0.005 && $wsArray[1] < 0.005 && $wsArray[2] > -0.005 && $wsArray[2] < 0.005){
setAttr ($ob + ":Transform_Ctrl.translateX") $counterX;
setAttr ($ob + ":Transform_Ctrl.translateZ") $counterZ;
$sCount++;
//update movement counter
$counterX = $counterX + 7;
if ($counterX == 28) {
$counterX = 0;
$counterZ = $counterZ + 7;
}
}
}
}



global proc BB_RenderCam(){
// -- RenderCam --
// Language: MEL
// Version 2.0

// Creates a new window using the shot camera and hides control visibility.

if(`objExists ("\*_Ren_CamRg_A:Render_Cam")`) {
string $renCh = 0;
if (`window -exists RenderCam`){deleteUI -window RenderCam; $renCh = 1;}
if (`modelPanel -exists RenderCamPanel`){deleteUI -panel RenderCamPanel;}
window -w 800 -h 600 "RenderCam";
paneLayout;
modelPanel -camera "\*_Ren_CamRg_A:Render_Cam" -l "RenderCamPanel" "RenderCamPanel";
setFocus RenderCamPanel;
displayStyle -ss;
modelEditor -e -allObjects false RenderCamPanel;
modelEditor -e -cameras true RenderCamPanel;
modelEditor -e -imagePlane true RenderCamPanel;
modelEditor -e -polymeshes true RenderCamPanel;
modelEditor -e -grid false RenderCamPanel;
string $currentPanel = `getPanel -withFocus`;
string $currCam = `modelEditor -q -camera $currentPanel`;
camera -e -displayResolution on -displayGateMask on -overscan 1.3 $currCam;
showWindow RenderCam;
if($renCh == 1){print "RenderCam window refreshed. \n";}
else {print "RenderCam window created. \n";}
} else {warning "Camera not detected. \n";}
}

global proc BB_SelectCam(){
// -- Select Camera --
//
// Literally just selects the camera. Not everything is wizardry magic.

if(`objExists "*Ren_CamRg_A:Render_Cam"`){select -r "*Ren_CamRg_A:Render_Cam";}
else {warning "Camera not detected.";}
}

global proc BB_IsolateSelect(){
// -- Isolate Select --
// Isolates the selected asset in the current viewport.
// This version also retains the selected control.

saveSelect();

for($g = 0; $g < 30; $g = $g + 1){pickWalk -d up;}

$currentPanel = `getPanel -withFocus`;
string $panelType = `getPanel -to $currentPanel`;
if ($panelType == "modelPanel"){
if (`isolateSelect -q -s $currentPanel` == 0){enableIsolateSelect $currentPanel true;}
else {enableIsolateSelect $currentPanel false;}
}

loadSelect();
}

global proc BB_PerspCam(){
// -- PerspCam --
//
// Creates a window using the persp camera.

string $renCh = 0;
if (`window -exists PerspCam`){deleteUI -window PerspCam; $renCh = 1;}
if (`modelPanel -exists PerspCamPanel`){deleteUI -panel PerspCamPanel;}
window -w 800 -h 600 -t "PerspCam" "PerspCam";
paneLayout;
modelPanel -camera "persp" -l "PerspCamPanel" "PerspCamPanel";
setFocus PerspCamPanel;
showWindow PerspCam;
if($renCh == 1){print "PerspCam window refreshed. \n";}
else {print "PerspCam window created. \n";}
}



global proc BB_CamControl(){
// -- Storyboard Control --
// Language: MEL
// Version 1.3
//
// Creates a control box with a slider and toggle for the storyboard, and and a rule-of-thirds field guide toggle.
// Re-run the script upon opening a new scene to refresh the controls.

if (`objExists imagePlane1` == 0){warning "Storyboards not detected."; return;}
global string $alphaControl;
float $alphagain1 = `getAttr ("imagePlane1.alphaGain")`;
string $refCh = 0;
if ( `window -exists $alphaControl` ){deleteUI -window $alphaControl; $refCh = 1;}
$alphaControl = `window -sizeable off -mxb off -mnb off -tlb on -title "Storyboard Control" -widthHeight 180 184 AlphaControl`;
window -e -widthHeight 180 119 AlphaControl;
string $form = `formLayout`;
global float $saved = 0;
//Create slider
string $label = `text -label "Storyboard Opacity" -align "right"`;
string $toggle = `button -label "Toggle" -bgc 0.7 0.5 0.8 -w 168 -h 35 -c "lockUnlock();"`;
string $fifty = `button -label "50%" -bgc 0.85 0.5 0.5 -w 84 -h 30 -c "alphaProc(0.5);"`;
string $hundred = `button -label "100%" -bgc 0.6 0.8 0.6 -w 84 -h 30 -c "alphaProc(1);"`;
string $field = `floatField -min 0.0 -max 1 -precision 2 -w 35`;
string $slider = `floatSlider -min 0.0 -max 1 -enable false`;
string $Ro3_label = `text -label "Rule of 3rds Field Guide" -align "right"`;
string $Ro3_toggle = `button -label "Toggle" -bgc 0.4 0.7 0.9 -w 168 -h 35 -c "Ro3_lockUnlock();"`;
//Connect to the controls
connectControl $field ("imagePlane1.alphaGain");
connectControl $slider ("imagePlane1.alphaGain");
formLayout -e
-af $field top 4
-af $field left 6
-af $slider top 8
-ac $slider left 6
$field -af $slider right 6
-af	$toggle	top	78
-af	$toggle	left 6
-af $label top 27
-af $label left 47
-af	$fifty top 45
-af	$fifty left 6
-af	$hundred top 45
-af	$hundred left 90
-af $Ro3_label top 122
-af $Ro3_label left 35
-af	$Ro3_toggle	top	140
-af	$Ro3_toggle	left 6
$form;
showWindow $alphaControl;
if($refCh == 1){print "Storyboard Control window refreshed. \n";}
else {print "Storyboard Control window created. \n";}
}

global proc alphaProc(float $myAlpha){setAttr imagePlane1.alphaGain $myAlpha;}

global proc lockUnlock(){
global float $saved;
float $current = `getAttr "imagePlane1.alphaGain"`;
if ($current == 0) {
setAttr "imagePlane1.alphaGain" $saved;
//setAttr "imagePlane1|imagePlaneShape1.useFrameExtension" 1;
setAttr "imagePlaneShape1.useFrameExtension" 1;
print "Use Image Sequence ON. \n";
} else {
$saved = `getAttr "imagePlane1.alphaGain"`;
setAttr "imagePlane1.alphaGain" 0;
//setAttr "imagePlane1|imagePlaneShape1.useFrameExtension" 0;
setAttr "imagePlaneShape1.useFrameExtension" 0;
print "Use Image Sequence OFF. \n";
}
}

global proc Ro3_lockUnlock(){
if (`objExists "VGT_CC_Ro3_imagePlane"`) {select -r "VGT_CC_Ro3*"; doDelete; print "Ro3 Guide OFF. \n";}
else {
select -r |imagePlane1 ;
duplicate -rr -n VGT_CC_Ro3_imagePlane;
setAttr "VGT_CC_Ro3_imagePlane.depth" 0.1;
setAttr -type "string" "VGT_CC_Ro3_imagePlane|VGT_CC_Ro3_imagePlaneShape.imageName" "T:/dwtv/vgt/Maya_VGT/scripts/BenScripts/Ro3_IMG.png";
setAttr "VGT_CC_Ro3_imagePlaneShape.alphaGain" 1;
select -cl;
print "Ro3 Guide ON. \n";
}
}



global proc BB_ReuseScene(){
// -- Reuse Scene Script --
// Language: MEL
// Version 2.0
//
// Changes the audio, storyboard, and frame count to the scene entered in the prompt.
// Be sure to use the proper format when entering the scene number.
//
// e.g: 321_032_001

string $reuseResult = `promptDialog -title "Reuse Scene" -message "Enter Scene: (000_000_000)" -button "OK" -button "Cancel" -defaultButton "OK" -cancelButton "Cancel" -dismissString "Cancel"`;
if ($reuseResult == "Cancel") {return;}

string $text = `promptDialog -query -text`;
if (`size($text)` != 11 && `size($text)` != 12){warning "Invalid entry."; return;}
else if (`substring $text 4 4` != "_"){warning "Invalid entry."; return;}
string $rsounds[] = `ls -typ "audio"`;
if (`size($rsounds)` < 1){warning "No audio detected.";}
else if (`size($rsounds)` > 1){warning "More than one audio file detected. Please delete the extraneous audio and try again."; return;}
else if (`objExists imagePlane1` == 0){warning "No storyboards detected."; return;}
string $fn = `getAttr ($rsounds[0] + ".filename")`;
string $sbfn = `getAttr imagePlane1.imageName`;
string $show = `substring $rsounds[0] 1 3`;
string $epi = `substring $rsounds[0] 5 7`;
string $seq = `substring $rsounds[0] 9 (size($rsounds[0]))`;
string $sea = `substring $text 1 1`;
string $epiR = `substring $text 1 3`;
string $seqR = `substring $text 5 (size($text))`;
string $fnSub = `substitute ("S_0.*/" + $epi + "/" + $seq) $fn ("S_0" + $sea + "/" + $epiR + "/" + $seqR)`;
string $fnR = `substitute $rsounds[0] $fnSub ($show + "_" + $text)`;
string $sbSub = `substitute ("S_0.*/" + $epi + "/" + $seq) $sbfn ("S_0" + $sea + "/" + $epiR + "/" + $seqR)`;
string $sbR = `substitute ($rsounds[0] + ".*") $sbSub ($show + "_" + $text)`;
//audio
if (`filetest -e $fnR` != 1){warning "Scene does not exist."; return;}
delete $rsounds[0];
file -i -type "audio" $fnR;
//storyboards
string $sbFin;
if (`getAttr ($show + "_" + $text + ".duration")` >= 1000) {$sbFin = $sbR + ".0001.png";}
else if (`getAttr ($show + "_" + $text + ".duration")` >= 100) {$sbFin = $sbR + ".001.png";}
else if (`getAttr ($show + "_" + $text + ".duration")` >= 10) {$sbFin = $sbR + ".01.png";}
else if (`getAttr ($show + "_" + $text + ".duration")` >= 1) {$sbFin = $sbR + ".1.png";}
setAttr -type "string" imagePlane1.imageName $sbFin;
BB_ResetFrameCount;
print ("Loaded " + $text + ".");
}



global proc BB_HighRes(string $char){
// -- Toggle Geo Res --
// Language: MEL
// Version 4.0
//
// Toggles between Proxy and High-res geo for selected objects OR all characters.

global int $resTog;
saveSelect();
if ($char == 1){if(`objExists "*:Base_Ctrl"`){select -r "*:Base_Ctrl";}}
string $geoList[] =`ls -selection`;
if (size($geoList) == 0){warning "Nothing selected. \n";
} else {
if ($resTog == 0){
if ($char ==1){print "Characters Geo set to Proxy. \n";} else {print "Geo set to Proxy. \n";}
for($i = 0; $i < size($geoList); $i = $i + 1){
select -r $geoList[$i];
string $geoCheck[] = `ls -selection`;
for($g = 0; $g < 20; $g = $g + 1){
if(`attributeExists "GeoRes" ($geoCheck[0])`){
$g = 20;
$resTog = 1;
string $qString[] = `attributeQuery -node ($geoCheck[0]) -le "GeoRes"`;
if (`size $qString[0]` == 11) {
setAttr ($geoCheck[0] + ".GeoRes") 1;
}
if (`size $qString[0]` == 17) {
setAttr ($geoCheck[0] + ".GeoRes") 2;
}
} else {pickWalk -d up; $geoCheck = `ls -selection`;}
}
}
} else {
if ($char ==1){print "Characters Geo set to High-res. \n";} else {print "Geo set to High-res. \n";}
for($i = 0; $i < size($geoList); $i = $i + 1){
select -r $geoList[$i];
string $geoCheck[] = `ls -selection`;
for($g = 0; $g < 20; $g = $g + 1){
if(`attributeExists "GeoRes" ($geoCheck[0])`){
$g = 20;
$resTog = 0;
string $qString[] = `attributeQuery -node ($geoCheck[0]) -le "GeoRes"`;
if (`size $qString[0]` == 11) {
setAttr ($geoCheck[0] + ".GeoRes") 0;
}
if (`size $qString[0]` == 17) {
setAttr ($geoCheck[0] + ".GeoRes") 0;
}
} else {pickWalk -d up; $geoCheck = `ls -selection`;}
}
}
}
}
loadSelect();
}

global proc BB_HighResALL(){
// -- Toggle Geo Res (ALL) --
//
// Toggles geo resolution for all objects, excluding characters.

global int $resTog;
saveSelect();
select -cl;
if(`attributeExists "GeoRes" "*Transform_Ctrl" `){select -add "*.GeoRes";}
if(`attributeExists "GeoRes" "*:Transform_Ctrl" `){select -add "*:*.GeoRes";}
if(`attributeExists "GeoRes" "*:*Transform_Ctrl" `){select -add "*:*.GeoRes";}
if(`attributeExists "GeoRes" "*:*:Transform_Ctrl" `){select -add "*:*:*.GeoRes";}
if(`attributeExists "GeoRes" "*:*:*Transform_Ctrl" `){select -add "*:*:*.GeoRes";}
if(`attributeExists "GeoRes" "*:*:*:Transform_Ctrl" `){select -add "*:*:*:*.GeoRes";}
if(`attributeExists "GeoRes" "*:*:*:*Transform_Ctrl" `){select -add "*:*:*:*.GeoRes";}
if(`attributeExists "GeoRes" "*:*:*:*:Transform_Ctrl" `){select -add "*:*:*:*:*.GeoRes";}
string $geoList[] =`ls -selection`;
//check for and deselect characters by looking for base control
for($i = 0; $i < size($geoList); $i = $i + 1){
float $nameSize = `size $geoList[$i]`;
float $nameSwitch = (float)$nameSize;
string $nameCheck = `substring $geoList[$i] 1 ($nameSize - 14 - 7)`;
if (`objExists ($nameCheck + "Base_Ctrl")`){select -d $geoList[$i];}
}
//Reload after characters deselected and toggle res
string $geoList[] =`ls -selection`;
if ($resTog == 0){
print "All Geo set to High-res.";
for($i = 0; $i < size($geoList); $i = $i + 1){setAttr $geoList[$i] 0;}
$resTog = 1;
} else {
print "All Geo set to Proxy.";
for($i = 0; $i < size($geoList); $i = $i + 1){setAttr $geoList[$i] 2;}
$resTog = 0;
}
loadSelect();
}

global proc saveSelect(){global string $saveSelect[]; string $saveSelect[] = `ls -selection`;}
global proc loadSelect(){global string $saveSelect[]; select -r $saveSelect;}



global proc BB_MassParent(){
// -- Mass Parent --
// Language: MEL
// Version 1.2
//
// Parents multiple selected objects to a single object.
// Select the PARENT first and then all of the childrens.

string $obj[] = `ls -selection`;
int $size = size($obj);
for($i=1;$i<$size;++$i) {
parentConstraint -mo $obj[0] $obj[$i];
}
if ($size <= 1) {warning "No objects selected.";}
if ($size == 1) {warning "Only one object selected.";}
if ($size == 2) {print ($obj[1] + " parented to " + $obj[0] + ". \n");}
if ($size > 2) {print (($size - 1) + " objects parented to " + $obj[0] + ". \n");}
}

global proc string rivet(){
// Copyright (C) 2000-2001 Michael Bazhutkin - Copyright (C) 2000 studio Klassika
// www.geocites.com/bazhutkin
// bazhutkin@mail.ru
//
// Rivet (button) 1.0
// Script File
// MODIFY THIS AT YOUR OWN RISK
//
// Creation Date: April 13, 2001
//
//
// Description:
// Use "Rivet" to constrain locator to polygon or NURBS surfaces
// Select two edges on polygon object
// or select one point on NURBS surface and call rivet
// Parent your rivets and buttons to this locator

// minor adjustments made

string $nameObject;
string $namePOSI;

string $parts[];
string $list[] = `filterExpand -sm 32`;
int $size = size($list);
if ($size > 0)
{
if ($size != 2)
{ warning("Please select two edges.");
return "";
}

tokenize($list[0],".",$parts);
$nameObject = $parts[0];
tokenize($list[0],"[]",$parts);
float $e1 = $parts[1];
tokenize($list[1],"[]",$parts);
float $e2 = $parts[1];

string $nameCFME1 = `createNode curveFromMeshEdge -n "rivetCurveFromMeshEdge1"`;
setAttr ".ihi" 1;
setAttr ".ei[0]" $e1;
string $nameCFME2 = `createNode curveFromMeshEdge -n "rivetCurveFromMeshEdge2"`;
setAttr ".ihi" 1;
setAttr ".ei[0]" $e2;
string $nameLoft = `createNode loft -n "rivetLoft1"`;
setAttr -s 2 ".ic";
setAttr ".u" yes;
setAttr ".rsn" yes;

$namePOSI = `createNode pointOnSurfaceInfo -n "rivetPointOnSurfaceInfo1"`;
setAttr ".turnOnPercentage" 1;
setAttr ".parameterU" 0.5;
setAttr ".parameterV" 0.5;

connectAttr -f ($nameLoft + ".os") ($namePOSI + ".is");
connectAttr ($nameCFME1 + ".oc") ($nameLoft + ".ic[0]");
connectAttr ($nameCFME2 + ".oc") ($nameLoft + ".ic[1]");
connectAttr ($nameObject + ".w") ($nameCFME1 + ".im");
connectAttr ($nameObject + ".w") ($nameCFME2 + ".im");
}
else
{ $list = `filterExpand -sm 41`;
$size = size($list);

if ($size > 0)
{
if ($size != 1)
{ error("No one point selected.");
return "";
}
tokenize($list[0],".",$parts);
$nameObject = $parts[0];
tokenize($list[0],"[]",$parts);
float $u = $parts[1];
float $v = $parts[2];
$namePOSI = `createNode pointOnSurfaceInfo -n "rivetPointOnSurfaceInfo1"`;
setAttr ".turnOnPercentage" 0;
setAttr ".parameterU" $u;
setAttr ".parameterV" $v;
connectAttr -f ($nameObject + ".ws") ($namePOSI + ".is");
}
else
{ warning("Please select two edges.");
return "";
}
}

string $nameLocator = `createNode transform -n "rivet1"`;
createNode locator -n ($nameLocator + "Shape") -p $nameLocator;

string $nameAC = `createNode aimConstraint -p $nameLocator -n ($nameLocator + "_rivetAimConstraint1")`;
setAttr ".tg[0].tw" 1;
setAttr ".a" -type "double3" 0 1 0;
setAttr ".u" -type "double3" 0 0 1;
setAttr -k off ".v";
setAttr -k off ".tx";
setAttr -k off ".ty";
setAttr -k off ".tz";
setAttr -k off ".rx";
setAttr -k off ".ry";
setAttr -k off ".rz";
setAttr -k off ".sx";
setAttr -k off ".sy";
setAttr -k off ".sz";

connectAttr ($namePOSI + ".position") ($nameLocator + ".translate");
connectAttr ($namePOSI + ".n") ($nameAC + ".tg[0].tt");
connectAttr ($namePOSI + ".tv") ($nameAC + ".wu");
connectAttr ($nameAC + ".crx") ($nameLocator + ".rx");
connectAttr ($nameAC + ".cry") ($nameLocator + ".ry");
connectAttr ($nameAC + ".crz") ($nameLocator + ".rz");

select -r $nameLocator;
return ($nameLocator);

}

global proc BB_SpotLoc(){
// -- Create Locator on Spot --
//
// Creates a locator on the current selection.

string $obj[] = `ls -selection`;
if(`objExists $obj[0]`){
spaceLocator -n "spotLoc0";
scale -r 4 4 4;
string $sL[] = `ls -selection`;
parentConstraint -n "tmpSL" $obj[0] $sL[0];
select -r "tmpSL";
doDelete;
select -cl;
} else {
spaceLocator -n "spotLoc0";
scale -r 3 3 3;
string $sL[] = `ls -selection`;
parentConstraint -n "tmpSL" persp $sL[0];
select -r "tmpSL";
doDelete;
select -r $sL[0];
move -r -os -wd 0 0 -15;
}
print "Spot Locator created.\n";
}



global proc BB_Align(){
// -- Align --
// Language: MEL
// Version 3.1
//
// If single object selected:
// - Aligns a character's ground controls to their Base_Ctrl
// - Aligns a prop's Transform_Ctrl to its COG_Ctrl

// If multiple objects selected:
// - Aligns all selected objects to the first selected object


string $obj[] = `ls -selection`;
if (`size($obj)` > 1){
if(`objExists $obj[0]` && `objExists $obj[1]`){
spaceLocator -n "alignLoc0";
scale -r 4 4 4;
string $sL[] = `ls -selection`;
parentConstraint -n "tmpSL" $obj[0] $sL[0];
delete "tmpSL";
for($i = 1; $i < size($obj); $i = $i + 1){
parentConstraint -n "tmpPar0" $sL[0] $obj[$i];
int $saveKey = 0;
int $curKey = `currentTime -q`;
if (`selectKey -add -k -t $curKey $obj[$i]`){$saveKey = 1;}
string $atrList[] = {"translateX","translateY","translateZ","rotateX","rotateY","rotateZ"};
for($k = 0; $k < size($atrList); $k = $k + 1){
float $vAtr = `getAttr ($obj[$i] + "." + $atrList[$k])`;
setKeyframe -s 0 -attribute $atrList[$k] -hierarchy none $obj[$i];
if ($saveKey == 0) {
cutKey -s 0 -attribute $atrList[$k] -t $curKey $obj[$i];
setAttr ($obj[$i] + "." + $atrList[$k]) $vAtr;
}
}
select -r $sL[0]; select -add $obj[$i];
parentConstraint -remove;
}
delete $sL[0];
print ($obj[1] + " aligned to " + $obj[0] + ".\n");
}
} else {warning "Please select multiple objects.\n";}
}



global proc BB_RefreshShader(){
// -- Refresh Shader --
// Language: MEL
// Version 2.0
//
// Restores broken shader on selected geo until scene is closed.

string $reShader;
string $shaList[] =`ls -selection`;
if (`size($shaList)` == 0){warning "Please select a geometry object."; return;}
for($i = 0; $i < size($shaList); $i = $i + 1){
string $RelCheck[] = `listRelatives -type mesh $shaList[$i]`;
if (`size($RelCheck)` > 0){
string $myShapeNode[] = `listRelatives -children -shapes $shaList[$i]`;
string $mySGs[] = `listConnections -type shadingEngine $myShapeNode[0]`;
string $surfaceShader[] = `listConnections ($mySGs[0] + ".surfaceShader")`;
string $reShader = $surfaceShader[0];
select -r $shaList[$i];
hyperShade -assign $reShader;
select -cl;
print ("Refreshed shader for " + $shaList[$i] + ".\n");
} else {warning "Please select a geometry object.";}
}
select -r $shaList;
}



global proc BB_ResetFrameCount(){
// -- Reset Frame Count --
// Language: MEL
// Version 1.1
//
// Resets the frame count based on the audio length.

global string $gPlayBackSlider;
string $sounds[] = `ls -typ "audio"`;
if (`size($sounds)` == 0){warning "Audio not detected."; return;}
playbackOptions -min 1 -ast 1 -max (`getAttr ($sounds[0] + ".duration")`) -aet (`getAttr ($sounds[0] + ".duration")`);
timeControl -e -ds true -s $sounds[0] $gPlayBackSlider;
}

global proc BB_AddFrameCount(string $where){
// -- Add 10f --
//
// Adds 10 frames of buffer to the start or end of a scene.

global string $gPlayBackSlider;
string $sounds[] = `ls -typ "audio"`;
if (`size($sounds)` == 0){warning "Audio not detected."; return;}
if($where == "st"){
int $cur = `playbackOptions -q -min`;
playbackOptions -min ($cur - 10) -ast ($cur - 10);
}
if($where == "en"){
int $cur = `playbackOptions -q -max`;
playbackOptions -max ($cur + 10) -aet ($cur + 10);
}
timeControl -e -ds true -s $sounds[0] $gPlayBackSlider;
}



global proc BB_CleanScene(){
// -- Clean Workspace STANDALONE OFFSHOOT --
// Language: MEL
// Version 1.3SA

// Preps scene for saving by closing all Maya panels and setting the display mode to wireframe.

print "\nClearing Workspace\n";
print "----------\n";
//execute Calista's python script to clear all panels
camera -e -startupCamera true persp;
setNamedPanelLayout "Four View";
python ("import sys\n\ndef clear_panels():\n '''Description: Removes all panels and resets to default panels.\n Input: None\n Return: None'''\n default_panels = {'modelPanel1': 'Top View',\n 'modelPanel2': 'Side View',\n 'modelPanel3': 'Front View',\n 'modelPanel4': 'Persp View',\n 'outlinerPanel1': 'Outliner', \n 'graphEditor1': 'Graph Editor',\n 'dopeSheetPanel1': 'Dope Sheet',\n 'clipEditorPanel1': 'Trax Editor',\n 'sequenceEditorPanel1': 'Camera Sequencer',\n 'hyperGraphPanel1': 'Hypergraph Hierarchy',\n 'hyperShadePanel1': 'Hypershade',\n 'visorPanel1': 'Visor',\n 'nodeEditorPanel1': 'Node Editor',\n 'createNodePanel1': 'Create Node',\n 'polyTexturePlacementPanel1': 'UV Texture Editor',\n 'renderView': 'Render View',\n 'blendShapePanel1': 'Blend Shape',\n 'dynRelEdPanel1': 'Dynamic Relationships Editor',\n 'relationshipPanel1': 'Relationship Editor',\n 'referenceEditorPanel1': 'Reference Editor',\n 'componentEditorPanel1': 'Component Editor',\n 'dynPaintScriptedPanel': 'Paint Effects',\n 'scriptEditorPanel1': 'Script Editor'}\n default_layouts = set(['hyperGraphInfo', 'hyperGraphLayout'])\n\n\n p_names = set(default_panels.keys())\n panels = set(cmds.getPanel(allPanels=True))\n panels = list(panels.difference(p_names))\n p_num = 0\n for panel in panels:\n cmds.deleteUI(panel, panel=True)\n p_num += 1\n \n layouts = set(cmds.ls(type=['hyperView', 'hyperLayout', 'hyperGraphInfo']))\n layouts = list(layouts.difference(default_layouts))\n l_num = 0\n for layout in layouts:\n try:\n cmds.delete(layout)\n except:\n pass\n finally:\n l_num += 1\n \n msg = '%i panels / %i layouts deleted' % (p_num, l_num)\n \n #Rebuild model panels if missing\n model_panels = ['modelPanel1','modelPanel2','modelPanel3','modelPanel4']\n gMainPane = mel.eval\('global string $gMainPane; $temp = $gMainPane;')\n for m_panel in model_panels:\n if not cmds.modelPanel(m_panel, exists=True):\n cmds.modelPanel(m_panel, parent=gMainPane)\n \n for name, label in default_panels.items():\n try:\n cmds.panel(name, e=True, label=label)\n except:\n pass\n\n\n mel.eval('lookThroughModelPanel top modelPanel1')\n mel.eval('lookThroughModelPanel side modelPanel2')\n mel.eval('lookThroughModelPanel front modelPanel3')\n mel.eval('lookThroughModelPanel persp modelPanel4')\n mel.eval('setNamedPanelLayout \"Single Perspective View\"')\n return msg\n \n \n#clean_scene()\n#clear_refs()\n#clear_groupID()\nclear_panels()\nsys.exit");
global string $gMainWindow;
string $allOpenWindows[] = `lsUI -wnd`;
//clear all other windows
for($i = 0; $i < size($allOpenWindows); $i = $i + 1){
if ($allOpenWindows[$i] == "MayaWindow"){}
else {
if ($allOpenWindows[$i] == "BentoBoxSA"){}
else {
deleteUI ($allOpenWindows[$i]);
print ("Cleared " + $allOpenWindows[$i] + ".\n");
}
}
}

//set display to wireframe
string $pans[] = `getPanel -type modelPanel`;
int $size = size($pans);
for($i=1;$i<$size;++$i) {
setFocus $pans[$i];
displayStyle -wireframe ;
}
setNamedPanelLayout "Single Perspective View";
setFocus modelPanel4;
print "----------\n";
print "Workspace cleared.\n";
}

global proc BB_LoadScene(){
// -- Load Workspace --
//
// Loads the workspace settings saved via the Save Workspace script.
$fileName = ( `internalVar -userScriptDir` + "layout.cfg" );
if(`filetest -e $fileName` == 0){ warning "No workspace saved. Please save your workspace by right-clicking the Load button and selecting \"Save Workspace\"."; return;}
$fileId=`fopen $fileName "r"`;
string $layoutName = `fgetline $fileId`;
string $ifRender = `fgetline $fileId`;
string $ifStory = `fgetline $fileId`;
string $ifGraph = `fgetline $fileId`;
string $ifDope = `fgetline $fileId`;
string $ifTrax = `fgetline $fileId`;
string $ifOut = `fgetline $fileId`;
string $ifHop = `fgetline $fileId`;
string $ifRef = `fgetline $fileId`;
string $ifTween = `fgetline $fileId`;
string $ifVGTP = `fgetline $fileId`;
string $ifPAIE = `fgetline $fileId`;
string $ifGhost = `fgetline $fileId`;
string $ifTang = `fgetline $fileId`;
string $ifANIP = `fgetline $fileId`;
string $ifANIP_path = `fgetline $fileId`;
string $ifPersp = `fgetline $fileId`;
fclose $fileId;
//string $plugList[] = `pluginInfo -q -ls`;
//for ($i = 0; $i < size($plugList); $i++) { if(`pluginInfo -q -n $plugList[$i]` == "AnimSchoolPicker"){$ifANIP = 1;}}
int $nameCut = `size($layoutName)` - 1;
string $cutName = `substring $layoutName 1 $nameCut`;
setNamedPanelLayout $cutName;
print "\n---Windows Loaded---\n";
if($ifRender == "1\n"){BB_RenderCam(); print "RenderCam\n";}
if($ifStory == "1\n"){BB_CamControl(); print "Storyboard Control\n";}
if($ifGraph == "1\n"){GraphEditor; print "Graph Editor\n";}
if($ifDope == "1\n"){DopeSheetEditor; print "Dope Sheet\n";}
if($ifTrax == "1\n"){CharacterAnimationEditor; print "Trax Editor\n";}
if($ifOut == "1\n"){OutlinerWindow; print "Outliner\n";}
if($ifHop == "1\n"){
//if(`window -ex "hopWin"`){deleteUI -window "hopWin";}
//source "hop.mel";source "as_infoInScene.mel";source "chop.mel";source "getPreUnder.mel";source "tungsethTangent.mel";hop;
//print "Hop Tool\n";
}
if($ifRef == "1\n"){ReferenceEditor; print "Reference Editor\n";}
if($ifTween == "1\n"){source "B:/maya/current/src/mel/anim/tweenMachine.mel"; tweenMachine; print "Tween Machine \n";}
if($ifVGTP == "1\n"){python "from vgt_anim_picker import vgt_anim_picker; reload(vgt_anim_picker); sys.exit;"; print "VGT Picker\n";}
if($ifPAIE == "1\n"){python "paie.GUI(); sys.exit;"; print "PAIE\n";}
if($ifGhost == "1\n"){bhGhost(); print "Ghost Tool\n";}
if($ifTang == "1\n"){autoTangent(); print "AutoTangent\n";}
if($ifANIP == "1\n"){
string $plugLoad = 0;
string $plugList[] = `pluginInfo -q -ls`;
for ($i = 0; $i < size($plugList); $i++) {
if(`pluginInfo -q -n $plugList[$i]` == "AnimSchoolPicker"){
if (`exists AnimSchoolPicker`) {AnimSchoolPicker();}
if (`exists CharacterPicker`) {CharacterPicker();}
$plugLoad = 1;
}
}
if ($plugLoad == 0){
loadPlugin -qt $ifANIP_path;
if (`exists AnimSchoolPicker`) {AnimSchoolPicker();}
if (`exists CharacterPicker`) {CharacterPicker();}
}
print "AnimSchoolPicker\n";
}
if($ifPersp == "1\n"){BB_PerspCam(); print "PerspCam\n";}
print ("\nLoaded \"" + $cutName + "\" workspace.\n");
}

global proc BB_SaveScene(){
// -- Save Workspace --
//
// Saves the current viewport layout plus any floating windows and their positions.
// Excludes the Anim Library and some other BD Tools.
//
// (Will also save the AnimSchoolPicker if the plugin is loaded.)

global string $gMainWindow;
global string $gMainPane;
global string $gPanelEditorWnd;
string $text = "New Layout";
string $layoutName = "";
string $config, $configArray[];

string $OK = (uiRes("m_saveCurrentPanelLayout.kOk"));
string $cancel = (uiRes("m_saveCurrentPanelLayout.kCancel"));

string $result = `promptDialog
-title (uiRes("m_saveCurrentPanelLayout.kSavePanelArrangement"))
-message (uiRes("m_saveCurrentPanelLayout.kEnterName"))
-text $text
-button $OK
-button $cancel
-defaultButton $OK
-cancelButton $cancel
-dismissString $cancel
-parent $gMainWindow`;

//
// If the result was "OK", then proceed
//
if ( $result == $OK ) {

$layoutName = `promptDialog -query`;

//	First check if the name is unique.
//
$configArray = `getPanel -allConfigs`;
for ($config in $configArray) {
if ($layoutName == `panelConfiguration -query -label $config`) {

string $str = (uiRes("m_saveCurrentPanelLayout.kConfirmDlgMsg"));
string $msg = `format -s $layoutName $str`;
confirmDialog
-title (uiRes("m_saveCurrentPanelLayout.kWarning"))
-message $msg
-button (uiRes("m_saveCurrentPanelLayout.kClose"))
-parent $gMainWindow;
return;
}
}

string $newConfigName = `panelConfiguration -sc false`;
panelConfiguration -edit -label $layoutName $newConfigName;
updatePanelLayoutFromCurrent $layoutName;
//check for windows
string $ifRender = 0;
if (`window -ex "RenderCam"` && `window -q -vis "RenderCam"` == 1){$ifRender = 1;}
string $ifStory = 0;
if (`window -ex "AlphaControl"` && `window -q -vis "AlphaControl"` == 1){$ifStory = 1;}
string $ifGraph = 0;
if (`window -ex "graphEditor1Window"` && `window -q -vis "graphEditor1Window"` == 1){$ifGraph = 1;}
string $ifDope = 0;
if (`window -ex "dopeSheetPanel1Window"` && `window -q -vis "dopeSheetPanel1Window"` == 1){$ifDope = 1;}
string $ifTrax = 0;
if (`window -ex "clipEditorPanel1Window"` && `window -q -vis "clipEditorPanel1Window"` == 1){$ifTrax = 1;}
string $ifOut = 0;
if (`window -ex "outlinerPanel1Window"` && `window -q -vis "outlinerPanel1Window"` == 1){$ifOut = 1;}
string $ifHop = 0;
if (`window -ex "hopWin"` && `window -q -vis "hopWin"` == 1){$ifHop = 1;}
string $ifRef = 0;
if (`window -ex "referenceEditorPanel1Window"` && `window -q -vis "referenceEditorPanel1Window"` == 1){$ifRef = 1;}
string $ifTween = 0;
//if (`window -ex "tweenMachineWin"` && `window -q -vis "tweenMachineWin"` == 1){$ifTween = 1;}
string $ifVGTP = 0;
if (`window -ex "meltGui"` && `window -q -vis "meltGui"` == 1){$ifVGTP = 1;}
string $ifPAIE = 0;
if (`window -ex "PaieGUI"` && `window -q -vis "PaieGUI"` == 1){$ifPAIE = 1;}
string $ifGhost = 0;
if (`window -ex "bhGhost"` && `window -q -vis "bhGhost"` == 1){$ifAnim = 1;}
string $ifTang = 0;
if (`window -ex "autoTangentWin"` && `window -q -vis "autoTangentWin"` == 1){$ifTang = 1;}
string $ifANIP = 0;
string $ifANIP_path = "none";
string $plugList[] = `pluginInfo -q -ls`;
for ($i = 0; $i < size($plugList); $i++) {
if(`pluginInfo -q -n $plugList[$i]` == "AnimSchoolPicker"){
$ifANIP = 1;
$ifANIP_path = `pluginInfo -q -p $plugList[$i]`;
}
}
string $ifPersp = 0;
if (`window -ex "PerspCam"` && `window -q -vis "PerspCam"` == 1){$ifPersp = 1;}
$fileName = ( `internalVar -userScriptDir` + "layout.cfg" );
$fileId=`fopen $fileName "w"`;
fprint $fileId ($layoutName + "\n");
fprint $fileId ($ifRender + "\n");
fprint $fileId ($ifStory + "\n");
fprint $fileId ($ifGraph + "\n");
fprint $fileId ($ifDope + "\n");
fprint $fileId ($ifTrax + "\n");
fprint $fileId ($ifOut + "\n");
fprint $fileId ($ifHop + "\n");
fprint $fileId ($ifRef + "\n");
fprint $fileId ($ifTween + "\n");
fprint $fileId ($ifVGTP + "\n");
fprint $fileId ($ifPAIE + "\n");
fprint $fileId ($ifGhost + "\n");
fprint $fileId ($ifTang + "\n");
fprint $fileId ($ifANIP + "\n");
fprint $fileId ($ifANIP_path + "\n");
fprint $fileId ($ifPersp + "\n");
fclose $fileId;

// special case for top,front,side,persp
//	-make sure they always reset their state.
//
int $i,$nArr;
string $labels[];
$labels = `panelConfiguration -q -labelStrings $newConfigName`;
$nArr = size($labels);
for ($i = 0; $i < $nArr; $i++) {
if (localizedPanelLabel("Persp View") == $labels[$i] ||
localizedPanelLabel("Top View") == $labels[$i] ||
localizedPanelLabel("Side View") == $labels[$i] ||
localizedPanelLabel("Front View") == $labels[$i])
{
panelConfiguration -e -rfs ($i+1) true $newConfigName;
}
}
}
//int $nameCut = `size($layoutName)` - 1;
//string $cutName = `substring $layoutName 1 $nameCut`;
print ("\nSaved \"" + $layoutName + "\" workspace.\n");
}