scripttexportable

:: ------SCRIPT D'INSTALLATION/UTILISATION AUTO TEX PORTABLE ---------------
:: v1.0     version initiale
:: -------------------------------------------------------------------------

@echo off
:: chemin du script (le \ est ok)
set chemin=%~dp0
set chemindouble=%chemin:\=\\%
:: variables des fichiers du site
set site=https://texportable.cpierquet.fr
set thonnyzip=%site%/fichiers/LOGICIELS/MATHS/thonny-windows-portable.zip
set texstudiozip=%site%/fichiers/LOGICIELS/MATHS/texstudio-win-portable-qt5.zip
set scriptauto=%site%/fichiers/SCRIPTS/Config.Auto.Mini.bat
set scriptinstlog=%site%/fichiers/SCRIPTS/Installation.Logiciels.bat
set launchtex=%site%/fichiers/SCRIPTS/texstudio.cmd
set launchpyt=%site%/fichiers/SCRIPTS/thonny.cmd
set gnuplotzip=%site%/fichiers/LOGICIELS/MATHS/gnuplot.zip
set inifilezip=%site%/fichiers/LOGICIELS/SYSTEME/inifile.zip
set initoolzip=%site%/fichiers/LOGICIELS/SYSTEME/initool.zip
set miktexportable=%site%/fichiers/LOGICIELS/MATHS/miktex-portable.exe
set unzip=%site%/fichiers/SCRIPTS/unzip.exe
set everythingzip=%site%/fichiers/LOGICIELS/SYSTEME/everything.zip
set sumatrazip=%site%/fichiers/LOGICIELS/OUTILS/SumatraPDF.zip
set fichierstestszip=%site%/fichiers/SCRIPTS/fichierstest.zip
:: variables des executables
set texstudioini=logiciels\texstudio\config\texstudio.ini
set unzipexe=logiciels\unzip.exe
set thonnyexe=logiciels\thonny\thonny.exe
set miktexini=logiciels\miktex-portable\texmfs\config\miktex\config\miktex.ini
set miktexexe=logiciels\miktex-portable\texmfs\install\miktex\bin\x64\miktex-console.exe
set everythingexe=logiciels\everything\everything.exe
set inifileexe=logiciels\inifile.exe
set initoolexe=logiciels\initool.exe
set sumatraexe=logiciels\texstudio\sumatra.exe
set texstudioexe=logiciels\texstudio\texstudio.exe
set gnuplotexe=logiciels\gnuplot\bin\gnuplot.exe
:: variables des fichiers ini
set diction=%chemindouble%logiciels\\texstudio\\dictionaries
set pythonexe=%chemindouble%logiciels\\thonny\\python.exe
set pythontex=%chemindouble%logiciels\\miktex-portable\\texmfs\\install\\scripts\\pythontex\\pythontex.py
set pathgnuplot=%chemindouble%logiciels\\gnuplot\\bin
set paththonny=%chemindouble%logiciels\\thonny
set paththonnyscripts=%chemindouble%logiciels\\thonny\\Scripts
set pathmiktex=%chemindouble%logiciels\\miktex-portable\\texmfs\\install\\miktex\\bin\\x64
set pathirfanview=%chemindouble%logiciels\\irfanview
set pathmagick=%chemindouble%logiciels\\imagemagick
:: variables diverses
set typeproxy=Aucun

:intro
:: Presentation, variables, choix proxy
cls
echo.
echo --------------------------------------------------------
echo Utilisation/Configuration d'un dossier MiKTeX-compatible
echo   # Mode Nomade   = sur cle, la lettre peut changer
echo   # Mode Portable = sur disque dur
echo   * [OUTILS] MiKTeX + TeXstudio + Gnuplot + Thonny
echo   * [UTILES] Initool + Inifile + Unzip + Sumatra
echo.
echo Pour le moment, proxy : %typeproxy%
echo.
echo --------------------------------------------------------
echo  [c] Configuration automatique des logiciels............
echo --------------------------------------------------------
echo  [p] Configuration du proxy.............................
echo  [i] Installation initiale..............................
echo  [v] Verif. de l'install. et/ou install. suppl..........
echo  [x] Lancement de TeXstudio.............................
echo  [t] Lancement de Thonny................................
echo  [m] Lancement de la Concole MiKTeX.....................
echo.
echo  [e] Effacer les fichiers temporaires...................
echo  [q] Quitter............................................
echo --------------------------------------------------------
echo.
set choix=-1
set /p choix="Quel est votre choix ? "
IF "%choix%"=="p" GOTO proxy
IF "%choix%"=="i" GOTO installinit
IF "%choix%"=="v" GOTO installverifinitunzip
IF "%choix%"=="c" GOTO configauto
IF "%choix%"=="x" GOTO testtexstudio
IF "%choix%"=="t" GOTO testthonny
IF "%choix%"=="m" GOTO testconsole
IF "%choix%"=="e" GOTO efface
IF "%choix%"=="q" exit /b
goto intro

:efface
rmdir /Q /S %chemin%tmp
goto intro

:proxy
:: on demande si on est au boulot ou pas
set varproxy=n
set /p varproxy="Utilisation d'un proxy [o/n] ? "
set proxylycee=192.168.224.254
set portproxylycee=3128
:: en fonction on parametre la section du proxy :
IF "%varproxy%"=="n" (
    set "paramcurl= "
    set typeproxy=Aucun
)
IF "%varproxy%"=="o" (
    set /p proxylycee="IP du proxy (%proxylycee%) ? "
    set /p portproxylycee="Port du proxy (%portproxylycee%) ? "
    set "paramcurl=-x http://%proxylycee%:%portproxylycee% -k"
    set "typeproxy=%proxylycee%:%portproxylycee%"
)
goto intro

:installinit
:: creat des repertoires
echo.
echo [Etape 1/6] -- On cree les repertoires (si besoin)
mkdir %chemin%logiciels 2>NUL
mkdir %chemin%tmp 2>NUL
mkdir %chemin%logiciels\miktex-portable 2>NUL
:: on dl les zip/tar
echo.
echo [Etape 2/6] -- On rappatrie les fichiers utiles :
echo a/ On commence par unzip (bien utile ;-))
curl -sS -o %chemin%logiciels\unzip.exe %unzip% %paramcurl%
echo b/ ensuite Thonny
curl -sS -o %chemin%tmp\thonny.zip %thonnyzip% %paramcurl%
echo c/ puis Texstudio
curl -sS -o %chemin%tmp\texstudio.zip %texstudiozip% %paramcurl%
echo d/ et gnuplot
curl -sS -o %chemin%tmp\gnuplot.zip %gnuplotzip% %paramcurl%
echo e/ ainsi que les fichiers tests
curl -sS -o %chemin%tmp\fichierstest.zip %fichierstestszip% %paramcurl%
echo f/ sans oublier inifile et initool...
curl -sS -o %chemin%tmp\inifile.zip %inifilezip% %paramcurl%
curl -sS -o %chemin%tmp\initool.zip %initoolzip% %paramcurl%
echo g/ puis sumatra...
curl -sS -o %chemin%tmp\sumatra.zip %sumatrazip% %paramcurl%
echo h/ et MiKTeX...
curl -sS -o %chemin%tmp\miktex-portable.exe %miktexportable% %paramcurl%
echo i/ puis les scripts...
curl -sS -o %chemin%texstudio.cmd %launchtex% %paramcurl%
curl -sS -o %chemin%thonny.cmd %launchpyt% %paramcurl%
:: on extrait les archives, on renomme
echo.
echo [Etape 3/6] -- Extraction des logiciels et renommage
echo a/ on commence par Thonny
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\thonny.zip -d %chemin%logiciels\thonny
echo b/ puis Texstudio
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\texstudio.zip -d %chemin%logiciels\texstudio
echo c/ et sumatra
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\sumatra.zip -d %chemin%logiciels\texstudio
echo d/ et les fichiers test
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\fichierstest.zip -d %chemin%
echo e/ et gnuplot
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\gnuplot.zip -d %chemin%logiciels
echo f/ sans oublier inifile et initool
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\inifile.zip -d %chemin%logiciels
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\initool.zip -d %chemin%logiciels
echo g/ on renomme sumatra
ren %chemin%logiciels\texstudio\SumatraPDF*.exe sumatra.exe
:: on lance miktex
echo.
echo [Etape 4/6] -- Lancement de MiKTeX
echo %chemin%logiciels\miktex-portable|clip
echo [le chemin pour installer MiKTeX est dans le presse-papier := Ctrl+V pour le coller !!]
pause
%chemin%tmp\miktex-portable.exe
pause
:: on lance texstudio une 1ere fois pour les fichiers de config
echo.
echo [Etape 5/6] -- Lancement de TeXstudio (une seule fois) pour avoir un fichier de configuration ini
%chemin%logiciels\texstudio\texstudio.exe
pause
:: on lance thonny pour pygments
echo.
echo [Etape 6/6] -- On lance Thonny pour pygments
echo a/ Menu OUTILS\Ouvrir la console du systeme
echo pip install pygments|clip
echo b/ Coller (:= Ctrl+V) la commande pip install pygments
%chemin%logiciels\thonny\thonny.exe
pause
goto intro

:probleme
echo Logiciel non disponible...
pause
goto intro

:testconsole
:: on lance miktex-console si besoin
echo.
IF EXIST %chemin%%miktexexe% (goto lancementconsole) ELSE (goto probleme)

:lancementconsole
echo Lancement de la Console MikTeX
start "" %chemin%%miktexexe% --mkmaps
goto intro

:testtexstudio
:: on lance texstudio si besoin
echo.
IF EXIST %chemin%%texstudioexe% (goto lancementtexstudio) ELSE (goto probleme)

:lancementtexstudio
echo Lancement de TeXStudio
start "" %chemin%%texstudioexe%
goto intro

:testthonny
:: on lance thonny
echo.
IF EXIST %chemin%%thonnyexe% (goto lancementthonny) ELSE (goto probleme)

:lancementthonny
echo Lancement de Thonny
start "" %chemin%%thonnyexe%
goto intro

:installverifinitunzip
:: on anticipe si besoin
cls
echo.
mkdir %chemin%logiciels 2>NUL
mkdir %chemin%tmp 2>NUL
mkdir %chemin%logiciels\miktex-portable 2>NUL
goto installverifinit

:installverifinit
:: on verifie les infos en memoire et on stocke les resultats
IF EXIST %chemin%logiciels\unzip.exe (set unzipinstall=OK) ELSE (set unzipinstall=KO)
IF EXIST %chemin%%thonnyexe% (set thonnyinstall=OK) ELSE (set thonnyinstall=KO)
IF EXIST %chemin%%texstudioini% (set texstudioinstall=OK) ELSE (set texstudioinstall=KO)
IF EXIST %chemin%%everythingexe% (set everythinginstall=OK) ELSE (set everythinginstall=KO)
IF EXIST %chemin%%inifileexe% (set inifileinstall=OK) ELSE (set inifileinstall=KO)
IF EXIST %chemin%%initoolexe% (set initoolinstall=OK) ELSE (set initoolinstall=KO)
IF EXIST %chemin%%sumatraexe% (set sumatrainstall=OK) ELSE (set sumatrainstall=KO)
IF EXIST %chemin%%gnuplotexe% (set gnuplotinstall=OK) ELSE (set gnuplotinstall=KO)
IF EXIST %chemin%%miktexexe% (set miktexinstall=OK) ELSE (set miktexinstall=KO)
goto installdebut

:installdebut
echo.
echo ----------------------------------------
echo  Analyse des infos disponibles en stock
echo ----------------------------------------
echo Le dossier de travail est %chemin%
echo Proxy : %typeproxy%
echo.
echo Inifile.......%inifileinstall%   Initool......%initoolinstall%
echo TexStudio.....%texstudioinstall%   MiKTeX.......%miktexinstall%
echo Thonny........%thonnyinstall%   Gnuplot......%gnuplotinstall%
echo Everything....%everythinginstall%   Sumatra......%sumatrainstall%
echo Unzip.........%unzipinstall%
echo.
echo   [0] Configurer le Proxy
echo.
echo   [1] Installer Inifile       [2] Installer Initool
echo   [3] Installer TeXstudio     [4] Installer MikTeX
echo   [5] Installer Thonny        [6] Installer Gnuplot
echo   [7] Installer Everything    [8] Installer Sumatra
echo   [9] Installer Unzip
echo.
echo   [b] Retourner au menu initial
echo   [e] Supprimer les fichiers temporaires
echo   [q] Quitter
echo.
set choix=-1
set /p choix="Quel est votre choix ? "
IF "%choix%"=="1" GOTO installinifile
IF "%choix%"=="2" GOTO installinitool
IF "%choix%"=="3" GOTO installtexstudio
IF "%choix%"=="4" GOTO installmiktex
IF "%choix%"=="5" GOTO installthonny
IF "%choix%"=="6" GOTO installgnuplot
IF "%choix%"=="7" GOTO installeverything
IF "%choix%"=="8" GOTO installsumatra
IF "%choix%"=="9" GOTO installunzip
IF "%choix%"=="0" GOTO proxy
IF "%choix%"=="b" GOTO intro
IF "%choix%"=="e" GOTO efface
IF "%choix%"=="q" exit /b
goto installverifinit

:installinifile
curl -sS -o %chemin%tmp\inifile.zip %inifilezip% %paramcurl%
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\inifile.zip -d %chemin%logiciels
goto installverifinit

:installinitool
curl -sS -o %chemin%tmp\initool.zip %initoolzip% %paramcurl%
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\initool.zip -d %chemin%logiciels
goto installverifinit

:installtexstudio
curl -sS -o %chemin%tmp\texstudio.zip %texstudiozip% %paramcurl%
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\texstudio.zip -d %chemin%logiciels\texstudio
goto installverifinit

:installunzip
echo on
curl -o %chemin%logiciels\unzip.exe %unzip% %paramcurl%
goto installverifinit

:installsumatra
curl -sS -o %chemin%tmp\sumatra.zip %sumatrazip% %paramcurl%
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\sumatra.zip -d %chemin%logiciels\texstudio
ren %chemin%logiciels\texstudio\SumatraPDF*.exe sumatra.exe
goto installverifinit

:installgnuplot
curl -sS -o %chemin%tmp\gnuplot.zip %gnuplotzip% %paramcurl%
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\gnuplot.zip -d %chemin%logiciels
goto installverifinit

:installthonny
curl -sS -o %chemin%tmp\thonny.zip %thonnyzip% %paramcurl%
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\thonny.zip -d %chemin%logiciels\thonny
goto installverifinit

:installeverything
curl -sS -o %chemin%tmp\everything.zip %everythingzip% %paramcurl%
%chemin%logiciels\unzip.exe -o -q %chemin%tmp\everything.zip -d %chemin%logiciels\everything
goto installverifinit

:installmiktex
curl -sS -o %chemin%tmp\miktex-portable.exe %miktexportable% %paramcurl%
echo %chemin%logiciels\miktex-portable|clip
echo [le chemin pour installer MiKTeX est dans le presse-papier := Ctrl+V pour le coller !!]
pause
%chemin%tmp\miktex-portable.exe
goto installverifinit

:configauto
cls
IF EXIST %chemin%logiciels\inifile.exe (set exeinifile=OK) ELSE (echo. & echo Inifile.exe := KO & goto probleme)
IF EXIST %chemin%logiciels\initool.exe (set exeinitool=OK) ELSE (echo. & echo Initool.exe := KO & goto probleme)
IF EXIST %chemin%logiciels\texstudio\texstudio.exe (set exetexstudio=OK) ELSE (echo. & echo TexStudio.exe := KO & goto probleme)
IF EXIST %chemin%logiciels\texstudio\config\texstudio.ini (set initexstudio=OK) ELSE (echo. & echo TexStudio.ini := KO & goto probleme)
IF EXIST %chemin%logiciels\miktex-portable\texmfs\config\miktex\config\miktex.ini (set inimiktex=OK) ELSE (echo. & echo Miktex.ini := KO & goto probleme)
IF EXIST %chemin%logiciels\miktex-portable\texmfs\install\miktex\bin\x64\miktex-console.exe (set exemiktex=OK) ELSE (echo. & echo MiKTeX.exe := KO & goto probleme)
IF EXIST %chemin%logiciels\thonny\thonny.exe (set exethonny=OK) ELSE (echo. & echo Thonny.exe := KO & goto probleme)
IF EXIST %chemin%logiciels\gnuplot\bin\gnuplot.exe (set exegnuplot=OK) ELSE (echo. & echo Gnuplot.exe := KO & goto probleme)
FOR /F %%i IN ('%chemin%logiciels\initool.exe g %chemin%%miktexini% MPM UseProxy --value-only') do (SET memproxyuse=%%i)
FOR /F %%i IN ('%chemin%logiciels\initool.exe g %chemin%%miktexini% MPM ProxyHost --value-only') do (SET memproxyadresse=%%i)
FOR /F %%i IN ('%chemin%logiciels\initool.exe g %chemin%%miktexini% MPM ProxyPort --value-only') do (SET memproxyport=%%i)
FOR /F %%i IN ('%chemin%logiciels\initool.exe g %chemin%%texstudioini% texmaker Spell\DictionaryDir --value-only') do (SET memtexstudio=%%i)
echo.
echo ------------------------------------------
echo   Analyse des infos disponibles en stock
echo ------------------------------------------
echo Inifile.exe.......%exeinifile%  Initool.exe.......%exeinitool%
echo TeXstudio.exe.....%exetexstudio%  TeXstudio.ini.....%initexstudio%
echo MiKTeX.exe........%exemiktex%  MiKTeX.ini........%inimiktex%
echo Thonny.exe........%exethonny%  Gnuplot.exe.......%exegnuplot%
echo.
echo Le proxy de MiKTeX est en %memproxyuse% avec l'adresse %memproxyadresse%:%memproxyport%
echo Le dossier de travail est %chemin%
echo Texstudio va chercher les fichiers dans %memtexstudio:\\texstudio\\Dictionaries=%
echo.
echo   [1] Configuration du proxy
echo   [2] Configurer TeXStudio
echo   [3] Lancer MiKTeX-Console
echo   [4] Lancer TeXstudio
echo   [5] Lancer Thonny
echo.
echo   [b] Retour
echo   [q] Quitter
echo.
set choix=-1
set /p choix="Quel est votre choix ? "
IF "%choix%"=="1" GOTO proxyconf
IF "%choix%"=="2" GOTO configtexstudio
IF "%choix%"=="3" GOTO miktexconsole
IF "%choix%"=="4" GOTO texstudio
IF "%choix%"=="5" GOTO thonny
IF "%choix%"=="b" GOTO intro
IF "%choix%"=="q" exit /b
goto configauto

:proxyconf
:: on demande si on est au boulot ou pas
set varproxy=n
set /p varproxy="Utilisation d'un proxy [o/n] ? "
set proxylycee=192.168.224.254
set portproxylycee=3128
:: en fonction on parametre la section du proxy :
IF "%varproxy%"=="n" (
    %chemin%logiciels\inifile.exe %chemin%%miktexini% [MPM] ProxyHost=127.0.0.1
    %chemin%logiciels\inifile.exe %chemin%%miktexini% [MPM] ProxyPort=8080
    %chemin%logiciels\inifile.exe %chemin%%miktexini% [MPM] UseProxy=false
)
IF "%varproxy%"=="o" (
    set /p proxylycee="IP du proxy (%proxylycee%) ? "
    set /p portproxylycee="Port du proxy (%portproxylycee%) ? "
)
IF "%varproxy%"=="o" (
    %chemin%logiciels\inifile.exe %chemin%%miktexini% [MPM] ProxyHost=%proxylycee%
    %chemin%logiciels\inifile.exe %chemin%%miktexini% [MPM] ProxyPort=%portproxylycee%
    %chemin%logiciels\inifile.exe %chemin%%miktexini% [MPM] UseProxy=true
)

goto configauto

:configtexstudio
echo.
echo Lancement de la Configuration de TeXStudio
:: on injecte la lettre dans le PATH dans texstudio
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] "Tools\Search%%20Paths"="%pathgnuplot%;%paththonny%;%pathmiktex%;%paththonnyscripts%;%pathirfanview%;%pathmagick%"
:: on modifie les exe (si jamais texstudio les change...)
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\latex="latex.exe -src synctex=0 -interaction=nonstopmode %%.tex"
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\pdflatex="pdflatex.exe -synctex=0 -interaction=nonstopmode %%.tex"
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\xelatex="xelatex.exe -synctex=0 -interaction=nonstopmode %%.tex"
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\lualatex="lualatex.exe -synctex=0 -interaction=nonstopmode %%.tex"
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\view-dvi=yap.exe %%.dvi
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\view-pdf-external=sumatra.exe %%.pdf
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\dvips=dvips.exe -o %%.ps %%.dvi
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\dvipng=dvipng.exe -T tight -D 120 %%.dvi
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\ps2pdf=ps2pdf.exe %%.ps
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\dvipdf=dvipdfmx.exe %%.dvi
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\bibtex=bibtex.exe %%
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\bibtex8=bibtex8.exe %%
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\biber=biber.exe %%
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\makeindex=makeindex.exe %%.idx
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\texindy=texindy.exe %%.idx
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\makeglossaries=makeglossaries.exe %%
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\metapost="mpost.exe -interaction=nonstopmode ?me)"
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\asy=asy.exe ?m*.asy
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\gs=mgs.exe \"?am.ps\"
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\latexmk="latexmk.exe -pdf -silent -synctex=1 %%"
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\texdoc="texdoc.exe "
:: on injecte la compilation pythonpdflatex
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\pythonpdflatex="txs:///pdflatex/[-draftmode] | %pythonexe% %pythontex% --rerun=always %%.tex | txs:///pdflatex | txs:///view-pdf"
:: on injecte la compilation pythonlualatex
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\pythonlualatex="txs:///lualatex/[-draftmode] | %pythonexe% %pythontex% --rerun=always %%.tex | txs:///lualatex | txs:///view-pdf"
:: on injecte la lettre pour les dictionnaires
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Spell\DictionaryDir=%diction%
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Spell\Language=fr_FR
:: on injecte sumatra
%chemin%logiciels\inifile.exe %chemin%%texstudioini% [texmaker] Tools\Commands\view-pdf-external=sumatra.exe %%.pdf
:: on injecte la lettre pour everything
%chemin%logiciels\inifile.exe %chemin%%everythingini% [Everything] folders="%chemindouble%"
goto configauto

:miktexconsole
:: on lance miktex-console si besoin
echo.
echo Lancement de la Console MikTeX
start "" %chemin%%miktexexe% --mkmaps
goto configauto

:texstudio
:: on lance texstudio
echo.
echo Lancement de TeXStudio
start "" %chemin%%texstudioexe%
goto configauto

:thonny
:: on lance texstudio
echo.
echo Lancement de Thonny
start "" %chemin%%thonnyexe%
goto configauto