* DELINEAMENTO E ANÁLISE DE EXPERIMENTOS
* DELINEAMENTOS FATORIAIS COMPLETAMENTE CASUALIZADOS
* PROF. GEORGE VON BOORRIES
* EXEMPLO RETIRADO DE LAWSON, J. (2010). DESIGN AND ANALYSIS
*   OF EXPERIMENTS WITH SAS. CRC Press.
    Fonte: Hunter, J.S. (1989). Let's all beware the latin square.
    Quality Engineering, 1, 453-465;

OPTIONS NODATE NOLABEL NONUMBER;

* Determinando a ordem de observação (casualizando);

TITLE 'ORDEM DOS EXPERIMENTOS';

proc factex;
  factors A B / nlev=3;
  model estimate = (A|B);
  output out=dcomb randomize designrep=3
  A nvals=(0.1 0.2 0.3)
  B nvals=(14 15 16); run;

proc print data=dcomb; run;

* ANALISE FATORIAL - COM REPETIÇÃO;
DATA FUEL;
  DO A = 0.1 TO 0.3 BY 0.1;
    DO B = 14 TO 16 BY 1;
        DO R = 1 TO 2 BY 1;
        INPUT Y @@;
        OUTPUT;
        END;
    END;
  END;
DATALINES;
66 62 72 67 68 66 78 81
80 81 66 69 90 94 75 78
60 58
;

PROC PRINT DATA=FUEL; RUN;

TITLE 'ANALISE FATORIAL';

ODS GRAPHICS ON;
PROC GLM DATA=FUEL;
  CLASS A B;
  MODEL Y = A B A*B / SOLUTION;
  LSMEANS A B A*B;
  ESTIMATE '0.3 VS 0.1' A -1 0 1;
  ESTIMATE '16 VS 14'   B -1 0 1; RUN;
ODS GRAPHICS OFF;

* DETERMINANDO PODER E N COM BASE NAS MEDIAS ESPERADAS;

data FUELM;
  input A B MAB;
  datalines;
0.1 14  64
0.1 15  69.5
0.1 16  67
0.2 14  79.5
0.2 15  80.5
0.2 16  67.5
0.3 14  92
0.3 15  76.5
0.3 16  59
;

title 'NÚMERO DE REPETIÇÕES';

proc glmpower data=FUELM;
      class A B;
      model MAB = A B A*B;
      contrast "A1 VS A2 E A3" A   2 -1 -1;
      contrast "A1 VS A2"      A   1 -1 0;
      contrast "B2 VS B3"      B   0 1 -1;
      power
         nfractional
         stddev      = 2.27
         alpha       = 0.01
         ntotal      = .
         power       = 0.95;
      plot x=power min=.70 max=.95; run;

title 'PODER DO TESTE';

proc glmpower data=FUELM;
      class A B;
      model MAB = A B A*B;
      contrast "A1 VS A2 E A3" A   2 -1 -1;
      contrast "A1 VS A2"      A   1 -1 0;
      contrast "B2 VS B3"      B   0 1 -1;
      power
         nfractional
         stddev      = 2.27
         alpha       = 0.01
         ntotal      = 9
         power       = .;
      plot x=n min=9 max=18;
run;

TITLE1 'ANALISE COM R=1';

TITLE2 'POLINOMIOS ORTOGONAIS';

PROC MEANS DATA=FUEL NOPRINT;
    BY A B; VAR Y;
    OUPUT OUT=FUEL1 MEAN=YMEAN; RUN;

PROC GLM DATA=FUEL1;
    CLASS A B;
    MODEL YMEAN = A B A*B; RUN;

PROC IML;
  T={14 15 16};
    C=ORPOL(T);
    PRINT C;
    CLL = (C[,2] * C[,2]`)`;
    CLQ = (C[,2] * C[,3]`)`;
    CQL = (C[,3] * C[,2]`)`;
    CQQ = (C[,3] * C[,3]`)`;
    PRINT CLL CLQ CQL CQQ; QUIT;

PROC GLM DATA=FUEL1;  * PROBLEMA 1;
    CLASS A B;
    MODEL YMEAN = A B A*B;
    CONTRAST 'LL' A*B  0.5 0 -0.5
                       0   0  0
                      -0.5 0  0.5; RUN; QUIT;

PROC GLM DATA=FUEL1;  * PROBLEMA 2;
    CLASS A B;
    MODEL YMEAN = A B;
    CONTRAST 'LL' A*B  0.5 0 -0.5
                       0   0  0
                      -0.5 0  0.5; RUN; QUIT;

* DECOMPOSIÇÃO DA SOMA DE QUADRADOS;

PROC GLM DATA=FUEL1;
    CLASS A B;
    MODEL YMEAN = A B A*B;
    CONTRAST 'LL' A*B   1  0 -1
                        0  0  0
                       -1  0  1;
    CONTRAST 'LQ' A*B  -1  0  1
                        2  0 -2
                       -1  0  1;
    CONTRAST 'QL' A*B  -1  2 -1
                        0  0  0
                        1 -2  1;
  CONTRAST 'QQ' A*B   1 -2  1
                     -2  4 -2
                      1 -2  1; RUN;

DATA IAB;
 MSLL = (324/1)/(15/3);
 PV = 1 - PROBF(MSLL,1,3); RUN;

PROC PRINT DATA=IAB; RUN;

TITLE '';

PROC SGPLOT DATA=FUEL1;
  SCATTER X=B Y=YMEAN / GROUP=A;
  REG X=B Y=YMEAN / GROUP=A;
  YAXIS LABEL = "EM. DE COMBUSTIVEL"; RUN;