ulauncher

pkgname=ulauncher
pkgver=5.9.0
pkgrel=1
pkgdesc="Application launcher for Linux"
arch=('any')
url="https://ulauncher.io"
license=('GPL3')
depends=('libkeybinder3' 'gtk3' 'webkit2gtk' 'libnotify' 'gdk-pixbuf2' 'python-dbus'
         'python-levenshtein' 'python-pyinotify' 'python-websocket-client'
         'python-xdg' 'python-gobject')
makedepends=('python-distutils-extra')
checkdepends=('desktop-file-utils')
optdepends=('libappindicator-gtk3: tray icon'
            'wmctrl: fix window focus on Wayland')
install="$pkgname.install"
source=("https://github.com/Ulauncher/Ulauncher/releases/download/$pkgver/${pkgname}_${pkgver}.tar.gz"
        "https://github.com/Ulauncher/Ulauncher/raw/$pkgver/contrib/systemd/$pkgname.service")
sha256sums=('8d10ab9097235070dddf017e1e4c60d10696ed880887bcccfca6784c01fce3f5'
            'acf583f52933c0f01fb02a64f4103b235c1780d2203e644ed1c7033c22fde4a2')

prepare() {
    cd "$srcdir/$pkgname"
    find -iname "*.py" | xargs sed -i 's=\(^#! */usr/bin.*\)python3 *$=\1python='
}

build() {
    cd "$srcdir/$pkgname"
    python setup.py build
}

check() {
    cd "$srcdir/$pkgname"
    desktop-file-validate "build/share/applications/$pkgname.desktop"
}

package() {
    cd "$srcdir/$pkgname"

    # https://github.com/Ulauncher/Ulauncher/issues/521
    install -Dm644 "build/share/applications/$pkgname.desktop" -t \
        "$pkgdir/usr/share/applications"

    export PYTHONHASHSEED=0
    python setup.py install --root="$pkgdir" --optimize=1 --skip-build

    install -Dm644 "$srcdir/$pkgname.service" -t "$pkgdir/usr/lib/systemd/user"
}