programa activar mp3 encoder

::PROGRAMA PARA Activar MP3 encoder en Windows Vista/7
::EL Windows Vista/7 viene con el codificador MP3 desactivado (solo viene con el ::decodificador), por lo que nos podemos encontrar algún problema a la hora de convertir o ::capturar audio. Para activarlo
:: Tenemos que tener permisos de Administrador
@echo off
echo ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
echo ³ Windows Vista Fix for Fraunhofer IIS MPEG Layer-3 Codec ³
echo ³ Revision 3 ³
echo ³ July 6, 2009 ³
echo ³ Copyright (C) 2007-2009 Chortkeh. All rights reserved. ³
echo ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
echo.
rem Preserve current directory for further referrings.
set InitialDirectory=%cd%
echo Removing the advanced edition of Fraunhofer IIS MPEG Layer-3 Codec...
reg delete "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\drivers.desc" /v "C:\Windows\System32\l3codeca.acm" /f
echo.
echo Activating the professional edition of Fraunhofer IIS MPEG Layer-3 Codec...
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\drivers.desc" /v "l3codecp.acm" /t REG_SZ /d "Fraunhofer IIS MPEG Audio Layer-3 Codec (professional)" /f
if errorlevel 1 (
echo Registry manipulation error.
goto :Error
)
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Drivers32" /v "msacm.l3acm" /t REG_SZ /d "l3codecp.acm" /f
if errorlevel 1 (
echo Registry manipulation error.
goto :Error
)
echo.
pause
goto :EOF

rem --------------------------------------------------------------------------

:Error
echo.
echo Patching failed.
echo.
echo Checking for a solution to the problem...
echo.
rem Check to see if initial directory differs from system32, becasue if batch
rem file was run-as-administrator, the initial directory would be System32.
if /i not "%InitialDirectory%" equ "%SystemRoot%\system32" (
echo * The patcher must be run as administrator. To do so, right-click on
echo the patcher file and select run as administrator.
) else (
echo * The patcher requires administrative privileges to complete the process.
)
echo.
pause
goto :EOF

rem --------------------------------------------------------------------------