YWOTPaste FIXED

(*
str_replace by Bruce Phillips from MacScripter
http://macscripter.net/viewtopic.php?id=18551
*)


-- find : Text (or list of text) to be found
-- replace : Text (or list of text) to replace with
-- subject : Text (or list of text) to be searched
on str_replace(find, replace, subject)
    set prevTIDs to text item delimiters of AppleScript
    set returnList to true

    -- This wouldn't make sense (you could have it raise an error instead)
    if class of find is not list and class of replace is list then return subject

    if class of find is not list then set find to {find}
    if class of subject is not list then ¬
        set {subject, returnList} to {{subject}, false}

    set findCount to count find
    set usingReplaceList to class of replace is list

    try
        repeat with i from 1 to (count subject)
            set thisSubject to item i of subject

            repeat with n from 1 to findCount
                set text item delimiters of AppleScript to item n of find
                set thisSubject to text items of thisSubject

                if usingReplaceList then
                    try
                        item n of replace
                    on error
                        "" -- `replace` ran out of items
                    end try
                else
                    replace
                end if

                set text item delimiters of AppleScript to result
                set thisSubject to "" & thisSubject
            end repeat

            set item i of subject to thisSubject
        end repeat
    end try

    set text item delimiters of AppleScript to prevTIDs
    if not returnList then return beginning of subject
    return subject
end str_replace


(*
This script pastes whatever myPaste is set to into YWOT, with enter.

Please don't use this to grief.
*)

set myPaste to "" --paste stuff here or just set to the clipboard
set keystrokeSpeed to 0.1 --set to 0.2 if some letters are skipped while pasting into YWOT

set myExplodedPaste to str_replace("
", return, every character of myPaste)

set i to 0

display dialog "This will take approximately " & (length of myPaste * keystrokeSpeed) & " seconds to complete."

if the button returned in the result is "OK" then
    tell application "Safari"
        activate
        tell application "System Events"
            repeat length of myPaste times
                set i to i + 1
                key down item i of myExplodedPaste
                key up item i of myExplodedPaste
                delay keystrokeSpeed
            end repeat
            key down return
            key up return
        end tell
    end tell
end if