Advanced Stylist 1.0

// credits to Annieruru
function	script	ValueConvert	{
	set .@num, atoi(""+getarg(0));
	if ( .@num == 0 || .@num >= 2147483647 ) return getarg(0);
	set .@l, getstrlen(""+.@num);
	for ( set .@i,0; .@i < .@l; set .@i, .@i + 1 ) {
		set .@num$, .@num % pow(10,.@i+1) / pow(10,.@i) + .@num$;
			if ( (.@i+1) % 3 == 0 && .@i+1 != .@l ) set .@num$, ","+ .@num$;
	}
	return .@num$;
}


-	script	Stylist	-1,{

	mes .npc_name$;
	mes "I can change your appearance.";
	if( .zeny_size ){
		mes " ";
		mes "^777777[ SERVICES PAYMENT ]^000000";
		for( .@i = 0; .@i < .menu_size; .@i++ )
			if( .npc_mode & ( 1 << .@i ) )
				if( .zeny[.@i] )
					mes "^0055FF"+.menu_name$[.@i]+" : ^777777"+ValueConvert( .zeny[.@i] )+" Zeny^000000";
				else
					mes "^0055FF"+.menu_name$[.@i]+" : ^777777Free of Charge^000000";
	}
	next;
	.@style = ( select( .npc_menu$ ) - 1 );
	.@style_value = getlook( .look_type[.@style] );
	deletearray .@blacklist;
	switch( .@style ){
		Case 0: .@blacklist$ = ","+.blacklist_hairstyle$+","; break;
		Case 1: .@blacklist$ = ","+.blacklist_haircolor$+","; break;
		Case 2: .@blacklist$ = ","+.blacklist_clothe$+","; break;
		default: break;
	}

	.@style_number = .min_style[.@style];

	do{
		next;
		mes .npc_name$;
		mes "Current "+.menu_name$[.@style]+" : ^0055FF"+.@style_number+"th^000000";
		mes " ";
		.@removed = 0;
		if( compare( .@blacklist$,","+.@style_number+"," ) ){
			mes "^FF0000NOTE : This style REMOVED^000000";
			.@removed = 1;
			setlook .look_type[.@style],.min_style[.@style];
		}else{
			setlook .look_type[.@style],.@style_number;
			if( .zeny[.@style] ){
				mes "Cost : ^777777"+ValueConvert( .zeny[.@style] )+" Zeny^000000";
				mes " ";
			}
		}

		.@next = .@style_number + 1;
		.@prev = .@style_number - 1;
		if( .@next > .max_style[.@style] ) .@next = .min_style[.@style];
		if( .@prev < .min_style[.@style] ) .@prev = .max_style[.@style];

		.@select = prompt( "Next - [ ^777777"+.@next+"th Style^000000 ]",
					"Back - [ ^777777"+.@prev+"th Style^000000 ]",
					"Jump to a Style",
					( .@removed )?"":"^0055FFOkay, I want this "+.menu_name$[.@style]+"^000000" );

		switch( .@select ){
			Case 1:	.@style_number = .@next; break;
			Case 2:	.@style_number = .@prev; break;
			Case 3:
				mes "Available Style : ^0055FF"+.min_style[.@style]+" ~ "+.max_style[.@style]+"^000000.";
				input .@style_number,.min_style[.@style],.max_style[.@style];
				break;
			Case 4:
				if( .@style_value == .@style_number ){
					mes "Swt..this is your original hairstyles.";
				} else if( .zeny[.@style] && Zeny < .zeny[.@style] ){
					mes "You dont have enough Zeny to change this "+.menu_name$[.@style]+".";
				}else{
					mes "Enjoy your ^0055FFNEW "+.menu_name$[.@style]+" !!";
					if( .zeny[.@style] )
						Zeny -= .zeny[.@style];
					.@style_value = .@style_number;
				}
			default:
				setlook .look_type[.@style],.@style_value;
				break;
		}
	}while( .@select != 4 && .@select != 255 );
	close;


OnInit:
	// NPC name
	.npc_name$ = "[^0055FF ::: Adv. Stylist ::: ^000000]";

	// NPC Mode ( Bitmask )
	//	1 - Enable Hairstyle
	//	2 - Enable Hair Color
	//	4 - Enable Cloth Color
	.npc_mode = 7;

	// Menu Name
	setarray .menu_name$,
		"Hair Style",
		"Hair Color",
		"Cloth Color";

	// Payment
	setarray .zeny,
		100000,	//	Hairstyle
		0,	//	Hair Color
		35000;	//	Cloth Color

	// Blacklisted Style for each style.
	.blacklist_hairstyle$ = "3,5,7";
	.blacklist_haircolor$ = "2,4,6";
	.blacklist_cloth$ = "143,188,261";

	// Dont edit
	setarray .min_style,getbattleflag( "min_hair_style" ),getbattleflag( "min_hair_color" ),getbattleflag( "min_cloth_color" );
	setarray .max_style,getbattleflag( "max_hair_style" ),getbattleflag( "max_hair_color" ),getbattleflag( "max_cloth_color" );
	.menu_size = getarraysize( .menu_name$ );
	.zeny_size = getarraysize( .zeny );
	setarray .look_type,LOOK_HAIR,LOOK_HAIR_COLOR,LOOK_CLOTHES_COLOR;
	for( .npc_menu$ = ""; .@i < .menu_size; .@i++ )
		.npc_menu$ = .npc_menu$ + ( ( .npc_mode & ( 1 << .@i ) )? .menu_name$[.@i]:"" ) +":";
	end;

}


// NPC Lists
prontera,155,181,5	duplicate(Stylist)	Adv. Stylist#1	878
prontera,155,183,5	duplicate(Stylist)	Adv. Stylist#2	878
prontera,155,185,5	duplicate(Stylist)	Adv. Stylist#3	878
prontera,155,165,5	duplicate(Stylist)	Adv. Stylist#4	878