label day1:
    title "Day 43" "The end of an ordinary day"
    body john yui
    scene bg school hallway dusk
    show john a_9 at centerright, faceleft
    show phila a_1 at centerleft
    with dissolve
    think "Urgh. What a hassle."

    show john a_3
    voice "voice/lines/Yui 1.opus"
    john "Yes, I understand that you are worried. And I will be on the lookout for your sister."

    show john a_11
    voice "voice/lines/Yui 2.opus"
    john "But I don't think you need to be this worried. You were separated just twenty minutes ago and she's probably still at school."

    show phila a_6
    "I held up my hand to cut off Phila's protest."

    show john a_12
    voice "voice/lines/Yui 3.opus"
    john "Look. The more we argue about this, the less time both of us are looking for her. So let's go try and find her now, okay?"

    show phila a_7 at centerleft, faceleft
    "Phila seemed like she wanted to say more, but grimly nodded and took off to search the next floor."
    hide phila with moveoutleft

    show john a_10
    voice "voice/lines/Yui 4.opus"
    john "...jeez, she's so overprotective. Well... have fun looking for Mina, Yui."

    exspirit john a_0
    hide johnGhost with moveoutright

    scene bg school classroom hallway dusk
    show johnGhost a_0 at center
    with dissolve
    "Yui was a tricky person to possess."

    "No, not because of how she sometimes stayed awake while I did it... that had an easy enough solution."

    "Rather, it's what she {i}didn't{/i} do while I was joyriding her: Paying attention in class and taking immaculate notes."

    think "You'd think of all people, she could take a few hours off the most."

    "The last time I possessed her I felt the sting of hand cramps and uncharacteristic exhaustion, and couldn't help but feel a little guilty when a memory dive revealed them to be due to a late night catch-up session."

    think "I'm an aspiring sorcerer though! I want to spend my time crafting new spells, not paying attention to Ms. Clark's provably wrong physics class!"

    think "Luckily, I found the solution."
    hide johnGhost a_0 with easeoutright
    body circe john

    #fade into door
    scene bg school clubroom dusk
    show circe a_0 at centerleft
    with dissolve
    show johnGhost a_0 at centerright, faceleft with easeinright

    "The only sound inside the room was one of methodical scribbling of pencil on paper. My own body was hunched over a desk and filling out a notebook without pause."

    "The puppet spell was so much more than an on-demand imposter for myself. It knew everything I knew when making it, and it would execute commands as best as it could. It was basically a full blown artificial intelligence!"

    think "And that means I can have it pay attention and write notes for me! With the memory samples I have of how Yui normally writes every day, I can get it to mimic her handwriting and style as well."

    think "I do wonder why it's still writing though..."

    "Curious, I re-entered my body. And instantly regretted it."
    possess john circe a_0

    show john a_4
    john "Argh! My hand!" with hpunch

    "A shooting pain was all that I felt from my right hand, cramping up fiercely the second I regained control."

    show john a_7
    think "You were meant to deliver me from hand cramps, traitor! Not give them to me!"

    show john a_9
    "As I wrung my hand out, I tried to page through the puppet's notes and figure out what went wrong."

    think "Okay, first few pages are mine, good. Next few pages are in Yui's handwriting, so that worked."

    think "Maybe I should get notes as detailed as hers for myself? Something for later."

    show john a_15
    think "Oh, after the notes are... fan fiction?"

    think "I mean I guess Yui {i}does{/i} write fanfiction, now that I think about it. Huh. Memory dumps are weird."

    "Taking stock of the rest of the notebook, I was surprised to see how much was filled out. I {i}did{/i} have some time left until I needed to return the notebook."

    show john a_0
    "My mild interest as to what the artificial intelligence of the puppet had written struggled valiantly against the fact that my hand still had an annoying sting."

    think "This is a pretty mundane problem, which clearly means I should throw more magic at the situation."

    menu:

        "I ignored the pain and began reading what the artificial mind of the puppet had come up with.":
            #scene 1
            call scene_0
            body john john
            scene bg school clubroom dusk
            show john a_15 at centerleft
            with cubeclouds
            think "...what? What on earth is any of this? Did it start writing fiction about myself and the people I know?"

            "Morbid curiosity pushed me onwards."

            #rest of the text
            call scene_1
            scene bg school clubroom dusk
            show john a_14 at centerleft
            with cubeclouds
            think "Why. Why did I read all of this."
            gameover "If you read this without skipping... why?"
            return

        "I decided to morph into someone whose hand wasn't cramping. Maybe even test my new spell.":
            jump AF_custommorph

        "I figured I'd let my hand recover normally and possess another body in the meantime.":
            jump AF_thevoicesjohnthevoices


label AF_custommorph:
    show john a_5
    "Putting the book aside for now, I dug through Yui's things for a small compact mirror I knew she had."
    #john hunched over
    #sfx_rustle

    "The new spell I had created was an offshoot of the transformation spell, and I was eager to try it out again."
    #sfx_rustle

    "In exchange for not targeting a single image or affecting my clothing, I could manually control what I looked like, altering my features as I pleased for the ultimate disguise."

    show john a_6
    john "Ah, there you are."

    "The first drawback was that I needed a mirror while casting it. My features tended to... wander, for lack of a better term, if I wasn't paying attention."

    show john a_0 at left:
        ease 1.0 xpos 0.15
    john "Let's move back a little bit, hold this in my left hand..."

    "The second was the fact that it had a strong tendency to leave me as a woman even with my adjustments."

    show john a_0 at left
    "Something about the sampling from the area I cast it in, and Tina Koya was lopsided towards the fairer sex. The situation at home wasn't any better, either."

    show john a_1
    john "Aaaaaaand, ready."

    "Still, the fact that I had {i}created{/i} a magical spell that noone had done before was pretty good for my ego."

    show pentagram at Position(pos=(placement_of(john).xpos, 0.5)) behind john as pentagram
    play sound sfx_spell
    play music bgm_mirage
    show john a_3
    john "{spell}Stahlge ayantu!{/spell}"

    "The moment the last syllable left my lips a wave of changes hit me all at once. My hair shifted hues and grew long enough to frame my face, cheekbones rose to give me a natural resting smile. As my clothes grew constricting I focused on the mirror in the palm of my hand."
    hide pentagram

    # $ renpy.movie_cutscene("images/mirror_morph.webm", loops=-1)
    show mirror_morph with dissolve

    $ renpy.pause(55, hard=True)
    voice "voice/lines/Morphed 1.opus"
    john "Always weird to watch, but not bad, not bad at all."

    gameover "Still working on full body sprites."
    return


label AF_thevoicesjohnthevoices:
    show pentagram at Position(pos=(placement_of(john).xpos, 0.5)) behind john as pentagram
    play sound sfx_spell
    play music bgm_mirage
    john "{spell}Anima a carne dimittat!{/spell}"

    "Once again the familiar weightlessness overtook me, all other physical sensations fading away. Including my hand cramp."

    exspirit john a_0
    hide pentagram with dissolve

    show johnGhost a_1
    think "Oh wizard powers. You are truly the solution to every problem."

    show johnGhost a_0
    think "Now, who can I kill some time as?"

    hide johnGhost withmoveoutright
    scene bg school classroom hallway dusk
    show mina a_7 at centerleft
    show johnGhost a_0 at centerright, faceleft
    with fade

    "The answer to my rhetorical question happened to be right outside of the door, as a matter of fact."

    voice "voice/lines/Mina 1.opus"
    mina "S-Sister? Phila?"

    "It seemed I had kept my promise to her sister, Mina was darting around like a spooked lamb."

    show johnGhost a_3
    think "And in this scenario, I'm the wolf!"

    possess john mina b_2

    mina "Eep!"

    "A squeak of fright escaped her lips as I took her over, and as I settled in more signs of panic made themselves apparent. Quick breathes and shivers did interesting things to my borrowed chest, but couldn't disguise how wound up she was."

    show john b_6
    voice "voice/lines/Mina 3.opus"
    john "Wow, you're this scared only half an hour apart? I take it back, Phila was right to be worried!"

    "I took a moment to calm her body down and enjoy some deep breathes."

    show john b_1
    voice "voice/lines/Mina 4.opus"
    john "Well, this can be my good deed of today. I'll bring Mina to her sister and then head back."

    voice "voice/lines/Mina 5.opus"
    john "In and out, easy ten minute possession."

    gameover "It wasn't."
    return