Scriptname WZONES_Bulwark_Armory extends ObjectReference
;Script Authors: GrandBulwark and Deapri

;Version History
;2015.2 FINAL - Moved catch and renamed some properties to prevent breaking the script, removed unecessary check on the WzonesArmory Gval.  That variable is determined by toggling Deapri's option in the previous script, so it will always be set prior to this script running.  Script cleaned up and process explained in comments.
;2015.2 Beta - Added catch to prevent improper values from effecting the armory's distribution and a trace to tell on users who may have done so.
;1.6 - Added backpack Global
;1.5 - Complete Overhaul bringing a 400 line script down to what you see here.  Going this way ensures that NO future work will need to be done to this script.  All patches/addons that use the outfits I(GrandBulwark) made for WZones will automatically conform to the McM Toggle.
;1.4 - Declared two new Gvars to Implement failsafe for potentially missed outfits.  It would have been better had we used that method to begin with for the entire thing but hey, wouldn't have learned as much.  Commented out the Imperial and Stormcloak soldiers; we no longer need to swap their outfits.
;1.3 - Fixed missing Imperial Soldiers from the vanilla outfit toggle
;1.2 - Added Vspawners
;1.1 - Added missing Imperial Soldier
;1.0 - Initial Release

;General Properties
GlobalVariable Property WZonesArmory Auto ; Should not be altered or check for accuracy in this script.  This value is set by the users choice in the McM menu; and it's configuration is handled there.  We only use it as a check here.
GlobalVariable Property WZonesArmoryModded Auto ; Should be set to 0 when Armory is on, 100 when off !SHOULD not be altered to any other parameter!
GlobalVariable Property WZonesArmoryVanilla Auto ; Should be set to 100 when armory is on, 0 when off !SHOULD not be altered to any other parameter!
GlobalVariable Property WZonesBackPacks Auto ; Should be set to 95 when the armory is on, 100 when off !COULD be set to other values but WILL be reset and trigger the catch so it's best left alone!

;Dev Properties
GlobalVariable Property WZonesArmoryTestChestChance Auto ; Should be set to 100 by all but developers
GlobalVariable Property WZonesArmoryDebugMode Auto ; Should be set to 0 by all but developers and should not be configurable via any script.
GlobalVariable Property WZonesArmoryBookGlobal Auto ; Used once in this script to completely disable the spawns of the Crafting Overwrite Book to thin out the test chest.

WZones_MCM Property sWZMCM Auto ; changed to sWZMCM due to property name conflict which was preventing the script from initializing.

State WZArmorySwitch ;State and Global Variable "WZonesArmory" are determined in the WZones_MCM script
		Event OnBeginState()
            If GetState() == "WZArmorySwitch" ;State is determined in the McM Script, as is the Gval "WZonesArmory"
				;General User Options: The first thing we check for here is if our values have been altered.  Setting a NO SPAWN chance via console to an INVALID value(Anything less that 100 or greater than 1) will result in naked NPCs.  Players will NEVER see this step without altering the values in their console.
				If WZonesBackPacks.GetValueInt() != 100 && WZonesBackPacks.GetValueInt() != 95 || WZonesArmoryVanilla.GetValueInt() != 0 && WZonesArmoryVanilla.GetValueInt() != 100 || WZonesArmoryModded.GetValueInt() != 0 && WZonesArmoryModded.GetValueInt() != 100 ; Translates roughly to if any value is not what the script expects, reset then and scold the user while informing the authors in the logs

					WZonesArmoryModded.SetValue(0) ; Sets the WARZONES armory spawn list's NO SPAWN chance to 0(Will Spawn)
					WZonesArmoryVanilla.SetValue(100); Sets the VANILLA armory spawn list's NO SPAWN chance to 100(Will NOT Spawn)
					WZonesBackPacks.SetValue(95) ; Sets the WARZONES Backpack spawn list's NO SPAWN chance to 95(5% chance to Spawn)

					;Messages and Debug telling the user, and us if they've messed anything up and how to fix it.
					Debug.MessageBox("Dear User, while we are delighted that you have a mind to alter your own game we must ask you to refrain from altering armory global values in the cosole.  This can break the armory's distribution entirely and we frankly don't need any needless bug reports.  Kill any WARZONES NPCs you've loaded recently, or reset your world cells to prevent naked NPCs. Thanks -Warzones 2015 team")
					Debug.Trace("WZONES ARMORY: Tampering with values detected inform user not to mess with Gvals regarding armory, distribution scripts reset.  Ignore reports of naked NPCs.")

				;This check initiates it's functions if the user chose to turn the Armory OFF in McM.
				Elseif WZonesArmory.GetValueInt() == 0 ; User turned OFF the armory in MCM(0=OFF)

					WZonesArmoryModded.SetValue(100) ; Sets the WARZONES armory spawn list's NO SPAWN chance to 100(Will NOT Spawn)
					WZonesArmoryVanilla.SetValue(0) ; Sets the VANILLA armory spawn list's NO SPAWN chance to 0(Will Spawn)
					WZonesBackPacks.SetValue(100) ; Sets the WARZONES Backpack spawn list's NO SPAWN chance to 100(Will NOT Spawn)
					Debug.MessageBox("WARZONES Armory OFF")

				;This check initiates it's functions if the user chose to turn the Armory ON in McM.  It is also the game's default starting state before the script is run.
				Elseif WZonesArmory.GetValueInt() == 1 ; User turned ON the armory in MCM(1=ON)

					WZonesArmoryModded.SetValue(0) ; Sets the WARZONES armory spawn list's NO SPAWN chance to 0(Will Spawn)
					WZonesArmoryVanilla.SetValue(100) ; Sets the VANILLA armory spawn list's NO SPAWN chance to 100(Will NOT Spawn)
					WZonesBackPacks.SetValue(95) ; Sets the WARZONES Backpack spawn list's NO SPAWN chance to 95(5% chance to Spawn)
					Debug.MessageBox("WARZONES Armory ON")

				Else
				Endif
				;Dev Use Only from here on
				If WZonesArmoryDebugMode.GetValueInt() == 1 ; WZonesArmoryDebugMode is not altered with any script.  It must be set with console commands and is NOT intended for users.

					;First we turn the chest on and our books and backpacks off and warn anyone this is an invasive option intended to debug the armory only
					WZonesArmoryTestChestChance.SetValue(0) ; The chest will spawn one potential armor configuration based upon if the armory is on/off.  If ON there should be 10 full sets of Warzones added armors.  If off there should be 10 vanilla full sets of vanilla armor.  Support items like weapons and loot will spawn regardless.
					WZonesArmoryBookGlobal.SetValue(100) ; The WARZONES armory book is disabled here to thin the test chests clutter
					WZonesBackPacks.SetValue(100) ; The WARZONES backpacks are also disabled to thin clutter.
					Debug.MessageBox("WZARMORY Toggle Test Chest is active; if you are NOT a developer STOP altering random Gvars in the console...  Enter Set WZonesArmoryDebugMode to 0 in the console and then toggle the armory to your desired setting in McM.") ; Should never be seen if you are not a developer


				Elseif WzonesArmoryDebugMode.GetValueInt() != 1

					WZonesArmoryTestChestChance.SetValue(100)
					;We do not restore our book global here purposely both to show off the fancy McM option Deapri whipped up, and because this is dev use only
					;here we stay silent so no one know there is a disabled option, we don't want them hunting for it as they might be a bit let down if they did find it.

				Else
				Endif
			Else
            Endif
        EndEvent
EndState