; Nickname colouring script by Phil
; Colours certain nicknames on your nick list
; Pretty intensive but required if you want IRCOps in another colour
; if not, use the mIRC address book

on 1:START:{
  set %nickcolour.whocounter 0
}

alias enableJoinWho {
  enable #dothejoinwho

  scon -a chanwho
}

alias chanwho {
  set %nickcolour.noofchans $chan(0)
  set %nickcolour.nochanvar 1
  while (%nickcolour.nochanvar <= %nickcolour.noofchans) {
    who $chan(%nickcolour.nochanvar)
    inc %nickcolour.nochanvar
  }
}

#dothejoinwho on
alias pausethewhos {
  set %nickcolour.whocounter 0
  .timer 1 60 enableJoinWho
  echo -a 4Whos disabled for 1 min
  disable #dothejoinwho
}

alias doWhoForJoin {
  .enable #supressoutput
  who $1
  inc -u20 %nickcolour.whocounter

  if (%nickcolour.whocounter > 70) {
    pausethewhos
  }
}

on *:JOIN:#:{
  .timerdoWhoForJoin 1 5 doWhoForJoin $chan
}

on 1:RAWMODE:#:{
  if (v isin $1 || h isin $1 || o isin $1 || a isin $1 || q isin $1) {
    .enable #supressoutput
    .timerdoWhoForJoin off
    who $chan
    set -u6 %nickcolour.whodone 1
    inc -u20 %nickcolour.whocounter

    if (%nickcolour.whocounter > 70) {
      pausethewhos
    }
  }
}
#dothejoinwho end

raw 352:*: {
  if ($me ison $2) {
    if ($chr(42) isin $7) && ($left($2,1) == $chr(35)) {
      cline 04 $2 $6
    }
    haltdef
  }
}

#supressoutput off
raw 315:*: {
  .disable #supressoutput
  halt
}
#supressoutput