#NoEnv
#KeyHistory 0
#SingleInstance force
ListLines Off
Process, Priority, , H
SetBatchLines, -1
SetKeyDelay, -1, -1
SetMouseDelay, -1
SetDefaultMouseSpeed, 0
SetWinDelay, -1
SetControlDelay, -1

running = 0

; screen res = 1284, 752

updateChk := [[1151,155,0xF6ECD5]]
partyChk := [[1011,212,0x00C8FF]]
fullChk := [[628,493,0xFEFCF8]]
prepChk := [[1175,581,0x0707CD]]
disbandChk := [[519,278,0x3A3A3A],[615,286,0x3E3E3E],[765,276,0x535353],[701,281,0x5B5B5B]]
ingameChk := [[478,325,0x575757],[504,328,0x434343]]
disconChk := [[532,334,0xEEEBE6],[685,364,0xC6BBAA],[630,451,0xE6E5F1]]
winChk := [[35,88,0xFFFFFF],[74,119,0xFFFFFF],[153,80,0xFFFFFF],[193,120,0xFFFFFF],[143,76,0xFFFF57]]
specatkChk := [[974,666,0xF0E8CB]]
regatkChk  := [[1165,645,0xEAE9E9]]
repeatChk := [[601,537,0xFFFFFF], [681,539,0xFFFFFF]]

ToolTip, Digimon Script Started
Sleep, 1000
ToolTip

mainloop:
loop {
if(running) {
; ======================================================== Main Loop Start ========================================================

; ================== Start In Party Finder =================
ToolTip, looking for match, 64, 256
while(!opt_chk(prepChk)) {
	; if a party is found
	if(opt_chk(partyChk)) {
		; click party
		move_click(1011, 212)
		; wait 1 second
		Sleep, 1000
		; check if party is full and click if it is
		if(opt_chk(fullChk))
			move_click(628, 493)
	}

	; if no party is found, check if can update and click if possible
	else if(opt_chk(updateChk))
		move_click(1151, 155)

	Sleep, 64
}

; ================== When In Party Lobby =================
; click the prepChk
move(1175, 581)
start := A_TickCount

ToolTip, Waiting for match to start, 64, 256
while(!opt_chk(ingameChk)) {
	if(opt_chk(disbandChk)){
		move_click(640, 500)
		Sleep, 2000
		continue mainloop
	} if (afk_check(start)) {
		move_click(1180, 70)
		Sleep, 1000
		continue mainloop
	} if (opt_chk(prepChk))
		click()
}
; ==================== In Combat Screen ==================

ToolTip, Waiting for match to end, 64, 256
while(!opt_chk(winChk)) {
	if(opt_chk(specatkChk)) {
		move_click(974,666)
		Sleep, 128
		click()
		Sleep, 1000
	}else if(opt_chk(regatkChk)) {
		move_click(1165,645)
		Sleep, 128
		click()
		Sleep, 1000
	}else if(opt_chk(disconChk)) {
		ToolTip, Player disconnected going to lobby, 64, 256
		move_click(640, 450)
		Sleep, 10000
		move_click(1180, 660)
		Sleep, 1000
		move_click(900, 224)
		Sleep, 1000
		move_click(900, 300)
		Sleep, 1000
		move_click(990, 650)
		Sleep, 1000
		move_click(500, 340)
		continue mainloop
	}
}
; ==================== Post Game Summary ==================
ToolTip, Skipping Summary, 64, 256
move(660, 635)

while(!opt_chk(repeatChk))
	click() ; skips through summary until end

;clicks repeat
move_click(650, 470)

;clicks join
Sleep, 1000
move_click(500, 340)

; ========================================================= Main Loop End =========================================================
}
}

End::
running := 1 - running
if(!running) {
	ToolTip, Paused after loop
	Sleep, 1000
	ToolTip
}
return

^+End::
TrayTip, Script Ended, digimon script has been closed
exitapp
return

afk_check(start) {
	if(A_TickCount - start > 60000)
		return 1
	return 0
}

opt_chk(arr) {
	for key in arr {
		PixelGetColor, color, arr[key, 1], arr[key, 2]
		if(color != arr[key, 3])
			return 0
	}
	return 1
}

move(x2, y2) {
	MouseMove, x2, y2
}

move_click(x2, y2) {
	move(x2, y2)
	click()
}

click() {
	DllCall("mouse_event", "UInt", 2)
	Sleep, 64
	DllCall("mouse_event", "UInt", 4)
	Sleep, 64
}