DESCRIPTION = "Bonjour, also known as zero-configuration networking, enables automatic discovery of computers, devices, and services on IP networks."
HOMEPAGE = "http://developer.apple.com/networking/bonjour/"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://LICENSE;md5=31c50371921e0fb731003bbc665f29bf"

PR = "r1"

TARGET_CC_ARCH += "${LDFLAGS}"

inherit systemd

SRC_URI = "http://opensource.apple.com/tarballs/mDNSResponder/mDNSResponder-${PV}.tar.gz \
           file://0001-fixed-posix-build.patch \
           file://DirectLink-optimization.patch \
           file://mdns.service \
"

INSANE_SKIP_${PN} += "dev-so file-rdeps"

SRC_URI[md5sum] = "16dc2098f97fe5347c82c898566befb4"
SRC_URI[sha256sum] = "8efdd7d57445f4defdb450217c31afc5c5d258822764bb02f4e8282430b33119"

S = "${WORKDIR}/mDNSResponder-${PV}"

EXTRA_OEMAKE = 'CC="${CC}" LD="${CC}"'

do_compile () {
	cd mDNSPosix
	oe_runmake os=linux DEBUG=0
}

do_install () {
    install -d ${D}${bindir}
    install -m 755 ${S}/Clients/build/dns-sd    ${D}${bindir}/

    install -d ${D}${includedir}
    install -m 644 ${S}/mDNSShared/dns_sd.h     ${D}${includedir}/

    install -d ${D}${sysconfdir}
    install -m 644 ${S}/mDNSPosix/nss_mdns.conf ${D}${sysconfdir}/

    install -d ${D}${libdir}
    install -m 755 ${S}/mDNSPosix/build/prod/libdns_sd.so       ${D}${libdir}/libdns_sd.so.1
    install -m 755 ${S}/mDNSPosix/build/prod/libnss_mdns-0.2.so ${D}${libdir}/libnss_mdns.so.2

    ln -sf libdns_sd.so.1     ${D}${libdir}/libdns_sd.so
    ln -sf libnss_mdns.so.2   ${D}${libdir}/libnss_mdns-0.2.so

    install -d ${D}${sysconfdir}/systemd/system
    install -m 644 ${WORKDIR}/mdns.service     ${D}${sysconfdir}/systemd/system

    install -d ${D}${sbindir}
    install -m 755 ${S}/mDNSPosix/build/prod/mdnsd  ${D}${sbindir}

    install -d ${D}/usr/share/man/man5
    install -d ${D}/usr/share/man/man8
}


SYSTEMD_SERVICE_${PN} = "mdns.service"
PACKAGE_DEBUG_SPLIT_STYLE = "debug-without-src"

pkg_postinst_${PN} () {
    sed -e '/^hosts:/s/\s*\<mdns\>//' \
        -e 's/\(^hosts:.*\)\(\<files\>\)\(.*\)\(\<dns\>\)\(.*\)/\1\2 mdns\3\4\5/' \
        -i $D/etc/nsswitch.conf
}

pkg_prerm_${PN} () {
    sed -e '/^hosts:/s/\s*\<mdns\>//' \
        -e '/^hosts:/s/\s*mdns//' \
        -i $D/etc/nsswitch.conf
}

FILES_${PN} += "${libdir} \
                ${sysconfdir} \
                ${bindir} \
                ${sbindir} \
                ${includedir} \
"

FILES_${PN}-dev += "${includedir}"

FILES_${PN}-dbg += "${libdir}/.debug/*"

FILES_${PN}-man += "${mandir}/man8/mdnsd.8 \
                    ${mandir}/man5/nss_mdns.conf.5 \
                    ${mandir}/man8/libnss_mdns.8 \
"