auto ban removal

alias -l Sets {
  ;edit %params to add *wildcardmasks*|seconds|network|#channel . Seperate multiple entries with a space.
  ;example ~q:*|86400|FordIRC|#FordIRC *@*|604800|MindForge|#mIRC
  ;This will remove bans that start with ~q:* after 2 days(86400 seconds) on network FordIRC in channel #FordIRC
  ;And bans That match *@* after 1 week(604800 seconds)
  return ~q:*|86400|FordIRC|#FordIRC
}
alias -l BanRemoveTimerStart {
  var %chan $1, %banmask $2
  tokenize 32 $Sets
  BanRemoveTimer %chan %banmask $*
}
alias -l BanRemoveTimer {
  var %chan $1, %banmask $2
  tokenize 124 $3
  if ($1 iswm %banmask && $4 == %chan && $network == $3) {
    .timer $+ %banmask $+ %chan 1 $2 mode $4 -b %banmask
  }
}
alias BanRemoveTimerConnect {
  var %chan $1
  tokenize 32 $Sets
  BanRemoveTimerRestart %chan $*
}
alias -l BanRemoveTimerRestart {
  var %chan $1, %bancount $ibl(%chan,0)
  tokenize 124 $2
  while (%bancount) {
    if ($1 iswm $ibl(%chan,%bancount) && $4 == %chan && $network == $3) {
      if ($calc($ctime - $ibl(%chan,%bancount).ctime) >= $2) mode $4 -b $ibl(%chan,%bancount)
      else .timer $+ $ibl(%chan,%bancount) $+ %chan 1 $calc($2 - ($ctime - $ibl(%chan,%bancount).ctime)) mode $4 -b $ibl(%chan,%bancount)
    }
    dec %bancount
  }
}
On @*:ban:#: BanRemoveTimerStart # $banmask
On *:join:#: {
  if ($nick == $me) {
    .mode # +b
    .timer 1 60 BanRemoveTimerConnect #
  }
}
raw 367:*: haltdef
raw 368:*: haltdef