Application system for bdfd

********************
Application Codes
********************
Variable / Value
applicationchannel /
modlog /
userapplication /
staffrole /

********************
HOW TO USE:
1) all the variables should have blank values when made.

2) first use the appset (code 3) to set the variables:
examples:
(prefix)appset logs #logchannel

(prefix)appset channel #applicationchannel

(prefix)appset roles @rolename

3) then for your server create a role called "staff" if you do not already have one

********************
Code 1: (prefix)newapplication

$nomention
$deletecommand
$onlyIf[$getServerVar[applicationchannel]!=;Please have an admin set the application channel first]
$onlyIf[$getServerVar[modlog]!=;Please have an admin set the mod logs channel first]
$title[__**Staff Application**__]
$description[<@$authorID>, Thank you for showing interest in joining the $serverName[$guildID] staff team!

Using the buttons below please answer all 8 questions to the best of your abilities.

Read all questions carefully, when there is a question that give you options only choose one if the options:
example: are you available for at least 30m a day?
yes or no

you replace the yes or no with only one choice.

any application that is not done properly will not be submitted.

Click Submit when you are finished]
$addButton[no;staffq1-$authorID;Questions 1-4;Primary;no;]
$addButton[no;staffq2-$authorID;Questions 5-8;Primary;no;]
$addButton[no;staffsubmit-$authorID;Submit;success;no;]
$addButton[no;delete-$authorID;Cancel Application;danger;no;]
***********************
Code 2: $onInteraction

$onlyIf[$checkContains[$customID;staffq1-;staffq2-;staffsubmit-;staffa1-;staffa2-;staffapprove-;staffdecline-;staffrole-]==true;]
$nomention
$textSplit[$customID;-]
$if[$splitText[2]!=$authorID]
$ephemeral
$removeButtons
$description[This is not your application]
$elseif[$splitText[2]==$authorID]
$if[$customID==staffq1-$authorID]
$newModal[staffa1-$authorID;Questions1-4]
$addTextInput[answer1;short;Timezone;;;yes;;]
$addTextInput[answer2;short;Are you over 18?;;;yes;yes or no;]
$addTextInput[answer3;short;Have you been staff/moderator/admin before?;;;yes;staff or moderator or admin or no;]
$addTextInput[answer4;short;Are you availble for 30m a day?;;;yes;yes or no;]
$endif
$if[$customID==staffq2-$authorID]
$newModal[staffa2-$authorID;Questions 5-9]
$addTextInput[answer5;short;Are you comfortable settling disputes?;;;yes;yes or no;]
$addTextInput[answer6;paragraph;How long have you been on the server?;;;yes;;]
$addTextInput[answer7;paragraph;What position would you like and why;;2000;yes;;]
$addTextInput[answer8;paragraph;Tell us about yourself;;2000;yes;;]
$addTextInput[answer9;paragraph;what can you contribute to the server?;;2000;yes;;]
$endif
$if[$customID==staffa1-$authorID]
$textSplit[$getUserVar[userapplication;$authorID];|]
$if[$checkContains[$toLowercase[$input[answer3]];staff]==true] $var[answer3;staff] $elseif[$checkContains[$toLowercase[$input[answer3]];mod]==true] $var[answer3;moderator] $elseif[$checkContains[$toLowercase[$input[answer3]];admin]==true] $var[answer3;admin] $elseif[$checkContains[$toLowercase[$input[answer3]];mod;staff;admin]!=true] $var[answer3;no] $endif
$setUserVar[userapplication;$input[answer1]|$input[answer2]|$var[answer3]|$input[answer4]|$splitText[5]|$splitText[6]|$splitText[7]|$splitText[8]|$splitText[9];$authorID]
$endif
$if[$customID==staffa2-$authorID]
$textSplit[$getUserVar[userapplication;$authorID];|]
$setUserVar[userapplication;$splitText[1]|$splitText[2]|$splitText[3]|$splitText[4]|$input[answer5]|$input[answer6]|$input[answer7]|$input[answer8]|$input[answer9];$authorID]
$endif
$endif
$if[$customID==staffsubmit-$authorID]
$textSplit[$getUserVar[userapplication;$authorID];|]
$removeComponent[staffq1-$authorID]
$removeComponent[staffq2-$authorID]
$removeComponent[staffsubmit-$authorID]
$removeComponent[delete-$authorID]
$description[Application has been submitted, thank you for your interest in joining our team.

Once reviewed you will be notified of our decision.]
$color[1700fb]
$async[1]
$replyIn[1]
$textSplit[$getUserVar[userapplication;$authorID];|]
$var[id;$sendEmbedMessage[$getServerVar[applicationchannel];;__**New Application**__;;__TimeZone:__ $splitText[1]
__Over 18:__ $splitText[2]
__Previously Been staff/Mod/Admin:__ $splitText[3]
__Available 30m a day:__ $splitText[4]
__Comfortable settling disputes:__ $splitText[5]
__How long in server:__ $splitText[6]
__Position and Why:__
$splitText[7]

__Information about applicant:__
$splitText[8]

__contributions:__
$splitText[9]

The Approve or Deny Buttons are for Admins only.;1700fb;;;;;$authorAvatar;;yes;yes]]
$useChannel[$getServerVar[applicationchannel]]
$addButton[no;staffapprove-$authorID;Approve;success;no;;$var[id]]
$addButton[no;staffdecline-$authorID;Decline;danger;no;;$var[id]]
$endasync
$endif
$if[$checkContains[$customID;staffapprove-]==true]
$if[$isAdmin[$authorID]!=true]
$sendMessage[This is a admin button only.]
$else
$textSplit[$customID;-]
$var[id;$splitText[2]]

$description[Which Staff role did they apply for?]
$textSplit[$getServerVar[staffroles];|]
$removeComponent[staffapprove-$var[id]]
$removeComponent[staffdecline-$var[id]]
$addButton[no;staffrole-$splitText[1]-$var[id];$roleName[$splitText[1]];primary;no;]
$if[$splitText[2]!=]
$addButton[no;staffrole-$splitText[2]-$var[id];$roleName[$splitText[2]];primary;no;]
$endif
$if[$splitText[3]!=]
$addButton[no;staffrole-$splitText[3]-$var[id];$roleName[$splitText[3]];primary;no;]
$endif
$if[$splitText[4]!=]
$addButton[no;staffrole-$splitText[4]-$var[id];$roleName[$splitText[4]];primary;no;]
$endif
$if[$splitText[5]!=]
$addButton[no;staffrole-$splitText[5]-$var[id];$roleName[$splitText[5]];primary;no;]
$endif
$if[$splitText[6]!=]
$addButton[yes;staffrole-$splitText[6]-$var[id];$roleName[$splitText[6]];primary;no;]
$endif
$if[$splitText[7]!=]
$addButton[no;staffrole-$splitText[7]-$var[id];$roleName[$splitText[7]];primary;no;]
$endif
$if[$splitText[8]!=]
$addButton[no;staffrole-$splitText[8]-$var[id];$roleName[$splitText[8]];primary;no;]
$endif
$if[$splitText[9]!=]
$addButton[no;staffrole-$splitText[9]-$var[id];$roleName[$splitText[9]];primary;no;]
$endif
$if[$splitText[10]!=]
$addButton[no;staffrole-$splitText[10]-$var[id];$roleName[$splitText[10]];primary;no;]
$endif
$async[approve]
$replyIn[1]
$dm[$var[id]]
$sendEmbedMessage[$dmChannelID[$var[id]];;__**Staff Application**__;;<@$var[id]> it is with great pleasure that we inform you that your staff application to $serverName[$guildID] has been approved!

Welcome to the staff team!!;1700fb;;;;;$serverIcon[$guildID];;yes;no]
$endasync
$if[$getServerVar[modlog]!=]
$async[promote]
$replyIn[2]
$sendEmbedMessage[$getServerVar[modlog];;__**New Staff Member**__;;Everyone please give a round of applause to the newest member of $serverName[$guildID]’s staff team <@$var[id]> !!!!;1700fb;;;;;$serverIcon[$guildID];;yes;no]
$endasync
$endif
$endif
$endif
$if[$checkContains[$customID;staffdecline-]==true]
$if[$isAdmin[$authorID]!=true]
$sendMessage[This is a admin button only.]
$else
$textSplit[$customID;-]
$var[id;$splitText[2]]

$async[decline]
$replyIn[1]
$dm[$var[id]]
$sendEmbedMessage[$dmChannelID[$var[id]];;__**Staff Application**__;;<@$var[id]> we are sorry to inform you that your staff application to $serverName[$guildID] has been declined!

Do not let this detour you from trying again however, one day in the future you may still yet be able to join our staff team!;1700fb;;;;;$serverIcon[$guildID];;yes;no]
$endasync
$endif
$endif
$if[$checkContains[$customID;staffrole-]==true]
$textSplit[$customID;-]
$removeButtons
$roleGrant[$splitText[3];+$roleID[staff];+$splitText[2]]
$sendEmbedMessage[$channelID;;__**Roles Granted**__;;The $roleName[$roleID[staff]] and $roleName[$splitText[2]] roles have been assigned to <@$splitText[3]> !!!!;1700fb;;;;;$serverIcon[$guildID];;yes;no]
$endif
**************
Code 3: (prefix)appset

$onlyIf[$checkContains[$message[1];logs;channel;roles]==true;]
$nomention
$onlyAdmin[Admin only]
$deletecommand
$if[$message[1]==logs]
$onlyIf[$mentionedChannels[1]!=;please mention a channel with the command]
$setServerVar[modlog;$mentionedChannels[1]]
$description[The mod log channel has been set to <#$mentionedChannels[1]>]
$deleteIn[15]
$endif
$if[$message[1]==channel]
$onlyIf[$mentionedChannels[1]!=;please mention a channel with the command]
$setServerVar[applicationchannel;$mentionedChannels[1]]
$description[The applications channel has been set to <#$mentionedChannels[1]>]
$deleteIn[15]
$endif
$if[$message[1]==roles]
$onlyIf[$mentionedRoles[1]!=;please mention a role with the command]
$setServerVar[staffroles;$getServerVar[staffroles]$mentionedRoles[1]|]
$description[<@&$mentionedRoles[1]> has been added as a staff role]
$deleteIn[15]
$endif