Clash Of Clan - TI Basic z80 - By Wistaro

Lbl 1:ClrDraw:ClrHome:AxesOff:Full
Output(2,1,"*-Clash of TI!-*
Output(3,1,"*v0.1 - Wistaro*
For(A,1,16
Output(4,A,"*
Output(1,A,"*
End
Repeat K=92 or K=105
getKey->K
If K=23:Goto R
If K=45:Goto Q
If K=93:Goto W
Output(6,5,"Play: 1
Output(8,5,"About: 2
End
Lbl J:ClrDraw
UnArchive |LC
ClrHome
Disp "Updating...
If 0>|LC(4:0->|LC(4
If 0>|LC(5:0->|LC(5
If 0>|LC(2:0->|LC(2
DelVar ADelVar D
|LC(18->A:|LC(18->B
A+10|LC(19->A
B+20|LC(19->B
A+80|LC(22->A
B+100|LC(23->B
A->|LC(20:B->|LC(21
startTmr-|LC(1->T
If int(T/3600:Then
int(T/3600->Q
|LC(4->R:|LC(5->W
|LC(4)+|LC(6)*Q->|LC(4
|LC(4)+|LC(7)*Q->|LC(4
|LC(5)+|LC(8)*Q->|LC(5
|LC(5)+|LC(9)*Q->|LC(5
Text(10,15,"Updated ",Q,"h ago!
Text(30,0,"Gold: +",|LC(4)-R
Text(40,0,"Elixir: +",|LC(5)-W
|LC(2->R
|LC(2)+100*Q->|LC(2
Text(50,0,"XP: +",|LC(2)-R
Pause
startTmr->|LC(1
End
|LC(3)^4+|LC(3->P
While |LC(2)>=P
|LC(3)+1->|LC(3
|LC(2)-P->|LC(2
|LC(3)^4+|LC(3->P
End
Menu(" Clash Of TI!","Show map",C,"General Shop",B,"My stats",I,"Fight",A,"Exit",Q
Lbl W:ClrDraw
Text(5,12,"Thanks for playing!
Text(20,0,"Author: Wistaro
Text(30,0,"Version: release 0.1
Text(40,0,"Last  update: 15/10/14
Text(50,0,"Total  size: 5837 octets
Pause :Goto 1
Lbl A
Menu("COC - Fight","Computer",AO,"Player",AJ,"<--",J
Lbl AJ:ClrHome
Disp "Soon!
Pause :Goto J
Lbl AO:ClrDraw
randInt(|LC(3)+10,|LC(3)*500->A
~randInt(0,|LC(18)->S
S+|LC(18->|LC(18
If |LC(20)<A:Then
Text(0,20,"You  loose...
A-|LC(21)->D
~10randInt(1,D->O
~10randInt(1,D->E
~randInt(D,|LC(3)^4->X
Else
Text(0,15,"Yous **WIN**!
|LC(21)-A->D
10randInt(1,D->O
10randInt(1,D->E
randInt(D,|LC(3)^4->X
End
Text(15,0,"Gold: ",O
Text(25,0,"Elixir: ",E
Text(35,0,"XP: ",X
Text(45,0,"Soldiers: ",S
O+|LC(4->|LC(4
E+|LC(5->|LC(5
|LC(2)+X->|LC(2
Pause :Goto J
Lbl C:ClrDraw
UnArchive [I]
8->V:5->W
DelVar L1DelVar L2seq(A,A,1,94,6)->L1
seq(B,B,1,58,7->L2
"o|E8}H->Str1
For(A,1,9
For(B,1,16
If [I](A,B:Text(L2(A),L1(B),sub(Str1,[I](A,B),1
End:End
DelVar SDelVar T
Repeat K=45 and not(S
getKey->K
If K=23 and not(S:Goto C
Pxl-Change(L2(W),L1(V)
not(Z->Z
If Zmax(K={24,25,26,34}
DelVar ZPxl-Change(L2(W),L1(V)
V+(K=26 and V<16)-(K=24 and V>1->V
W+(K=34 and W<9)-(K=25 and W>1->W
If K=105 and not(S) and [I](W,V:Then
Text(L2(W),L1(V),"   "
1->S
[I](W,V->T
Text(L2(1),L1(15),"[",sub(Str1,T,1),"]
0->[I](W,V
DelVar K
End
If K=105 and S and not([I](W,V:Then
Text(L2(W),L1(V),sub(Str1,T,1
DelVar S
T->[I](W,V
Text(L2(1),L1(15),"[
End:End
Goto J
Lbl I
Text(0,40,"Global
Text(9,0,"LvL: ",|LC(3
|LC(3)^4+|LC(3->P
round((100*|LC(2)/P),1->P
Text(18,0,"XP: ",|LC(2)," (",P," ^^o/plotsquare)
Text(27,0,"Or: ",|LC(4
Text(36,0,"Elixir: ",|LC(5
Text(45,0,"Attaque: ",|LC(20
Text(54,0,"Defense: ",|LC(21
Pause :ClrDraw
Text(0,40,"Mines
Text(7,0,"Mine or 1:
Text(14,10,"LvL: ",|LC(10)," Prod: ",|LC(6
Text(21,0,"Mine or 2:
Text(28,10,"LvL: ",|LC(11)," Prod: ",|LC(7
Text(35,0,"Mine elixir 1:
Text(42,10,"LvL: ",|LC(12)," Prod: ",|LC(8
Text(49,0,"Mine elixir 2:
Text(56,10,"LvL: ",|LC(13)," Prod: ",|LC(9
Pause :ClrDraw
Text(0,40,"Unitees
Text(7,0,"Soldats: ",|LC(18
Text(14,0,"Geants: ",|LC(19
Text(21,0,"Canons: ",|LC(22
Text(28,0,"Remparts: ",|LC(23
Pause :Goto J
Lbl B:ClrHome
DelVar QDelVar R
Menu("COT - Shop","Army",BA,"Defenses",BD,"Mine",BM,"<--",J
Lbl BM
{6,7,8,9->L3
{11,12,13,14->L4
Goto BV
Lbl BD
Menu("Defense","Canon",DC,"Rempart",DR,"<--",B
Lbl DC
500->P:22->L:Goto BW
Lbl DR
200->P:23->L:Goto BW
Lbl BA
Menu("Army","Soldiers",AS,"Giants",AG,"<--",B
Lbl AS
10->P:18->L:Goto BW
Lbl AG
100->P:19->L:Goto BW
Lbl BV
DelVar RDelVar Q
Menu("Mine","Or",MO,"Elixir",MX,"<--",B
Lbl MO
Menu("Mine Or","Acheter",M1,"Ameliorer",M2,"<--",BV
Lbl MX
Menu("Mine elixir","Buy",M3,"Upgrade",M4,"<--",BV
Lbl M2
14->C:10->L:6->P:10->M:Goto MM
Lbl M4
16->C:12->L:8->P:12->M:Goto MM
Lbl MM
ClrHome
Output(3,1,"Next Lvl:
Output(3,10,|LC(L)+1
Output(4,1,"Nxt Prod:
Output(4,10,|LC(P)|LC(M)+10|LC(3)
Output(5,1,"Price:
Output(5,7,10|LC(P)
Output(6,1,"Exl bank:
Output(6,11,|LC(5
Input "Ok? (1/0): ",A
If A and |LC(L) and |LC(5)>=10|LC(P)
Then
startTmr->|LC(C
|LC(5)-10|LC(P)->|LC(5
|LC(L)+1->|LC(L
int(2|LC(P)|LC(M)(|LC(3)+1)/3->|LC(P
Else
Output(8,1,"Failure!
End
ClrHome:Goto BM
Lbl M1
If not(|LC(10:Then
14->C:100->P:10->L:6->R
Else
15->C:1000->P:11->L:7->R
End:Goto BW
Lbl M3
If not(|LC(12:Then
16->C:200->P:12->L:8->Q
Else
17->C:2000->P:13->L:9->Q
End
Lbl BW
DelVar ARepeat PA<=|LC(4
Output(3,1,"Price: "
Output(3,8,P
Output(6,1,"Gold: "
Output(6,7,|LC(4
Output(4,1,"Alrd:"
Output(4,6,|LC(L
If PA>|LC(4:Output(7,1,"Not enought money!
If not(Q+R:Then
Input "Qt? ",A
Else
Input "Ok? (1/0): ",A
End
int(abs(A->A
ClrHome
End
If not(Q+R:Then
If max(L={22,23:Then
Disp "Building...
Output(3,5,"/100
For(T,1,A
1->Q
Output(3,1,int((T*100)/A
max((L={22,23})({4,3->Z
For(M,1,9
For(N,1,16
If Q and not([I](M,N:DelVar QZ->[I](M,N
End:End
If not(Q:Then
1+|LC(L->|LC(L
|LC(4)-P->|LC(4
Else
A->T
Pause "Plus de place
End:End
Else
A+|LC(L->|LC(L
|LC(4)-PA->|LC(4
End

Else
If A:Then
Pause "?2
If R:Then
10->|LC(R
1->|LC(L
End
If Q:Then
20->|LC(Q
1->|LC(L
End
|LC(4)-P->|LC(4
startTmr->|LC(C
End
End
Goto B
Lbl R
Pause "ENTER to reset!
{startTmr,0,1,100,100,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0->|LC
DelVar [I]{9,16->dim([I]
5->[I](4,8
1->[I](8,12
1->[I](3,3
2->[I](5,7
2->[I](7,15
Pause "Account cleared!
Goto 1
Lbl Q:ClrHome
Disp "Saving Game..
Disp "Please Wait...
Archive |LC:Archive [I]
ClrDraw:ClrHome