Calculadora REPITA Portugo

algoritmo "Calculadora"

var
opcao: caractere
n1, n2: real
inicio
repita
   escreval("***********************")
   escreval("1 - Soma")
   escreval("2 - Subtração")
   escreval("3 - Multiplicação")
   escreval("4 - Divisão")
   escreval("5 - Exponenciação")
   escreval("6 - SAIR")
   escreva("Escolha uma opção: ")
   leia(opcao)
   // Executar apenas se a pessoa NÃO escolher 6:
   se opcao<>"6" entao
      // Ler os números n1 e n2:
      escreva("Digite o primeiro valor: ")
      leia(n1)
      escreva("Digite o segundo valor: ")
      leia(n2)
   fimse
   // Limpar a tela:
   limpatela
   // Verificar qual opção a pessoa escolheu:
   escolha opcao
    caso "1"
         escreva(n1+n2)
    caso "2"
         escreva(n1-n2)
    caso "3"
         escreva(n1*n2)
    caso "4"
         se n2=0 entao
            escreva("Não é possível dividir por zero!")
         senao
            escreva(n1/n2)
         fimse
    caso "5"
         escreva(n1^n2)
    caso "6"
         escreva("CALCULADORA ENCERRADA!")
    // Caso a pessoa não escolha uma opção valida:
    outrocaso
         escreva("Opção inválida!")
   fimescolha
   // Pular uma linha no final
   escreval("")

ate opcao="6"

fimalgoritmo