; Edit log_file to your Client.txt path.
; Your game needs to be in windowed fullscreen mode.
log_file = G:\Games\Path of Exile\logs\Client.txt
overlay_x := 910
overlay_y := 550
sound_lich =  lich.wav
sound_no_lich = lich_none.wav

; Shouldn't need to edit below this line.
filehandle := FileOpen(log_file, "r")
if !IsObject(filehandle) {
    MsgBox Error while opening Path of Exile's Client.txt.
}
filehandle.seek(0, 2)

overlay_color = 000000
Gui, Color, %overlay_color%
Gui, 1:Margin , 0, 0
Gui, Font, s10 bold, fontin
Gui, Add, Text, Center vLich w100 cC49964 BackgroundTrans,
Gui +LastFound +AlwaysOnTop +ToolWindow -Border -Caption +E0x20 ; E0x20 is clickthrough
WinSet, TransColor, %overlay_color% 255
SetTimer, check_poe_active, 100
SetTimer, read_poe_log, 500

GuiControl,, Lich,
Return

read_poe_log:
    loop {
        line := filehandle.readline()
        StringReplace, line, line, `r,, All
        StringReplace, line, line, `n,, All

        if line {
            line_parts := StrSplit(line, A_Space)

            if (line_parts[8] = "Entering" && line_parts[9] = "area")
            {
                LinePart := line_parts[10]
                If InStr(LinePart, "AbyssLeagueBoss2")
                {
                    SoundPlay, %sound_lich%
                    Loop, 10
                    {
                        GuiControl,, Lich, Amanamu
                        Sleep, 500
                        GuiControl,, Lich,
                        Sleep, 500
                    }
                    ;GuiControl,, Lich, Amanamu
                }
                Else If InStr(LinePart, "AbyssLeagueBoss")  ; wildcard, as Ulaman can be either AbyssLeagueBoss or AbyssLeagueBoss1,
                                                            ; either way it's fine, as this will catch both
                {
                    SoundPlay, %sound_lich%
                    Loop, 10
                    {
                        GuiControl,, Lich, Ulaman ; This is a guess
                        Sleep, 500
                        GuiControl,, Lich,
                        Sleep, 500
                    }
                    ;GuiControl,, Lich, Ulaman
                }
                Else If InStr(LinePart, "AbyssLeague")
                {
                    SoundPlay, %sound_no_lich%
                    Loop, 5
                    {
                        GuiControl,, Lich, No Lich
                        Sleep, 500
                        GuiControl,, Lich,
                        Sleep, 500
                    }
                }
                else
                {
                    GuiControl,, Lich,
                }
            }
        } else break
    }
return

check_poe_active:
    IfWinActive, ahk_exe PathOfExile_x64.exe
    {
        Gui +LastFound +AlwaysOnTop +ToolWindow -Border -Caption +E0x20 ; E0x20 is clickthrough
        Gui, Show, x%overlay_x% y%overlay_y% h%A_ScreenHeight% w%A_ScreenWidth% NoActivate, PoE Ingame Overlay
    } else {
        Gui, Hide
    }
return