Flag CMD 1.0 SVN

// Function that allows you to loop through a given string's characters like
// looplist does for an item's list, usage: /loopchar <var> [action]
loopchar = [
    loop $arg1 (strlen $arg2) [
        @arg1 = (substr $arg2 $[@arg1] 1)
        @arg3
    ]
]

// Function to add 1 to given value and alias it back, usage: /++ <var>
"++" = [$arg1 = (+ (getalias $arg1) 1)]


// Conditional function that operates based on flags, and their order before executing given content.
// usage: cmd <flags> [content]
// example: cmd cmp [say hi] -- would say "hi" when you are connected, have master rights, and are playing.
// note 1: each flag that comes back negative stops the script, to avoid notification spam.
// note 2: the order the flags are used plays an important role in determining which error comes first.
// note 3: all flags must be tested positive before the content is executed.

cmd = [
    local tmp
    tmp = 0
    loopchar f $arg1 [
        if (> $tmp -1) [
            cases $f "m" [
                if (ismaster (getclientnum)) [++ tmp] [
                    error "^f3You do not have master rights!"
                    tmp = -1
                ]
            ] "a" [
                if (isadmin (getclientnum)) [++ tmp] [
                    error "^f3You do not have admin rights!"
                    tmp = -1
                ]
            ] "s" [
                if (isspectator (getclientnum)) [++ tmp] [
                    error "^f3You can only do this while spectating!"
                    tmp = -1
                ]
            ] "p" [
                if (! (|| (isspectator (getclientnum)) $editing)) [++ tmp] [
                    error "^f3You can only do this while playing!"
                    tmp = -1
                ]
            ] "c" [
                if (isconnected) [++ tmp] [
                    error "^f3You can only do this while online"
                    tmp = -1
                ]
            ] "o" [
                if (! (isconnected)) [++ tmp] [
                    error "^f3You can only do this while offline"
                    tmp = -1
                ]
            ] "e" [
                if $editing [++ tmp] [
                    error "^f3You can only do this while in editmode!"
                    tmp = -1
                ]
            ] "r" [
                if (movierecording) [++ tmp] [
                    error "^f3You can only do this while recording a movie!"
                    tmp = -1
                ]
            ] () [error "^f3Invalid command flag:" $f]
        ]
    ]
    if (= $tmp (strlen $arg1)) arg2
]