Possession and Ownership, for Inform7

Version 2/130613 of Possession and Ownership by Shadow Wolf begins here.

[NOTE: Superceded by version 3 here: http://pastebin.com/QA2wxC5g ]

Section 1 - Possessions

[Option - ignore physical possession]
Use legal possession translates as (- Constant ONLY_LEGAL_POSSESSION; -).

Definition: A thing is possessed if a person is holding it.
To decide which person is the possessor of (T - a thing):
	if T is held by a person (called the holder), decide on the holder;
	decide on nothing;

Understand "my" as a thing when the player is holding the item described. Understand "your" as a thing when the person asked is holding the item described.

Every thing has an indexed text called the possessive name. The possessive name of a thing is usually "". Understand the possessive name property as referring to a thing.

The last when play begins rule: if the legal possession option is inactive, update possessions.
Every turn: if the legal possession option is inactive, update possessions.

To update possessions:
	repeat with item running through possessed things:
		now the possessive name of the item is "[possessive form of the possessor of the item]";

To say possessive form of (X - a thing):
	if X is the player:
		say "your";
	otherwise if X is plural-named:
		say "[X][apostrophe]";
	otherwise:
		say "[X][apostrophe]s".



Section 2 - Ownership

[Sometimes items are permanently associated with a person, even if they are currently held by someone else, or not held at all (a building, for example). Ownership handles this.]

Ownership relates one person (called the owner)  to various things. The verb to own (he owns, they own, he owned, he is owned) implies the ownership relation.
Understand "my" as a thing when the player owns the item described. Understand "your" as a thing when the person asked owns the item described.

Every thing has an indexed text called the owners name. The owners name of a thing is usually "". Understand the owners name property as referring to a thing.

The last when play begins rule: update ownership.
Every turn: update ownership.

To update ownership:
	repeat with item running through things owned by a person:
		now the owners name of the item is "[possessive form of the owner of the item]";


Possession and Ownership ends here.

---- DOCUMENTATION ----

"Possession and Ownership" allows the player to use possessives to refer to items which are either physically held by a particular individual, or notionally owned by an individual.

The original idea, which only covered physical possession, originated on a r.a.i.f thread, archived here: http://rec.arts.int-fiction.narkive.com/dBgGlsLL/possessives-in-inform-7

With this extension, a player can automatically use commands like "EXAMINE BOB'S PANTS" or "DROP MY PENCIL" or "ALICE, GIVE ME YOUR NECKLACE" - as long as the appropriate person (Bob, the player, and Alice respectively) is holding the item in question. Possession in this case lasts until another person picks up the item - so "ALICE, DROP YOUR NECKLACE" can be followed by "TAKE ALICE'S NECKLACE". (Of course, once the player picks it up, it no longer belongs to Alice by this rule, so "X ALICE'S NECKLACE" would subsequently fail.

Some items may be notionally owned by a particular individual, even if they are currently held by someone else, or are fixed in place (and thus not holdable at all.) The ownership relation handles this.

	Bob carries a gun. The gun is owned by Annie. [or "Annie owns the gun."]

This allows:

	> EXAMINE ANNIE'S GUN [even though it's held by Bob]
	> BOB, DROP ANNIE'S GUN
	> ANNIE, GET YOUR GUN

(Who didn't see that last line coming?)

Naturally, ownership of an item can change during play:

	Oak Street is a room. The red house is scenery on Oak Street. The house is owned by Bob.

	Signing the Deed is a scene. When Signing the Deed ends: Now the house is owned by the player.

If you want to ignore physical possession, and only use the ownership relation, set the option "Use legal possession."

Section - Caveats and Issues

If a person's name has multiple words, the player has to spell it in full. (e.g. "Red Riding Hood is a person. She wears a cloak." requires "X RED RIDING HOOD'S CLOAK".) There isn't really any way around this that I can see. (Even with assemblies, this can be an issue - see 4.15 of the Documentation). So if possible use only single names.

The format for possessives is simple: "[name][apostrophe]s" for singular nouns, and "[name][apostrophe]" for plural ones. This is the same rule used in Plurality. To override it for particular nouns (e.g. "children"), write a more specific "To say possessive form of (X - a thing)". Note that "possessive form" is used in order to avoid conflict with Plurality's "To say the possessive of X" (which has side effects that mean I cannot simply use that phrase directly).