veil,116,147,3	script	Reward NPC::accreg 	864,{
	if ( .gepard ) .@unique_id$ = get_unique_id();
	query_sql("SELECT COUNT(DISTINCT `"+.tbl$+"`) FROM `login`", .@c );
	if ( .@c > $total_account_reg ) $total_account_reg = .@c;
	mes "We currently have "+ $total_account_reg +" Legitimate Accounts registered in MetaRO.";
	mes "Rewards will be given if we reach:";
	mes "~ 50 registered accounts";
	mes "~ 300 registered accounts";
	mes "~ 500 registered accounts";
	mes "~ 1000 registered accounts";
	mes "~ 1001 registered accounts";
	next;
	mes "What do you want to do?";
	next;
	switch(select("Open Reward List",( $total_account_reg  >= 50 && !#CLAIMRWD50 ) ? "Claim reward - 50 Accounts":"",( $total_account_reg  >= 300 && !#CLAIMRWD300 ) ? "Claim reward - 300 Accounts":"",( $total_account_reg  >= 500 && !#CLAIMRWD500 ) ? "Claim reward - 500 Accounts":"",( $total_account_reg  >= 1000 && !#CLAIMRWD1000 ) ? "Claim reward - 1000 Accounts":"",( $total_account_reg  > 1000 && !#CLAIMRWD1001 ) ? "Claim reward - 1001 Accounts":"","Nothing")) {
	case 1:
		mes "Which one you'd like to view?";
		next;
		switch(select("50 Account registered","300 Account registered","500 Account registered","1000 Account registered","1001 Account registered")) {
			case 1: .@select = 50; break;
			case 2: .@select = 300; break;
			case 3: .@select = 500; break;
			case 4: .@select = 1000; break;
			case 5: .@select = 1001; break;
		}
		mes "You will get:";
		if ( .@select == 1001 ) {
			mes "~ "+ .reg1001 +" Cashpoints";
			close;
		}
		for (.@i = 0; .@i < getarraysize(getd(".reg"+.@select)); .@i+=2)
			mes "~ "+ getd(".reg"+.@select+"["+(.@i+1)+"]") +" "+ getitemname(getd(".reg"+.@select+"["+.@i+"]"));
		close;

	case 2: callsub OnGetItem, 50; break;
	case 3:	callsub OnGetItem, 300; break;
	case 4: callsub OnGetItem, 500; break;
	case 5: callsub OnGetItem, 1000; break;
	case 6: callsub OnGetItem, 1001; break;
	default:
		close;
	}
	close;

OnGetItem:
	.@var = getarg(0);
	if ( getd("$"+ .@var +"_"+ .@unique_id$) && .gepard ) {
		mes "You've claimed your reward with another account.";
		close;
	}
	if ( .@var == 1001 ) {
		#CASHPOINTS += getd(".reg"+.@var+"[0]");
		dispbottom "You received "+ getd(".reg"+.@var+"[0]") +" Cashpoints. Total : "+ #CASHPOINTS +" Cashpoints.";
	} else {
	for (.@i = 0; .@i < getarraysize(getd(".reg"+.@var)); .@i+=2)
		getitem getd(".reg"+.@var+"["+.@i+"]"), getd(".reg"+.@var+"["+(.@i+1)+"]");
	}
	mes "Here you go!";
	set getd("#CLAIMRWD"+.@var), 1;
	if ( .gepard ) setd "$"+ .@var +"_"+ .@unique_id$, 1;
	close;

OnInit:
	// If you want to use Gepard Last Unique ID,
	// set to true.. If just the IP, set to false.
	.gepard = true;

	if ( .gepard ) .tbl$ = "last_unique_id"; else .tbl$ = "last_ip" ;

	query_sql("SELECT COUNT(DISTINCT `"+.tbl$+"`) FROM `login`", .@c );

	if ( .@c > $total_account_reg ) $total_account_reg = .@c;

	waitingroom "Current Accounts Registered: "+ $total_account_reg, 0;

	// Item rewards
	setarray .reg50,	// 50 accounts
		16268,1,	// ELITE_BOX_SUPPLY
		12103,1,	// ADV_FIELD_MANUAL
		42088,10;	// BUBBLE_GUM
	setarray .reg300,	// 300 accounts
		16268,1,	// ELITE_BOX_SUPPLY
		13550,10,	// ADV_FIELD_MANUAL
		17162,1,	// BUBBLE_GUM
		13710,1;	// INSURANCE
	setarray .reg500,	// 500 accounts
		42088,10,	// RESET_STONE???? Check ID
		12103,5,	// NEUTRALIZER???? Check ID
		16268,1,	// ELITE_BOX_SUPPLY
		13550,10;	// HE_MANUAL
	setarray .reg1000,	// 1000 accounts
		6320,5,	// RESET_STONE???? Check ID
		16268,2,	// NEUTRALIZER???? Check ID
		12103,5,	// ELITE_BOX_SUPPLY
		42088,20;	// HE_MANUAL
	setarray .reg1001,	// 1001 accounts
		5888;	// CASHPOINTS
	end;
}