require conf/distro/poky.conf

DISTRO = "fod-os"
DISTRO_NAME = "FOD Operating System"
DISTRO_VERSION = "0.2-Beta"

SDK_VENDOR = "-fodsdk"

MAINTAINER = "Eduardas Meile <[email protected]>"

TARGET_VENDOR = "-fod"

DISTROOVERRIDES = "fod"

# This function changes the default tune for machines which are based on armv7a
# to use common tune value
def arm_tune_handler(d):
    features = d.getVar('TUNE_FEATURES', True).split()
    if 'armv7a' in features or 'armv7ve' in features:
        tune = 'armv7athf'
        if 'bigendian' in features:
            tune += 'b'
        if 'vfpv3' in features:
            tune += '-vfpv3'
        if 'vfpv3d16' in features:
            tune += '-vfpv3d16'
        if 'neon' in features:
            tune += '-neon'
        if 'vfpv4' in features:
            tune += '-vfpv4'
    else:
        tune = d.getVar('DEFAULTTUNE', True)
    return tune

DEFAULTTUNE_fod := "${@arm_tune_handler(d)}"

DISTRO_ARM_INSTRUCTION ?= "thumb"
DISTRO_ARM_INSTRUCTION_armv5 ?= "arm"
ARM_INSTRUCTION_SET_fod ??= "${DISTRO_ARM_INSTRUCTION}"

# Use bluez5 as default.
DISTRO_FEATURES_append = " bluez5"

# Remove conflicting backends.
DISTRO_FEATURES_remove = "x11 wayland directfb vulkan alsa irda pcmcia nfs zeroconf pci 3g nfc"