white 2 sub_217DB34 rewrite

.nds
.thumb

BLACK2 equ 0

.if BLACK2
getBaseBlk            equ 0x02016A98
getFieldMapWorkBlock  equ 0x02016AB0
getDayPartForSeason   equ 0x02163134
sub_2180518           equ 0x021804D8
getEncounterBlk       equ 0x02180524
sub_21A23D8           equ 0x021A2398
.else
getBaseBlk            equ 0x02016AD8
getFieldMapWorkBlock  equ 0x02016AF0
getDayPartForSeason   equ 0x02163174
sub_2180518           equ 0x02180518
getEncounterBlk       equ 0x02180564
sub_21A23D8           equ 0x021A23D8
.endif

.org BLACK2 ? 0x0217DAF4 : 0x0217DB34

.area 0x0217DB80 - 0x0217DB34

sub_217DB34:
    PUSH    {R3-R7,LR}
    MOV     R7, R1
    MOV     R5, R0
    MOV     R0, R7          // gsys
    BL      getBaseBlk
    MOV     R6, R0
    MOV     R0, R7          // pSysBlock
    BL      getFieldMapWorkBlock
    STR     R0, [SP]
    MOV     R0, R6          // pBaseBlk
    BL      getDayPartForSeason // replace getSeasonValue

// 0 -> 0, 1-2 -> 1, 3-4 -> 2
// 2 new instructions
    add r0, #1
    lsr r4, r0, #1

    //MOV     R4, R0 // take 1 out
    LDR     R0, [SP]
    STR     R7, [R5]
    STR     R6, [R5,#4]
    STR     R0, [R5,#8]
    BL      sub_2180518
    STRH    R0, [R5,#0xC]
    MOV     R0, #0
    STR     R0, [R5,#0x40]
    STR     R0, [R5,#0x44]
    MOV     R0, R5
    ADD     R0, #0x48
    STRH    R4, [R0]
    //MOV     R0, R5 // take another out
    ADD     R0, #0x2 // modified
    STRH    R4, [R0]
    LDR     R0, [R5,#8]
    BL      getEncounterBlk
    MOV     R1, #1
    BL      sub_21A23D8
    POP     {R3-R7,PC}

.endarea