BatchGameLauncherTemplate

:: Batch Game Launcher Template
:: /u/DigitalPhreaker
:: Last Modified: 2018-12-08
:: When run as Admin, this script will call PowerShell to disable Windows Defender, launch the provided program/game, lower the priorities of provided programs, set the program/game's priority to high, then pause. Once the game has closed and the user strikes another key, the script will continue, re-enabling Windows Defender, re-launching any programs set below, resetting priorities back to normal, and then finally backing up

@echo off

::----------------------------------------------------------------------------------------------------------------
::                              BEGIN MAIN VARIABLE DECLARATIONS
::
:: Search and replace the following variables before you forget
::
:: If launching the game through Steam, be sure to set the STEAMCOMMAND variable and comment out the
::  start "" %GAMEEXE%
:: and
::  echo %STARTNOTIFY%
:: commands directly before :NOTFOUND below.
::
:: If launching the executable directly, do the opposite of above, commenting out
::  start "" %STEAMCOMMAND%
:: and
::  echo %STEAMNOTIFY%
::
::  GAMPEATH: Main parent directory where the game is installed (where the main executable is stored). Do not include a final backslash .
set GAMEPATH=D:\Games\Just Cause 4
::
::  GAMEEXE:  Pretty self-explanatory
set GAMEEXE=JustCause4.exe
::
::  STEAMCOMMAND: Command line argument to launch a game through Steam, where XXXXXXX is the AppID. You can find this AppID by Googling "[Game Name] Steam AppID". Commented out as CPY's version of JC4 obviously doesn't go through Steam to launch, but left it in so you can see how to use this for other games.
::set STEAMCOMMAND=steam://run/XXXXXXX
::
::  BACKUPDIRECTORY: Main parent directory where you'd like your game saves/settings backups stored. Like GAMEPATH, do not include a final backslash.
set BACKUPDIRECTORY=F:\BACKUPS\_GAMESAVES
::
::  GAMENAME: Whatever you want it to be set as, but DO NOT include special characters (':', '\', etc.) as this variable is used as part of the directory path for the backup location string later on, and Windows does not allow special characters in directory names.
set GAMENAME=Just Cause 4
::
::  SAVELOCATION: Main parent directory where the game's save files are stored. For *most* Steam games, this will be %SteamInstallDirectory%\userdata\XXXXXXXX\AppID" (where XXXXXXXX is a random number assigned to your Steam user ID).
::  For other games (and some Steam games) this can be in your user Documents directory, or a handful of other locations. You'll want to search for where the saves are located, then set that directory here (again, without a closing backslash). For JC4, though, they are stored in:
set SAVELOCATION=C:\Users\YourWindowsUsername\Documents\Square Enix\Just Cause 4\LocalData
::
:: STARTNOTIFYSTEAM and STARTNOTIFY are simply used later in the script to notify you when the game has been launched. I use one for Steam games and one for non-Steam games so I remember that Steam games may take a few extra seconds to start
::
::set STARTNOTIFYSTEAM=%GAMENAME% has been started through Steam.
set STARTNOTIFY=%GAMENAME% has been started, but will immediately close as you've had to launch this script with Admin rights. (%GAMENAME% cannot run with Admin rights and crashes immediately.) Use this time to manually launch it yourself. The script will still set everything as soon as it detects the game is running.
::
::
::                              END MAIN VARIABLE DECLARATIONS
::----------------------------------------------------------------------------------------------------------------
goto DISABLEDEFENDER

:DEFDISABLED
SETLOCAL EnableExtensions
::----------------------------------------------------------------------------------------------------------------
::                              SET PROGRAM AND PRIORITY VARIABLES
::
:: Use 'wmic processs where name="programExecutable.exe" CALL setpriority "n"' to set any program matching that name
:: to priority level n
::
::      wmic
::          Calls Windows Management Instrumentation Command to execute the commands following it
::      processs where name="programExecutable.exe"
::          Commands WMIC to search for any running process matching the name programExecutable.exe
::      CALL setpriority "n"
::          Calls the setpriority command and sets programExecutable.exe's prirority to n, where n =
::              "64"    = Idle
::              "16384" = Below Normal
::              "32"    = Normal
::              "32768" = Above Normal
::              "128"   = High
::              "256"   = Real Time (NEVER RECOMMENDED)
::
:: Use 'taskkill /F /T /IM programExecutable.exe' to kill any running program that matches that name, as well as any child processes started by it.
::      /F
::          tells taskkill to forcefully kill the program immediately.
::      /T
::          tells taskkill to also kill any child process launched by 'programExecutable.exe'
::      /IM
::          tells taskkill to kill any running program matching 'programExecutable.exe'
::-----------------------
set IDLE=CALL setpriority "64"
set BELOWNORMAL=CALL setpriority "16384"
set NORMAL=CALL setpriority "32"
set ABOVENORMAL=CALL setpriority "32768"
set HIGH=CALL setpriority "128"
::-----------------------
::
set GAMEPRIORITY=wmic process where name="%GAMEEXE%"
::
::-----------------------
::
::  Use this section to set any variable you want to enable the script to set its corresponding program's priority. Just make sure you get the executable's name EXACTLY as it appears in Task Manager/Process Explorer, or else the script will just skip over it. The variable's name can be whatever you want. The ones below are for programs that pretty much run on all Windows 10 machines regardless of setup, but you can add or remove as many as you want.
::
::  While we've already disabled Windows Defender and thus it shouldn't be interfering with the game, I still have it's main executable set to low priority anyway just in case.
set WINDEFENDER=wmic process where name="MsMpEng.exe"
::
set WINEXPLORER=wmic process where name="explorer.exe"
set SEARCHUI=wmic process where name="SearchUI.exe"
set SEARCHINDEXER=wmic process where name="SearchIndexer.exe"
set SHELLHOST=wmic process where name="ShellExperienceHost.exe"
set STEAM=wmic process where name="steam.exe"
set STEAMWEB=wmic process where name="Steamwebhelper.exe"
set XBOXAPP=wmic process where name="XboxApp.exe"
set GAMEBAR=wmic process where name="GameBar.exe"
::-----------------------
::
::  For programs you'd rather just have killed when starting the game, use this section.
::
set FORCEKILL=taskkill /F /T /IM
set SOFTKILL=taskkill /T /IM
::
::  This is used as part of FORCEKILL/SOFTKILL down below. Set the program executable's name here.
set FIREFOX=firefox.exe
::
::  This is used to re-launch the program after the game has closed and you've told the script to continue.
set FIREFOXPATH=C:\Program Files\Mozilla Firefox\firefox.exe
::
::-----------------------
::
::    These commands will set your computer's power configuration to high performance (POWERHIGH), balanced (POWERBALANCED), or power saver (POWERLOW). I've commented these out as I'm on desktop, and my power configuration is always set to high and will never be set below that. However, if you're on a laptop and would like to enable these, they can give you a bit of an extra kick while ensuring they're set back to a proper config once the script has finished.
::
set POWERHIGH=powercfg -s 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c
set POWERBALANCED=powercfg -s 381b4222-f694-41f0-9685-ff5bb260df2e
set POWERLOW=powercfg -s  a1841308-3541-4fab-bc81-f71556f20b4a
::-----------------------

::    These are the commands to launch the games and notify you when they've been launched.

::    'start' instructs cmd.exe to start the following program/command.
::    'timeout n' pauses the script for 'n' seconds.
::    'echo' prints the following string for you to read.
::    'echo[' prints a blank line.


start "" "%GAMEPATH%\%GAMEEXE%"
::start "" %STEAMCOMMAND%
timeout 5
echo %STARTNOTIFY%
::echo %STARTNOTIFYSTEAM%
echo[
echo -------------------------------------------------------------------------------------------------------------
echo[
::----------------------------------------------------------------------------------------------------------------

::----------------------------------------------------------------------------------------------------------------
:NOTFOUND
:: The script enters a for loop at this section. The loop repeats every 30 seconds until %GAMEEXE% is detected, and then the script is told to go to :FOUND, where it will continue on to set priorities. You can set the timeout below to whatever you want; I have it set to 30 specifically in this case because the CPY version of JC4 cannot run with admin rights, and will crash as soon as it launches. With the timeout set to 30, the script won't detect it before it crashes, and therefore will only detect it after it's been manually launched.
::
echo %GAMENAME% is not running. Waiting 30 seconds.
timeout 30
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %GAMEEXE%"') DO IF %%x == %GAMEEXE% goto FOUND
goto NOTFOUND
::----------------------------------------------------------------------------------------------------------------

::----------------------------------------------------------------------------------------------------------------
:FOUND
::%DATE:~10,4% = YYYY
::%DATE:~4,2% = MM
::%DATE:~7,2% = DD
::%TIME:~0,2% = HH
::%TIME:~3,2% = MM
::%TIME:~6,2% = SS
set STARTDATE=%DATE:~10,4%-%DATE:~4,2%-%DATE:~7,2%
set STARTTIME=%TIME:~0,2%:%TIME:~3,2%:%TIME:~6,2%
::-----------------------
::          WRITE LAUNCH DATE/TIME TO FILE
echo %GAMENAME% launched on %STARTDATE% at %STARTTIME% >> "%GAMEPATH%\_LaunchAndCloseTimes.txt"
::
::-----------------------
cls
echo[
echo -------------------------------------------------------------------------------------------------------------
echo[
echo %GAMENAME% is running!
echo[
echo Killing chosen programs and setting priorities in 5 seconds.
echo[
timeout 5
echo[
::-----------------------
::%POWERHIGH%
::-----------------------
%SOFTKILL% %FIREFOX%
::-----------------------
%GAMEPRIORITY% %HIGH%
%STEAM% %BELOWNORMAL%
%STEAMWEB% %IDLE%
%WINDEFENDER% %IDLE%
%SEARCHINDEXER% %IDLE%
%XBOXAPP% %BELOWNORMAL%
%WINEXPLORER% %BELOWNORMAL%
%SEARCHUI% %IDLE%
%SHELLHOST% %IDLE%
::-----------------------
::
cls
echo[
echo %GAMENAME% launched on %STARTDATE% at %STARTTIME%
echo[
echo Script will now pause until you come back to this window and press any key to make it continue. Enjoy the game!
pause
goto BACKUP
::----------------------------------------------------------------------------------------------------------------

:BACKUP
::%DATE:~10,4% = YYYY
::%DATE:~4,2% = MM
::%DATE:~7,2% = DD
::%TIME:~0,2% = HH
::%TIME:~3,2% = MM
::%TIME:~6,2% = SS
set ENDDATE=%DATE:~10,4%-%DATE:~4,2%-%DATE:~7,2%
set ENDTIME=%TIME:~0,2%:%TIME:~3,2%:%TIME:~6,2%
set TIMESTAMP=%DATE:~10,4%-%DATE:~4,2%-%DATE:~7,2% %TIME:~0,2%_%TIME:~3,2%_%TIME:~6,2%
set BACKUPLOCATION=%BACKUPDIRECTORY%\%GAMENAME%\%TIMESTAMP%
echo %GAMENAME% ended    on %ENDDATE% at %ENDTIME%
echo %GAMENAME% ended    on %ENDDATE% at %ENDTIME% >> "%GAMEPATH%\_LaunchAndCloseTimes.txt"
echo ----------------------------------------------------- >> "%GAMEPATH%\_LaunchAndCloseTimes.txt"
mkdir "%BACKUPLOCATION%"
copy "%SAVELOCATION%" "%BACKUPLOCATION%"
copy "%GAMEPATH%\_LaunchAndCloseTimes.txt" "%BACKUPLOCATION%\_LaunchAndCloseTimes.txt"
echo[
echo -------------------------------------------------------------------------------------------------------------
echo Game saves successfully backed up.
echo[
goto ENABLEDEFENDER

:DEFENABLED
SETLOCAL EnableExtensions
echo -------------------------------------------------------------------------------------------------------------
echo[
echo Restoring process priorities and relaunching programs...
echo[
::-----------------------
%STEAM% %NORMAL%
%STEAMWEB% %NORMAL%
%WINDEFENDER% %NORMAL%
%SEARCHINDEXER% %NORMAL%
%XBOXAPP% %NORMAL%
%WINEXPLORER% %NORMAL%
%SEARCHUI% %NORMAL%
%SHELLHOST% %NORMAL%
start "" "%FIREFOXPATH%"
echo Firefox is launching...
echo[
::-----------------------
:: %POWERBALANCED%
::-----------------------
echo -------------------------------------------------------------------------------------------------------------
echo[
echo All done!
echo[
pause
exit

::----------------------------------------------------------------------------------------------------------------
::
:: Calls Windows PowerShell and executes the command "Set-MpPreference -DisableRealtimeMonitoring $true" which disables Windows Defender's real-time monitoring until ENABLEDEFENDER is called at the end of the script.
:DISABLEDEFENDER
echo Launching PowerShell and disabling Windows Defender...
echo[
PowerShell -Command "Set-MpPreference -DisableRealtimeMonitoring $true"
echo[
echo Windows Defender has been disabled.
echo[
goto DEFDISABLED

:ENABLEDEFENDER
echo Launching PowerShell and enabling Windows Defender...
echo[
PowerShell -Command "Set-MpPreference -DisableRealtimeMonitoring $false"
echo[
echo Windows Defender has been enabled.
echo[
goto DEFENABLED