list engines in engs.
set servos to ship:modulesnamed("ModuleRoboticRotationServo"). for s in servos s:setfield("traverse rate", 10).



function tilt { parameter tlt is 0. for s in servos s:setfield("target angle", tlt). }
function vertThrust {
  set vth to 0.
  for e in engs if e:ignition set vth to vth + vdot(up:vector, e:facing:vector) * e:availablethrust.
  return max(1,vth).
}


function norm {
    parameter p0 is v(0,0,0).
    set u to (p0-body:position):normalized.
    set p1 to vxcl(u,facing:vector):normalized * 10.
    set p2 to body:geopositionof(angleaxis(120, u) * p1 + p0):position.
    set p3 to body:geopositionof(angleaxis(-120, u) * p1 + p0):position.
    set p1 to body:geopositionof(p1 + p0):position.
    return vcrs(p1-p2,p1-p3):normalized.
}

lock curFwdTilt to vang(up:vector, vxcl(vcrs(up:vector, facing:vector),facing:vector)) * (choose 1 if vdot(vxcl(up:vector,facing:vector), facing:topvector) >= 1 else -1). //assumes forwards control point, spaceplane style.

when true then {
    tilt(-curFwdTilt + vang(up:vector, -velocity:surface)). //point engines retrograde, compensating for whatever our steering is currently tilted to. Assumes the forward direction of the craft (using yaw control and keeping roll close to 0) is pointing in the direction of travel.
    return ship:status <> "landed".
}

set vesHeight to 1.3. //vessel height offset, larget for bigger crafts.
lock altR to max(0,min(alt:radar, altitude - max(body:geopositionof(velocity:surface * 4):terrainheight,body:geopositionof(velocity:surface * 12):terrainheight))). //a little bit of very crude terrain sampling ahead
set grav to body:mu/(body:radius^2).
lock acc to max(1,(max(0.3,vdot(up:vector,facing:vector)) * vertThrust() * 0.9) / mass - grav).
lock steering to vxcl(norm(velocity:surface * 1),velocity:surface).

lock throttle to grav/(vertThrust()/mass) + (-verticalspeed - max(0.5,min((alt:radar - vesHeight) ,5))) - sqrt(2 * acc * max(altR - 15 + verticalspeed * 0.1,0.0001)).
when verticalspeed > 0 or ship:status <> "landed" then { lock throttle to 0. lock steering to lookdirup(norm(),facing:topvector). }.