flycast-git-2.2.r37.g552e5b7d7-1

# Maintainer: Manuel <mdomlop@gmail.com>

_pkgname=flycast
pkgname=$_pkgname-git
pkgver=2.2.r37.g552e5b7d7
pkgrel=1
pkgdesc='A multiplatform Sega Dreamcast, Naomi, Naomi 2 and Atomiswave emulator'
arch=(x86_64 i686 armv7h aarch64)
url='https://github.com/flyinghead/flycast'
license=(GPL2)
depends=(alsa-lib curl gcc-libs glibc hicolor-icon-theme libao libpulse libzip lua miniupnpc zlib)
makedepends=(cmake git libgl ninja xxhash)
provides=($_pkgname)
conflicts=($_pkgname)
source=($_pkgname::git+$url.git
    breakpad::git+https://github.com/flyinghead/mingw-breakpad.git
    glslang::git+https://github.com/KhronosGroup/glslang.git
    libchdr::git+https://github.com/flyinghead/libchdr.git
    luabridge::git+https://github.com/vinniefalco/LuaBridge.git
    SDL::git+https://github.com/libsdl-org/SDL.git
    Vulkan-Headers::git+https://github.com/KhronosGroup/Vulkan-Headers.git
    VulkanMemoryAllocator::git+https://github.com/GPUOpen-LibrariesAndSDKs/VulkanMemoryAllocator.git
)
md5sums=('SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP' 'SKIP')

pkgver() {
    cd $_pkgname
    git describe --long --tags | sed -E 's/^[Vv]//;s/([^-]*-g)/r\1/;s/-/./g'
}

prepare() {
    cd $_pkgname
    git submodule init
    for submod in breakpad glslang libchdr luabridge SDL Vulkan-Headers VulkanMemoryAllocator
    do
        git config "submodule.core/deps/$submod.url" "../$submod"
        git -c protocol.file.allow=always submodule update -- "core/deps/$submod"
    done
}

build() {
    cd $_pkgname
    cmake -B build -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX='/usr' -G Ninja
    cmake --build build --config Release
}

package() {
    cd $_pkgname
    DESTDIR="$pkgdir" cmake --install build --config Release
}