# Maintainer: Bhushan Shah <bshah@kde.org>
# Contributor: Gustavo Alvarez <sl1pkn07@gmail.com>
_pkgname=user-manager
pkgname=user-manager-git
pkgver=r274.e74e910
pkgrel=1
pkgdesc="A simple system settings module to manage the users of your system (GIT version)"
url='https://projects.kde.org/user-manager'
arch=('i686' 'x86_64')
license=('GPL' 'LGPL' 'FDL')
depends=('libpwquality' 'kio')
makedepends=('extra-cmake-modules' 'kdoctools' 'git')
conflicts=('kcm-user-manager' 'user-manager')
provides=('kcm-user-manager' 'user-manager')
replaces=('kcm-user-manager-git')
groups=('plasma')
source=("git+https://invent.kde.org/plasma/${_pkgname}.git")
sha1sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cmake -B build -S "${srcdir}/${_pkgname}" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
}