UKTC Ball Game

/* променливи за характеристиките на падащото топче -
  позиция (x, y), радиус и скорост */
float ballX = 100;
float ballY = 0;
float ballR = 10;
float ballSpeed = 1;

float heroR = 20; // радиус на хващащото топче

int score = 10; // резултат - начален резултат 10

boolean gameOver = false; // променлива, която ни казва дали играта е загубена

void setup(){
  size(600, 600);
  frameRate(200);  // честота на изпъление на draw() - пъти в секунда
}

void draw(){
  if (!gameOver){   // ако играта не е загубена
    background(0);
    fill(255, 255, 0);
    ellipse(mouseX, mouseY, 2*heroR, 2*heroR);
    ellipse(ballX, ballY, 2*ballR, 2*ballR);
    ballY = ballY + ballSpeed;

    // ако падащото топчето достигне долния край на прозореца
    if (ballY > height) {
      score--;
      if (score <= 0){     // ако резултата е <= 0 изпълняваме gameOver
        gameOver = true;
      }
      ballSpeed += 0.1;
      ballY = 0;
      ballX = random(0, width);
    }

    // ако хванем падащото топче
    if (dist(mouseX, mouseY, ballX, ballY) < ballR + heroR){
      score++;
      ballSpeed += 0.1;
      ballY = 0;
      ballX = random(0, width);
    }
    // размер на шрифта
    textSize(30);
    // изписване на текста на определена позиция
    text("Score: " + score, 400, 100);
  } else {      // ако играта е загубена
    background(255);
    text("GAME OVER! Press R to continue...", 50, 300);
    if (keyPressed && key == 'r'){   // ако натиснем клавиша 'r', започваме отначало
      // връщане на началното състояние на играта
      score = 10;
      ballSpeed = 1;
      ballY = 0;
      ballX = random(0, width);
      gameOver = false;
    }
  }
}