r[t_] := {t, t^2, t^3}

uT[t_] = Simplify[ r'[t] / Norm[ r'[t] ], t ∈ Reals];
vN[t_] = Simplify[ uT'[t]/ Norm[ uT'[t]], t ∈ Reals];
vB[t_] = Simplify[ Cross[r'[t], r''[t]] / Norm[ Cross[r'[t], r''[t]] ], t ∈ Reals];

{uT[t], vN[t], vB[t]} // Column // TraditionalForm

Simplify[ Norm /@ {uT[t], vN[t], vB[t]}, t ∈ Reals]

{1, 1, 1}

Animate[
    Show[ ParametricPlot3D[ {r[t]}, {t, -1.3, 1.3}, PlotStyle -> {Blue, Thick}],
          Graphics3D[{ {Thick, Darker @ Red, Arrow[{r[s], r[s] + uT[s]}]},
                       {Thick, Darker @ Green, Arrow[{r[s], r[s] + vB[s]}]},
                       {Thick, Darker @ Cyan, Arrow[{r[s], r[s] + vN[s]}]}}],
          PlotRange -> {{-2, 2}, {-2, 2}, {-2, 2}}, ViewPoint -> {4, 6, 0},
          ImageSize -> 600],
          {s, -1, 1}]

frame[r_] := Function[{t}, Evaluate[FullSimplify[
  Append[#, Cross @@ #] &@ Orthogonalize[D[r[t], {t, #}] & /@ {1, 2}, Dot],
  Assumptions -> t [Element] Reals]]]

frame[{#, #^2, #^3} &][t] // TraditionalForm

bigT={1,2t,3t^2}/Sqrt[1+4 t^2+9 t^4]

bigT/. t-> 2

BigTFunction[x_]:= {1,2x,3x^2}/Sqrt[1+4 x^2+9 x^4]

BigTFunction[2]

FrenetSerretSystem[{ x1, ..., xn}, t]  gives the generalized curvatures
and Frenet-Serret basis for the parametric curve x[t]
i.e.
it returns {{ k1, ..., k(n-1)}, { e1, ..., en}}, where ki are generalized curvatures
and ei are the Frenet-Serret basis vectors.

FrenetSerretSystem[ r[t], t] // TraditionalForm

r[t_] := {t, t^2, t^3}

FrenetSerretSystem[ r[t], t] // Last // Simplify // Column // TraditionalForm