Residial ial for mIRC + realname identifier

;Residual Info by Ford_Lawnmower (
alias -l LengthOfStorage {
  ;The time here will determine how long the address and realname will be stored.
  ;s = second, m = minute, h = hour, d = day, w = week, y = year
  ;Note that the hashtable is not saved and will clear when you close mIRC
  return $duration(1d)
}
alias -l ialupdateCheck {
  inc -z $+(%,ialupdateCheck,$network) $iif($calc($nick($1,0) / 2),$v1,5)
  ;If your ial is already being updated on join, comment .who $1 out.
  ;If you are using /names to update ial you will still need this line.
  .who $1
}
;$realname identifier by Ford_Lawnmower
;Usage $realname(nickname)
;Example /mode #mychan +b ~r:* $+ $realname(fred) $+ *
alias RealName {
  var %info $iif($ial($1).mark,$v1,$hget(Oldinfo,$1))
  noop $regex(%info,/realname=([^\s]*)/)
  return $iif($regml(1),$v1,0)
}
;Usage $addy(Nickname,addresstype) ie. $addy(Fred,2)
alias addy {
  if ($address($1,$2)) return $v1
  else {
    var %info $iif($ial($1).mark,$v1,$hget(Oldinfo,$1)), %type $iif($2 > 9,9,$2)
    noop $regex(%info,/addy=([^\s]*)/)
    var %nick $gettok($regml(1),1,33), %ident $gettok($gettok($regml(1),2,33),1,64),%ip $gettok($gettok($regml(1),2,33),2,64)
    if (%nick) goto %type
    else return
    :1
    return $+(*!*,%ident,@,%ip)
    :2
    return $+(*!*@,%ip)
    :3
    return $+(*!*,%ident,@,%ip)
    :4
    return $+(*!*@,%ip)
    :5
    return $+(%nick,!,%ident,@,%ip)
    :6
    return $+(%nick,!*,%ident,@,%ip)
    :7
    return $+(%nick,!*@,%ip)
    :8
    return $+(%nick,!*,%ident,@*,%ip)
    :9
    return $+(%nick,!*@*,%ip)
  }
}
raw 352:*: {
  if ($($+(%,ialupdateCheck,$network),2)) haltdef
  .ialmark $6 $addtok($ial($6).mark,$+(realname=,$replace($9-,$chr(32),_)),32)
  .ialmark $6 $addtok($ial($6).mark,$+(addy=,$+($6,!,$3,@,$4)),32)
}
raw 315:*: if ($($+(%,ialupdateCheck,$network),2)) haltdef
On me:join:#: .timer 1 1 ialupdateCheck #
on *:join:#: .timer 1 1 ialupdateCheck $nick
on *:part:#: hadd $+(-mu,$lengthofstorage) Oldinfo $nick $ial($nick).mark
on *:quit: hadd $+(-mu,$lengthofstorage) Oldinfo $nick $ial($nick).mark
on *:kick:#: hadd $+(-mu,$lengthofstorage) Oldinfo $knick $ial($knick).mark
alias ialmark_ {
  var %item $2
  if ($isid) {
    if ($regex($ial($1).mark,/ $+ %item $+ =([^\x01]*)/i)) return $regml(1)
  }
  else {
    var %value $3-
    if (!$regex($ial($1).mark,/ $+ %item $+ =[^\x01]*/i)) {
      .ialmark $1 $addtok($ial($1).mark,$+(%item,=,%value),1)
    }
    else {
      .ialmark $1 $regsubex($ial($1).mark,/( $+ %item $+ =[^\x01]*)/i,$+(%item,=,%value))
    }
  }
}