vectorDiv = {
	_returnValue=[];
	_vector = _this select 0;
	_divisor = _this select 1;
	{
		_returnValue pushBack (_x / _divisor);
		nil
	} count _vector;
	_returnValue
};

_handle = [{
	if((cameraView == "GUNNER" && vehicle player isKindOf "Air")|| ((UAVControl getConnectedUAV  player) select 1 == "Gunner")) then {
		{
			_center = positionCameraToWorld [0,0,3];
			_x params ["_letter", "_color", "_offset1", "_offset2"];
			_div= ((call CBA_fnc_getFov)select 1);
			_offset1 = [_offset1, _div] call vectorDiv;
			_offset2 = [_offset2, _div] call vectorDiv;
			drawIcon3D [
				"",
				_color,
				_center vectorAdd _offset1,
				0,
				0,
				0,
				_letter,
				2,
				0.05,
				"PuristaMedium"
			];
			drawIcon3D [
				"",
				_color,
				_center vectorAdd _offset2,
				0,
				0,
				0,
				".",
				2,
				0.05,
				"PuristaMedium"
			];
		} count [
			["N",[1,1,1,1],[0,1,0],[0,0.5,0]],
			["S",[1,1,1,0.7],[0,-1,0],[0,-0.5,0]],
			["E",[1,1,1,0.7],[1,0,0],[0.5,0,0]],
			["W",[1,1,1,0.7],[-1,0,0],[-0.5,0,0]]
		];
	};
}] call CBA_fnc_addPerFrameHandler;