Public Class Form1
    Inherits System.Windows.Forms.Form

#Region " Windows Form Designer generated code "

#End Region

    '************************************************************************'
    '*         Strategi:   D A T O     S K A L    R E G I S T R E R E S     *'
    '*                                                                      *'
    '*  Hva må endres i programmet når dato skal med?
    '*      - Utvide den egendefinerte datatypen
    '*      - Endre konstanten postLengde
    '*      - Legge til en ekstra tekstboks
    '*      - Lese inn informasjonen fra denne tekstboksen
    '*      - Brukte ikke With ved innlegging i egendefinert datatype
    '*        overalt i leksjonen, men det er ingen grunn til ikke å
    '*        gjøre det konsekvent i øvingen. With er viktig!
    '*  MERK:
    '*      - Siden oppgave 2 består i å lage kode for å hoppe helt
    '*        først og helt sist, men fortsatt vise koden i tekstfelt,
    '*        er det lurt å generalisere denne visningen ut i en egen
    '*        prosedyre som kan kalles opp.
    '*      - Kan også kalle denne prosedyren fra de knappene som blar
    '*        bare en og en post.
    '*      - Prosedyren heter visInformasjonITekstbokser()                 *'
    '*                                                                      *'
    '************************************************************************'


    '************************************************************************'
    '*         Strategi:   S L E T T I N G     A V    S T U D E N T E R     *'
    '*                                                                      *'
    '*  Fakta:
    '*      - Sletting av studenter (XTRA) er ikke helt enkelt å få til.
    '*      - I første øyekast innebærer det å måtte reorganisere filen
    '*        og fjerne den posten som skal slettes. Dette er tidkrevende.
    '*      - En vanlig teknikk er derfor å rett og slett legge til et nytt
    '*        felt som heter Slettet.
    '*              - Dersom dette feltet har verdi TRUE er posten
    '*                ikke-eksisterende.
    '*              - Dersom det er FALSE, har posten data.
    '*      - En annen strategi er å blanke ut alle felt
    '*      - En kan også sette teksten "SLETTET" i for eksempel første
    '*        felt Navn for de poster som skal slettes.
    '*      - I dette løsningsforslaget bruker vi den siste teknikken.
    '*
    '*  Konsekvens for Bla-funksjonaliteten:
    '*      - Det er ikke bra dersom slettede poster faktisk vises i
    '*        grensesnittet.
    '*      - Dette kan unngås ved å sjekke i Bla-knappene om posten er
    '*        slettet, og i så fall bla videre inntil en post
    '*        som ikke er slettet treffes på.
    '*      - MERK: Implementerer ikke dette i denne løsningen
    '*
    '*  Konsekvens for innlegging av nye studenter:
    '*      - Dette bør fortsatt skje på slutten av filen, siden det er
    '*        tidkrevende å søke gjennom filen og legge inn en ny student
    '*        på en gammel slettet-post.
    '*
    '*  Konsekvens for filen som sådan:
    '*      - En kan kjøre en "garbage collection" (opprydningsrutine)
    '*        med jevne mellomrom som kopierer bare de postene som har
    '*        fornuftige data over til en ny fil, og så slette hele den
    '*        gamle filen. Dermed fjerner en de tomme postene for godt.
    '*      - Det er for øvrig ofte regnet som viktig å ta vare på data,
    '*        selv om de skal slettes. Dette for statistikkens skyld.
    '*        Kanskje det er interessant å se hvor mange som er slettet?
    '*        Eller å rekonstruere data? I så fall må en enten bruke et
    '*        arkiv, eller bare markere slettede poster med et flagg
    '*        eller teksten SLETTET. Lurt? Slike teknikker er mye brukt,
    '*        både i fil- og databaseløsninger!                             *'
    '*                                                                      *'
    '************************************************************************'


    '************************************************************************'
    '*         G  L  O  B  A  L  E        V  A  R  I  A  B  L  E  R         *'
    '*                                                                      *'
    '*    Her er definisjonen av vår egendefinerte datatype, StudentPost
    '*    og globale variabler (og konstanter) som brukes
    '*    av flere prosedyrer og knapper i programmet                       *'
    '*                                                                      *'
    '************************************************************************'

    Structure StudentPost
        ' Tallet i parantesen til konstanten VBFixedString
        ' står for lengden på hvert enkeltfelt
        ' Den totale postlengden blir summen av hvert felt,
        ' det vil si 60 for strengene og 8 for dato,
        ' totalt 68

        <VBFixedString(30)> Public Navn As String
        <VBFixedString(5)> Public Klasse As String
        <VBFixedString(25)> Public EPost As String
        Public Bursdag As Date
    End Structure


    'Deklarerer en variabel av typen som vi har opprettet nettopp.
    'Innlesing og skriving av en student mellomlagres her.
    Private minStudent As StudentPost

    'Lager en konstant for å holde rede på postlengden (her 68 bytes)
    Const postLengde = 68

    'Inneholder totalt antall studenter i filen
    Private Antall As Integer

    'Holder rede på hvilken post som skal skrives til eller leses fra
    'i filen. Dette tallet angir altså riktig posisjon til enhver tid.
    Private Posisjon As Integer

    'En fil har et logisk nummer. Lager en global
    'variabel slik at filnummeret kan brukes av alle prosedyrene.
    Private FilNummer As Integer


    '************************************************************************'
    '*         V  I  K  T  I  G   -  egne prosedyrer lages her              *'
    '*                                                                      *'
    '*    Vi ser et mønster hvor flere hendelsesprosedyrer
    '*    skal utføre samme kode: nemlig å skrive noe til skjerm
    '*    Lager derfor egne prosedyrer som gjør dette                       *'
    '*                                                                      *'
    '************************************************************************'



    ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    ' Navn:         visInformasjonITekstbokser                               '
    ' Argumenter:   en post av type StudentPost                              '
    ' Hva skjer?    Overfører innholdet i posten til tekstboksene på         '
    '               skjermen.                                                '
    ' Merk:         Bruker With til å hente ut spesielle felt.               '
    '               Dette er en egendefinert prosedyre som må kalles fra     '
    '               steder der en ønsker å slette tekstfeltenes innhold, for '
    '               eksempel i knappene "Lagre" og "Bla neste".              '
    ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    Private Sub visInformasjonITekstbokser(ByVal post As StudentPost)
        With post  'argumentet post er nå som en lokal variabel å regne
            txtNavn.Text = .Navn   'uten With: txtNavn.Text = minStudent.Navn
            txtKlasse.Text = .Klasse
            txtEpost.Text = .EPost
            txtFodselsdato.Text = .Bursdag
        End With
    End Sub


    ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    ' Navn:         fjernTekstFraTekstFelter                                 '
    ' Argumenter:   Ingen                                                    '
    ' Hva skjer?    Fjerner det som ligger i tekstfeltene.                   '
    ' Merk:         Dette er en egendefinert prosedyre som må kalles fra     '
    '               steder der en ønsker å slette tekstfeltenes innhold, for '
    '               eksempel i knappen "Blank ut felter".                    '
    ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    Private Sub fjernTekstFraTekstFelter()
        txtNavn.Text = ""
        txtKlasse.Text = ""
        txtEpost.Text = ""
        txtFodselsdato.Text = ""
    End Sub








    '-----------------------------------------------------------------------------------------------------------
    ' Knapp:    Sletter gjeldende post
    ' Strategi: Har riktig posisjon allerede, så det er bare å manipulere innholdet
    '           i den posten som Posisjon peker mot.
    '           Sletter opplysningene ved å sette inn teksten slettet hvor studentens navn er
    '           Blanker også ut de andre feltene og setter datoen til 1.1.3000  (som ingen kan være født på)
    ' Merk:     Se også kommentarene helt øverst i koden.
    '           Posisjon endres ikke her, men i en fullgod løsning bør den også oppdateres til noe forutsigbart
    '-----------------------------------------------------------------------------------------------------------
    Private Sub Button8_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button8.Click
        Dim bekreft As Integer = MsgBox("Vil du virkelig slette denne studenten?")
        If bekreft = vbOK Then
            With minStudent
                .Navn = "SLETTET"
                .Klasse = ""
                .EPost = ""
                .Bursdag = CDate("1.1.3000")  'å nullstille en dato betyr å velge en dato vi selv mener er null
            End With
            fjernTekstFraTekstFelter()  'Indikerer overfor brukeren at posten ble slettet
            FilePut(FilNummer, minStudent, Posisjon)  'Skriver informasjonen til fil, nå med tekst slettet
            MsgBox("Studenten ble slettet")  'Gir en bekreftende beskjed
        Else
            MsgBox("Studenten ble ikke slettet")  'Hvis Avbryt trykkes slettes ingenting
        End If

        'MERK: Posisjon er ikke endret.
    End Sub




    '-----------------------------------------------------------------------------------------------------------
    ' Knapp:    Åpne filen
    ' Strategi: Åpner filen og klargjør alt for bruk.
    '           - Når denne knappen trykkes, vil enten
    '               a) en ny fil lages dersom det ikke eksisterer noen fil fra før.
    '               b) eksisterende fil åpnes, og første post leses inn i tekstfeltene.
    ' Merk:     - Postlengden er 68 (30+5+25+8).
    '           - Posisjon initialiseres enten til 1 eller 0.
    '           - Denne knappen må trykkes før noe annet. Det er en litt dum løsning. En bedre strategi
    '             er å legge inn koden i form_load-prosedyren, så klargjørs filen i det programmet starter.
    '           - Skriver posisjonen til tekstfeltet txtViserPostNr
    ' Kaller:   Prosedyren VisInformasjonITekstbokser   [definert øverst i koden]
    '-----------------------------------------------------------------------------------------------------------
    Private Sub Button14_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button14.Click
        'Henter det neste tilgjengelige filnummeret vha innebygd funksjon.
        FilNummer = FreeFile()

        'Åpner filen med FileOpen setningen. Her spesifiserer vi det
        'logiske filnummeret, den fysiske adressen til filen, modus,
        'lar to argumenter stå tomme, og angir tilslutt lengde på posten
        FileOpen(FilNummer, "student.dat", OpenMode.Random, , , postLengde)

        'Finner hvor mange studenter det er i registeret
        'ved å dele fillengden på postlengden
        Antall = FileLen("student.dat") / postLengde

        'Hvis det finnes noe på filen, er det registrert studenter fra før.
        'Strategien er å lese første post fra filen inn i en variabel
        'og så legge innholdet i denne variabelen ut på skjerm.
        'Samtidig oppdaterer vi posisjonspekeren slik at vi vet hvor
        'på filen vi skal lese fra neste gang. Dette er viktig!
        If Antall > 0 Then
            'Leser inn den studenten som ligger i første post på
            'filen, og legger denne posten inn i variabelen minStudent
            FileGet(FilNummer, minStudent, 1)

            ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
            ' NYTT: Skriver ut informasjonen på skjerm i tekstbokser '
            ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
            visInformasjonITekstbokser(minStudent)

            'Holder rede på hvor vi er kommet i filen
            Posisjon = 1
        Else
            Posisjon = 0  'Dersom filen er tom, settes Posisjon til 0.
        End If
        'Oppgir hvilken post som vises nå
        txtViserPostNr.Text = Posisjon

    End Sub




    '-----------------------------------------------------------------------------------------------------------
    ' Knapp:    Blanke ut tekstfeltene
    ' Strategi: Blanker ut, og gir deretter fokus til tekstfeltet, slik at det bare er å skrive rett inn.
    '-----------------------------------------------------------------------------------------------------------
    Private Sub Button13_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button13.Click
        'Blanker ut tekstfeltene på skjermen
        txtNavn.Text = ""
        txtKlasse.Text = ""
        txtEpost.Text = ""
        txtFodselsdato.Text = ""

        'Gir fokus til første tekstfelt
        txtNavn.Focus()
    End Sub




    '-----------------------------------------------------------------------------------------------------------
    ' Knapp:    Lagre på fil
    ' Strategi: Det som ligger i tekstfeltene på skjerm, lagres i en ny post på fil
    '           - For å skrive til en ny post, må Antall oppdateres til å reflektere at det nå er flere
    '             poster på fil.
    '           - Posisjon må oppdateres, slik at bla-knappene fungerer slik de skal.
    ' Merk:     Angående innlegging av Bursdag, må vi være litt forsiktige.
    '           - Hvis feltet txtFodselsdato er tomt, vil en tom streng overføres.
    '           - Det vil faktisk medføre at programmet kræsjer. En blank dato skal
    '             nemlig skrives som en gyldig dato, ikke som tom streng.
    '           - En løsning på dette er å late som at 1.1.3000 er det samme som å nullstille dato.
    '             Det går fordi 1.1.3000 trolig aldri vil bli brukt i programmet.
    ' Kaller:   Prosedyren fjernTekstFraTekstFelter   [definert øverst i koden]
    '-----------------------------------------------------------------------------------------------------------
    Private Sub Button11_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button11.Click
        'Antall som er lagt inn fra før ligger i variabelen Antall.
        'Vi må skrive studentinformasjonen til neste post etter denne.
        'Vi må huske på å ikke overskrive gamle,
        'derfor oppdaterer vi antallet med en ekstra.
        Antall = Antall + 1

        'Antallet sier hvor mange poster som vi har på filen til nå
        'Posisjon sier hvor neste post skal skrives. 'Siden vi skal ha
        'en ny post på slutten av filen blir Posisjon og Antall det samme.
        Posisjon = Antall

        'Overfører verdiene fra tekstboksene til feltene i studentPost
        With minStudent
            If txtFodselsdato.Text = "" Then
                .Bursdag = CDate("1.1.3000")  'å nullstille en dato betyr å velge en dato vi selv mener er null
            Else
                .Bursdag = CDate(txtFodselsdato.Text)  'gjør om til dato først. Bruker kan finne på å skrive mange ulike formater her
            End If
            .Navn = txtNavn.Text
            .Klasse = txtKlasse.Text
            .EPost = txtEpost.Text
        End With

        'Skriver hele posten til datafilen
        'Legg merke til at den legges i i filen som det postnr som er angitt i variablen Posisjon.
        'Kunne også brukt variabelen Antall (siden den tilfeldigvis har samme verdi som Posisjon),
        'men det er litt mer sølete og ikke så intuitivt. Vi skriver til en posisjon (med Posisjon)
        'og filen har til enhver tid et visst antall poster (Antall) som innhold. Bruk disse riktig!
        FilePut(FilNummer, minStudent, Posisjon)

        'Blanker ut tekstfeltene for å vise tydelig at ting ble lagret.
        'Har laget en prosedyre for dette, kaller den.
        'Prosedyren er definert øverst i koden.
        fjernTekstFraTekstFelter()

        'Oppgir hvilken post som vises nå = ingen (fordi vi lagret)
        txtViserPostNr.Text = ""
    End Sub




    '-----------------------------------------------------------------------------------------------------------
    ' Knapp:    Avslutt
    ' Strategi: Lukke filen og deretter avslutte programmet. Hvis ikke det gjøres, vil filen være åpen.
    '           noe som er uheldig.
    '-----------------------------------------------------------------------------------------------------------
    Private Sub Button9_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button9.Click
        FileClose(FilNummer)
        MsgBox("Filen er lukket")
        End     'lukker skjemaet, og dermed også programmet
    End Sub




    '-----------------------------------------------------------------------------------------------------------
    ' Knapp:    Bla forrige
    ' Strategi: Blar bakover i filen
    '           - Kan ikke bla lenger bak enn til første post
    '           - Reduserer posisjonen i Posisjon med 1, men bare dersom vi ikke allerede er på første post.
    ' Merk:     Ikke noe spesielt
    ' Kaller:   Prosedyren visInformasjonITekstbokser   [definert øverst i koden]
    '-----------------------------------------------------------------------------------------------------------
    Private Sub Button10_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button10.Click
        'Før vi blar oss bakover i filen, tester vi på at vi ikke er på
        'den 1. studenten. I såfall er det ingen flere å bla bakover mot.
        If Posisjon >= 1 Then
            If Posisjon > 1 Then
                'Minker posisjonen hvor vi er i registeret med 1
                'men ikke dersom posisjonen er nøyaktig lik 1
                Posisjon = Posisjon - 1
            End If

            'Henter studenten fra registeret med utgangspunkt i
            'hvor posisjonspekeren er rettet mot
            FileGet(FilNummer, minStudent, Posisjon)

            'Overfører opplysningen om studenten til tekstboksen på skjermen
            'MERK:  Innebærer å kalle den egendefinerte
            '       prosedyren visInformasjonITekstbokser
            visInformasjonITekstbokser(minStudent)
        End If

        'Oppgir hvilken post som vises nå
        txtViserPostNr.Text = Posisjon
    End Sub




    '-----------------------------------------------------------------------------------------------------------
    ' Knapp:    Bla neste
    ' Strategi: Blar forover i filen
    '           - Kan ikke bla lenger enn til siste post
    '           - Øker posisjonen i Posisjon med 1, men bare dersom vi ikke allerede er på siste post.
    ' Merk:     Kan ikke bla i det hele tatt dersom filen er tom (Posisjon = 0).
    '           Her er det lett å gjøre feil siden en gjerne lager en fil først, og så tester programmet hele tiden
    '           mens denne filen har innhold.
    ' Kaller:   Prosedyren visInformasjonITekstbokser   [definert øverst i koden]
    '-----------------------------------------------------------------------------------------------------------
    Private Sub Button12_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button12.Click
        'Før vi blar oss framover i filen, tester vi på om det er flere
        'å bla i i det hele tatt. Bare hvis så, fortsetter vi
        If Posisjon <= Antall And Posisjon <> 0 Then
            If Posisjon < Antall Then
                'Øker posisjonen hvor vi er i registeret med 1
                'men ikke dersom posisjonen er nøyaktig lik Antall
                Posisjon = Posisjon + 1
            End If

            'Henter denne studenten fra registeret
            FileGet(FilNummer, minStudent, Posisjon)

            'Overfører opplysningen om studenten til tekstboksen på skjermen
            'MERK:  Innebærer å kalle den egendefinerte
            '       prosedyren visInformasjonITekstbokser
            visInformasjonITekstbokser(minStudent)
        End If

        'Oppgir hvilken post som vises nå
        txtViserPostNr.Text = Posisjon
    End Sub




    '-----------------------------------------------------------------------------------------------------------
    ' Knapp:    Gå til siste post
    ' Strategi: Viser siste post i filen, dersom filen har poster
    '           - Kan ikke bla lenger enn til siste post
    '           - Øker posisjonen i Posisjon med 1, men bare dersom vi ikke allerede er på siste post.
    ' Merk:     Må oppdatere Posisjon.
    '           - Hva hadde skjedd dersom vi ikke hadde oppdatert posisjonen nå,
    '             men bare brukt Antall direkte, tror du?
    '           - Svaret er at neste gang du klikker på for eksempel Forrige, og posisjon ikke er oppdatert
    '             vil det bli kluss med hvilken post som vises, og i verste fall kan programmet kræsje.
    ' Kaller:   Prosedyren visInformasjonITekstbokser   [definert øverst i koden]
    '-----------------------------------------------------------------------------------------------------------
    Private Sub Button16_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button16.Click
        'Skal hoppe til siste post og vise opplysningene i tekstfeltene
        'Setter posisjonen til Antall siden vi nå skal til siste post

        'Må håndtere at filen kan være tom. Hvis tom, og denne knappen trykkes på, må ingenting gjøres.
        If Antall > 0 Then
            Posisjon = Antall   'Antall er siste plass

            ' Henter studenten fra registeret med utgangspunkt i
            ' hvor posisjonspekeren er rettet mot
            FileGet(FilNummer, minStudent, Posisjon)

            'Overfører opplysningen om studenten til tekstboksen på skjermen
            'MERK:  Innebærer å kalle den egendefinerte
            '       prosedyren visInformasjonITekstbokser
            visInformasjonITekstbokser(minStudent)

            'Oppgir hvilken post som vises nå
            txtViserPostNr.Text = Posisjon
        End If
    End Sub




    '-----------------------------------------------------------------------------------------------------------
    ' Knapp:    Gå til første post
    ' Strategi: Viser siste post i filen, dersom filen har poster
    '           - Kan ikke bla lenger enn til siste post
    '           - Øker posisjonen i Posisjon med 1, men bare dersom vi ikke allerede er på siste post.
    ' Merk:     Må oppdatere Posisjon.
    '           - Hva hadde skjedd dersom vi ikke hadde oppdatert posisjonen nå,
    '             men bare brukt tallet 1 direkte, tror du?
    '           - Svaret er at neste gang du klikker på for eksempel Neste, og posisjon ikke er oppdatert
    '             vil det bli kluss med hvilken post som vises, og i verste fall kan programmet kræsje.
    ' Kaller:   Prosedyren visInformasjonITekstbokser   [definert øverst i koden]
    '-----------------------------------------------------------------------------------------------------------
    Private Sub Button15_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button15.Click
        'Skal hoppe til første post og vise opplysningene i tekstfeltene
        'Setter posisjonen til 1 siden vi nå skal til første post

        'Må håndtere at filen kan være tom. Hvis tom, og denne knappen trykkes på, må ingenting gjøres.
        If Antall > 0 Then

            Posisjon = 1

            ' Henter studenten fra registeret med utgangspunkt i
            ' hvor posisjonspekeren er rettet mot
            FileGet(FilNummer, minStudent, Posisjon)

            'Overfører opplysningen om studenten til tekstboksen på skjermen
            'MERK:  Innebærer å kalle den egendefinerte
            '       prosedyren visInformasjonITekstbokser
            visInformasjonITekstbokser(minStudent)

            'Oppgir hvilken post som vises nå
            txtViserPostNr.Text = Posisjon
        End If
    End Sub




    '-----------------------------------------------------------------------------------------------------------
    ' Knapp:    Form_Load (altså ingen knapp, men det som skjer når programmet starter)
    ' Strategi: Det er viktig at brukeren trykker på knappen "Åpne fil" før noe annet klikkes på.
    '           Det er fort gjort å glemme dette. Derfor vises en beskjed hvor dette påpekes ettertrykkelig.
    '           Noe som er enda smartere, er å legge koden fra "Åpne fil" inn i Form_Load. Da slipper brukeren å
    '           tenke på at filen i det hele tatt må åpnes.
    '-----------------------------------------------------------------------------------------------------------
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        MsgBox("Husk å åpne filen først" & vbLf & "Du må klikke på knappen ""Åpne fil"" før du gjør noe annet")
    End Sub
End Class