/*
    Author: Maxence Lyon
    Altis DEV: https://altisdev.com/user/maxence-lyon
    Teamspeak 3: ts.the-programmer.com
    Web site: www.the-programmer.com
    Steam: « Une Vache Sur CS – Maxence », please leave a message on my profile who says the exact reason before adding me.

    Terms of use:
        - This file is forbidden unless you have permission from the author. If you have this file without permission to use it please do not use it and do not share it.
        - If you have permission to use this file, you can use it on your server however it is strictly forbidden to share it.
        - Out of respect for the author please do not delete this information.

    License number:
    Server's name:
    Owner's name:
*/
disableSerialization;

if ((lbCurSel 5013) isEqualTo -1) exitWith {hint localize "STR_Global_NoSelection";};

_dataArr = lbData [5013,(lbCurSel 5013)];
_vehicleData = call compile format ["%1",_dataArr];
_className = _vehicleData select 1;
_vehicleLife = _className;

_vid = lbValue [5013,(lbCurSel 5013)];
_pid = _vehicleData select 2;
_unit = player;
_exit = false;

if !(_pid isEqualTo (getPlayerUID player)) then {
    _action = [
        format [(["STR_CONFIRM_UNIMPOUND_TEXT","Max_Settings_Fourriere","Fourriere_Localization"] call theprogrammer_core_fnc_localize),(_vehicleData select 5)],
        (["STR_CONFIRM_UNIMPOUND_HEADER","Max_Settings_Fourriere","Fourriere_Localization"] call theprogrammer_core_fnc_localize),
        (["STR_CONFIRM","Max_Settings_Fourriere","Fourriere_Localization"] call theprogrammer_core_fnc_localize),
        (["STR_CANCEL","Max_Settings_Fourriere","Fourriere_Localization"] call theprogrammer_core_fnc_localize)
    ] call BIS_fnc_guiMessage;

    if !(_action) then {_exit = true;};
};
if (_exit) exitWith {};

if (isNil "_className") exitWith {hint localize "STR_Garage_Selection_Error";};

if !(isClass (missionConfigFile >> "LifeCfgVehicles" >> _vehicleLife)) then {
    _vehicleLife = "Default";
    diag_log format ["%1: LifeCfgVehicles class doesn't exist",_className];
};

_price = getNumber (missionConfigFile >> "LifeCfgVehicles" >> _vehicleLife >> "price");
_config = missionConfigFile >> "Max_Settings_Fourriere";

_vehicle_four_multiplier = getNumber (_config >> "price_unimpound");

if (([] call max_fourriere_fnc_checkConditionFourriere) isEqualTo "all") then {
    _vehicle_four_multiplier = getNumber (_config >> "price_unimpound_condition_matched");
};

_purchasePrice = _price * (getNumber (missionConfigFile >> "Life_Settings" >> "vehicle_purchase_multiplier_CIVILIAN"));
_price = _purchasePrice * _vehicle_four_multiplier;

if (_price < (getNumber (_config >> "minimum_retreive_price"))) then {_price = (getNumber (_config >> "minimum_retreive_price"));};
if (life_atmbank < _price) exitWith {hint format [(localize "STR_Garage_CashError"),[_price] call life_fnc_numberText];};

if (life_fourriere_sp isEqualType []) then {
    [_vid,_pid,(life_fourriere_sp select 0),_unit,_price,(life_fourriere_sp select 1),(localize "STR_Garage_spawn_Success")] remoteExec ["TON_fnc_spawnVehicle",2];
} else {
    [_vid,_pid,(getMarkerPos life_fourriere_sp),_unit,_price,(markerDir life_fourriere_sp),(localize "STR_Garage_spawn_Success")] remoteExec ["TON_fnc_spawnVehicle",2];
};

[0,_pid,(_vehicleData select 4)] remoteExec ["max_fourriere_fnc_updateFourriere",2];

hint localize "STR_Garage_SpawningVeh";
life_atmbank = life_atmbank - _price;
if !(isNil "masterpay_script_enable_and_ready") then {
    if (masterpay_script_enable_and_ready) then {
        _vehicleName = getText (configFile >> "CfgVehicles" >> _vehicleLife >> "displayName");
        [player,(["STR_IMPOUND_MENU_FROM","The_Programmer_Settings_MasterPay","MasterPay_Localization"] call theprogrammer_core_fnc_localize),_price,format [(["STR_IMPOUND_MENU_DESCRITPION","The_Programmer_Settings_MasterPay","MasterPay_Localization"] call theprogrammer_core_fnc_localize),_vehicleName]] spawn masterpay_fnc_updateBank;
    };
};
[1] call SOCK_fnc_updatePartial;
closeDialog 0;

_companyID = getNumber (_config >> "send_money_to_company_id");
if !(_companyID isEqualTo -1) then {
    _company = objNull;
    {
        if ((_x select 0) isEqualTo _companyID) exitWith {_company = (_x select 1);};
    } foreach maxence_all_entreprises;

    if !(isNull _company) then {
        _oldEntACC = _company getVariable ["entreprise_bankacc",0];
        _oldEntACC = _oldEntACC + _price;
        _company setVariable ["entreprise_bankacc",_oldEntACC,true];
        [(_company getVariable ["entreprise_id",0]),5,(_company getVariable ["entreprise_bankacc",0])] remoteExecCall ["max_entreprise_fnc_updateEntreprise",2];
        [_company,format ["%1 : %2",(name player),(["STR_UNIMPOUND_FEE","Max_Settings_Fourriere","Fourriere_Localization"] call theprogrammer_core_fnc_localize)],_price,2] remoteExecCall ["max_entreprise_fnc_insertEntrepriseLogs",2];
    };
};