AV for Handschuh

#include <renderer/RenderSetup.hlsl>

struct VS_INPUT
{
   float3 ssPosition   : POSITION;
   float2 texCoord     : TEXCOORD0;
   float4 color        : COLOR0;
};

struct VS_OUTPUT
{
   float2 texCoord     : TEXCOORD0;
   float4 color        : COLOR0;
   float4 ssPosition   : SV_POSITION;
};

struct PS_INPUT
{
   float2 texCoord     : TEXCOORD0;
   float4 color        : COLOR0;
};

sampler2D       baseTexture;
sampler2D       depthTexture;
sampler2D       normalTexture;

cbuffer LayerConstants
{
    float        startTime;
    float        amount;
};

/**
* Vertex shader.
*/
VS_OUTPUT SFXBasicVS(VS_INPUT input)
{

   VS_OUTPUT output;

   output.ssPosition = float4(input.ssPosition, 1);
   output.texCoord   = input.texCoord + texelCenter;
   output.color      = input.color;

   return output;

}

float2 clamp_tex2D( sampler2D tex, float2 coord )
{
    // TODO: remove this and fix sampler using wrapped instead of clamped addressing for depthTexture
    return tex2D( tex, clamp( coord, float2( 0.001, 0.001 ), float2( 0.999, 0.999 ) ) );
}

const float4 edgeColorOrange = float4(1.0, 0.05, 0.0, 0);
const float4 edgeColorDarkOrange = float4(0.3, 0.08, 0.0, 0);
const float4 edgeColorGreen = float4(0.0, 0.8, 0.0, 0);
const float4 edgeColorDarkGreen = float4(0.02, 0.15, 0.01, 0);
const float4 edgeColorDarkGreen2 = float4(0.02, 0.25, 0.01, 0);

const float4 edgeColor2 = float4(1.0, 1.0, 1.0, 0) * 0.15;

float4 SFXDarkVisionPS(PS_INPUT input) : COLOR0
{
    float2 texCoord = input.texCoord;
    float4 inputPixel = tex2D(baseTexture, texCoord);

    if (amount == 0) // AV off - nothing else to see here
    {
        return inputPixel;
    }

    float2 depth1 = tex2D(depthTexture, input.texCoord).rg;

    // Flashlight on
    float offset = 0.0006;   // width of the silhoutte around units

    //sample the difference in distance of nearby pixel to create a depth map
    float depth2 = clamp_tex2D(depthTexture, texCoord + float2(-offset, -offset)).r;
    float depth3 = clamp_tex2D(depthTexture, texCoord + float2(-offset,  offset)).r;
    float depth4 = clamp_tex2D(depthTexture, texCoord + float2( offset, -offset)).r;
    float depth5 = clamp_tex2D(depthTexture, texCoord + float2( offset,  offset)).r;

    float edge =
            abs(depth2 - depth1.r) +
            abs(depth3 - depth1.r) +
            abs(depth4 - depth1.r) +
            abs(depth5 - depth1.r);

    edge = clamp(pow(edge, 2), 0, 1);

    // diminish with distance
    float fadeout = pow(2, -depth1.r * 0.2 + 0.2);

    if (depth1.g > 0.5) // entities
    {

        //if (depth1.r < 0.4) // view model
        //{
        //    return inputPixel;
        //}

        float4 edgeColor;
        if ( depth1.g > 0.9 ) // gorges
        {
            return inputPixel * 0.5 + edgeColorDarkGreen2 * edge;
        }
        else if ( depth1.g > 0.8 ) // aliens
        {
            return inputPixel * 0.5 + edgeColorDarkGreen * edge;
        }
        else // targets and world ents
        {
            return inputPixel * 0.5 + edgeColorGreen * (edge + 0.007);
        }
    }
    else // world geometry
    {
        if (depth1.g > 0) // view model
        {
            return inputPixel * 0.3;
        }
        edge = edge * step( depth1.r, 100 ); // no edges for skyboxes
        return inputPixel * 0.05 + (edgeColor2 * edge * fadeout);
    }
}