EntityName.var

15 %hplen
1 TICKS
EVENT(ENTITY) %entity
@entity ISPLAYER IF RETURN THEN
@entity NBTENTITY %container
@container "Health" NBTQUERY TOINTEGER %hp
@container "\"Bukkit.MaxHealth\"" NBTQUERY TOINTEGER %maxhp
@container "CustomName" NBTQUERY TOSTRING %name
@hp !IF RETURN THEN
@maxhp !IF RETURN THEN
@hp 0 < IF 0 %hp THEN
@hp @maxhp D/ %relhp
@relhp 0.95 > IF
    "\c2" %color
ELSE
    @relhp 0.7 > IF
        "\ca" %color
    ELSE
        @relhp 0.5 > IF
            "\ce" %color
        ELSE
            @relhp 0.3 > IF
                "\c6" %color
            ELSE
                @relhp 0.1 > IF
                    "\cc" %color
                ELSE
                    "\c4" %color
                THEN
            THEN
        THEN
    THEN
THEN
@name !IF
    @entity ENTITYTYPE %header
ELSE
    " " @hplen 0 DO{"|" S+} %hppattern
    @name CLEARCOLOR @hppattern ENDS IF
        "" %newname
        @name TOARRAY %arrayname
        @arrayname LEN 5 - @hplen - %len
        @len 0 DO{
            @arrayname I ELEMENT @newname SWAP S+ %newname
        }
        @newname %header
    ELSE
        @name %header
    THEN
THEN
@header LEN @hplen + 5 + 64 > IF RETURN THEN
@header @color S+ %header
@header " " S+ %header
@hplen @relhp D* TOINTEGER %displayhp
@displayhp 0 DO{
    @header "|" S+ %header
}
@header "\c0" S+ %header
@hplen @displayhp - 0 DO{
    @header "|" S+ %header
}
@container @header NBTSTRING "CustomName" NBTSETQUERY