#!/usr/bin/perl
#This script generates PTR records for use as our defaults. Use primarily to "undo" customer PTR records if requested, or if reclaimed
#By Sprayberry
#Bug reports or problems should go to asprayberry@theplanet
#I am aware that this script could do with some optimizing, but I care more about having something that works.
#If you give the script data that is not an IP/CIDR range or a netmask in the proper format and it gives you garbage or an error, that is not a bug. That is USER ERROR. If you cannot figure out the right data to give this script, become an hero

#If these modules are not installed, first: PANIC AND RUN AWAY. Second: Pull yourself together and go bug your administrator
use strict;
use warnings;
use Net::Netmask;
use Getopt::Long;
use Data::Validate::IP qw/is_ipv4/;

#setting empty values for possible command line options
my $mask = '';
my $help = '';

#set valid command line arguments
GetOptions('mask|m=s' => \$mask, 'help|h' => \$help);

#print help if the help variable is true(boolean)
help() if ($help);

#if no arguments are supplied, the help prompt is displayed
if ( @ARGV == 0 || @ARGV eq "" ) {
    print "------------------------------------\nNO ARGUMENTS!!\nPrinting Help....\n------------------------------------\n";
    help();
}

#shifts first argument out of the @ARGV array and into the $IP variable
my $ip = shift;

#checks to see if the IP supplied is actually a CIDR. If the IP is a CIDR, it generates the mask from the CIDR, validates the IP, and generates the records based on the mask
if ($ip =~ m/^[\d.]+\/\d{1,2}/) {
    my @testip = split(/\//, $ip);
    my $block = new Net::Netmask($ip);
    validate($testip[0]);
    $mask = $block->mask();
    my $record = record($block->base());
    my $first = trim($block->first());
    my $last = trim($block->last());
    genrecords($record, $first, $last);
}

#checks if the mask consists of numbers or periods. If no match, it creates records for the entire C block of the IP specified
if ($mask !~ m/[\d.]+/) {
    validate($ip);
    genrecords(record($ip), 0, 255);
    exit;
}
#if a mask is valid and supplied, it will generate records based on the netmask provided
else {
    validate($ip);
    validate($mask);
    my $block = new Net::Netmask($ip, $mask);
    my $record = record($block->base());
        my $first = trim($block->first());
        my $last = trim($block->last());
    genrecords($record, $first, $last);
}

#this generates the record template to be used. The template is the complete record save for the last octet in use, which is unique for each record. The complete record is generated in the function below
sub record {
    my $ip = shift;
    my ($first, $second, $third) = split(/\./, $ip);
    my $convention = "static.theplanet.com.";
    my $zone = "\." . sprintf("%x", $third) . "." . sprintf("%x", $second ) . sprintf("%x", $first) . "\.";
    my $template = $zone . $convention;
    return($template);
}


#this part actualy prints the records to the user
sub genrecords {
    my $record = shift;
    my $first = shift;
    my $last = shift;
    $last++;
    until ( $first == $last ) {
    print "$first\tIN\tPTR\t" . sprintf("%x", $first) . $record . "\n";
    $first++;
    }
    exit;
}


#gets last octect of given IP
sub trim {
    my $ip = shift;
    my @octets = split(/\./, $ip);
    return($octets[3]);
}


#makes sure that the IP addresses supplied are VALID, so the script does not produce garbage records.
sub validate{
    my $ip = shift;
    if (is_ipv4($ip)) {
        return();
    }
    else {
        print "------------------------------------\n$ip is NOT a valid IP or netmask.\n\nPlease do the needful and check the same.\nPerhaps you should read the documentation?\n$0 -help\n------------------------------------\n";
        exit;
    }
}

#prints somewhat useful information on using the script. RTFM!
sub help{
    print <<"EOF";
This script will take three different kinds of arguments. The records are printed in DNS record format.

EG:

196     IN      PTR     c4.0.00.static.theplanet.com.

Examples of using the script are as follows:

------------
IP address:

$0 123.123.123.123

Supplying a plain IP address will generate records for the entire C block.
------------
CIDR range:

$0 123.123.123.123/24

This will generate PTR records for the block specified
------------
If you want to generate records based on a bare IP in combination with a netmask, you will have to use the mask flag:
    -mask OR -m

$0 123.123.123.123 -mask 255.255.255.248
$0 123.123.123.123 -m 255.255.255.248

############
This script is built to accept IP addresses and ranges in the C Class ONLY! Not tested or built for dealing with A or B class blocks.
############

EOF

exit;
}

1;