#include <amxmodx>
#include <engine>
#include <colorchat>

#define PLUGIN "Revision"
#define VERSION "0.7.1"
#define AUTHOR "Peyote"

#define TASK_ID 352

new target[33], body
new bool:w_trakcie[33]

new czas_rewizji, odleglosc_rewizji

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)

	register_clcmd("+revision", "wlacz_rewizje")
	register_clcmd("-revision", "wylacz_rewizje")
	register_event("Damage", "Damage", "b", "2!=0")
	register_event("CurWeapon","CurWeapon","be", "1=1")
	register_event("ResetHUD", "Spawn", "be")
	czas_rewizji = register_cvar("amx_revision_time", "3")
	odleglosc_rewizji = register_cvar("amx_revision_distance", "80")
}

public plugin_precache()
{
	precache_sound("weapons/c4_disarm.wav")
	precache_sound("weapons/c4_disarmed.wav")
}

public wlacz_rewizje(id)
{
	if(get_user_team(id) != 2)
	{
		ColorChat(id, GREEN, "[Wiezienie]^x01 Musisz byc straznikiem, aby przeszukiwac wiezniow!");
		return PLUGIN_HANDLED;
	}
	if(!is_user_alive(id))
	{
		return PLUGIN_HANDLED
	}

	get_user_aiming(id, target[id], body, get_pcvar_num(odleglosc_rewizji))

	if(!is_user_alive(target[id]))
	{
		ColorChat(id, GREEN, "[Wiezienie]^x01 Musisz podejsc do wieznia!");
		return PLUGIN_HANDLED
	}
	if(get_user_team(target[id]) != 1)
	{
		ColorChat(id, GREEN, "[Wiezienie]^x01 Nie mozesz przeszukiwac straznikow!");
		return PLUGIN_HANDLED
	}

	new p_czas_rewizji = get_pcvar_num(czas_rewizji)

	entity_set_float(id, EV_FL_maxspeed, -1.0)
	set_bartime(id, p_czas_rewizji)
	w_trakcie[id] = true
	emit_sound(id, CHAN_WEAPON, "weapons/c4_disarm.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)

	entity_set_float(target[id], EV_FL_maxspeed, -1.0)
	set_bartime(target[id], p_czas_rewizji)
	w_trakcie[target[id]] = true

	set_task(get_pcvar_float(czas_rewizji), "Pokaz_bronie", TASK_ID+id)

	return PLUGIN_HANDLED
}

public wylacz_rewizje(id)
{
	if(get_user_team(id) != 2 || !w_trakcie[id])
		return PLUGIN_HANDLED

	entity_set_float(id, EV_FL_maxspeed, 250.0)
	set_bartime(id, 0)
	w_trakcie[id] = false
	remove_task(TASK_ID+id)

	if(!is_user_alive(target[id]))
		return PLUGIN_HANDLED

	entity_set_float(target[id], EV_FL_maxspeed, 250.0)
	set_bartime(target[id], 0)
	w_trakcie[target[id]] = false

	return PLUGIN_HANDLED
}


public Pokaz_bronie(id)
{
	id -= TASK_ID
        if(!is_user_alive(target[id])) return;
	new weapons[32], numweapons
	new weaponname[33]
	get_user_weapons(target[id], weapons, numweapons)
	ColorChat(id, GREEN, "Znalazles:");
	for(new i=0; i<numweapons; i++)
	{
		get_weaponname(weapons[i], weaponname, 32)
		replace_all(weaponname, 32, "weapon_", "")
		replace_all(weaponname, 32, "knife", "")
		ColorChat(id, BLUE, weaponname)
	}
	wylacz_rewizje(id)
	emit_sound(id, CHAN_WEAPON, "weapons/c4_disarmed.wav", 1.0, ATTN_NORM, 0, PITCH_NORM)
}

public Damage(id)
{
	if(w_trakcie[id])
		wylacz_rewizje(id)
}

public CurWeapon(id)
{
	if(w_trakcie[id])
		entity_set_float(id, EV_FL_maxspeed, -1.0)
}

public Spawn(id)
{
	w_trakcie[id] = false
}

public set_bartime(id, czas)
{
	message_begin(MSG_ONE, get_user_msgid("BarTime"), _, id)
	write_short(czas)
	message_end()
}