[EVENTS e_Human_ConvInit]

ON=@NPCSeeNewPlayer
    // When a new person comes into range do something (attack them?)
    if ( <DISTANCE> > 5 )   // too far away ?
        return 1    // do nothing for now
    ENDIF
    FACE
    IF ( <SRC.KARMA.WICKED> || <SRC.KARMA.BELLIGERENT> )
        DORAND 5
            SAY Nepriblizuj se ke me!
            SAY Ani sem nechod!
            SAY Neplytvej mym casem.
            SAY Jdi pryc.
            SAY Moc se tu nepoflakuj.
        ENDDO
    ELSE
        ACT=<SRC.UID>
        IF ( <SRC.FAME.INFAMOUS> || <SRC.FAME.OUTLAW> )
            DORAND 3
                SAY Jdi pryc.
                SAY Moc se tu nepoflakuj.
                SAY chces se mnou mluvit? Radeji ne.
            ENDDO
        ELIF ( <SRC.FAME.ANONYMOUS> )
            DORAND 4
                SAY Chces mi neco?
                SAY Ale koho to nevidim, <SRC.NAME>!
                SAY Prejes si neco?
                SAY Posloucham te.
            ENDDO
            SALUTE
        ELSE
            DORAND 4
                SAY Dobry den, <SRC.SEX vzacny pane/vzacna pani>.
                SAY Posloucham vas, <SRC.SEX pane/pani> <SRC.NAME>.
                SAY Prejete si neco, <SRC.SEX pane/pani> <SRC.NAME>?
                SAY Posloucham vas, <SRC.SEX pane/pani> <SRC.NAME>.
            ENDDO
            BOW
        ENDIF
        ACTION=107 // NPCACT_TALK_FOLLOW
    ENDIF

    RETURN 0    // don't come here again.