deodexall.bat

@echo OFF
setlocal enabledelayedexpansion

REM Choix de l'API Android
set API=15

REM Configuration des chemins des executables
set unzip_exe=%CD%\unzip
set zip_exe=%CD%\zip
set java_exe=java
set zipalign_exe=%CD%\zipalign
set aapt_exe=%CD%\aapt
set jarsigner_exe="C:\Program Files\Java\jdk1.7.0_75\bin\jarsigner"

set baksmali_jar=%CD%\baksmali.jar
set smali_jar=%CD%\smali.jar

REM Configuration de jarsigner
set keystore="D:\Dev\android\djeman.keystore"
set keypass=
set keyalias=djeman

echo *********** Debut du processus ***********

REM Répertoire à deodexer
set path_to_process=app
REM Répertoire temporaire
set tmpout=tmpout

REM Récupération du nom de tous les .jar pour configurer le classpath
for %%i IN (framework\*.jar) do (
    set classpath=!classpath!:%%~nxi
)

if exist !tmpout! rd /s /q !tmpout!

REM Boucle deodexant chaque repertoire à déodexer
for %%k in (!path_to_process!) do (
    echo *-* Repertoire %%k

    set indir=%%k
    set outdir=%%k_new

    mkdir !outdir!

    REM Boucle deodexant chaque fichier odex du repertoire à déodexer
    for %%i IN (!indir!\*.odex) do (
        REM Création d'un repertoire temporaire
        mkdir !tmpout!

        echo.
        echo * Fichier %%~nxi

        REM Copie du jar ou de l'apk
        if exist !indir!\%%~ni.jar (
            copy !indir!\%%~ni.jar !tmpout!\%%~ni.jar
        ) else (
            copy !indir!\%%~ni.apk !tmpout!\%%~ni.apk
            REM Suppression de la signature dans les apk
            call !zip_exe! -d !tmpout!\%%~ni.apk META-INF/*
        )
        echo * %%~nxi copied

        REM Déssassemblage du odex
        call !java_exe! -Xmx512m -jar !baksmali_jar! -a !API! -d framework -c !classpath! -x %%i -o !tmpout!\%%~ni
        echo * %%~nxi deodexed

        REM Réassemblage en dex
        call !java_exe! -Xmx512m -jar !smali_jar! -a !API! !tmpout!\%%~ni -o !tmpout!\classes.dex
        echo * %%~nxi dexed

        REM Ajout du dex dans le package avec aapt
        cd !tmpout!
        if exist ..\!indir!\%%~ni.jar (
            call !aapt_exe! add %%~ni.jar classes.dex
        ) else (
            call !aapt_exe! add %%~ni.apk classes.dex
        )
        cd ..
        echo * %%~nxi dex added in main package

        REM Signature des apks et alignement des zips
        if exist !indir!\%%~ni.jar (
            call !zipalign_exe! 4 !tmpout!\%%~ni.jar !outdir!\%%~ni.jar
        ) else (
            REM Avant d'aligner les apks on les resigne
            call !jarsigner_exe! -sigalg SHA1withRSA -digestalg SHA1 -keystore !keystore! -storepass !keypass! !tmpout!\%%~ni.apk !keyalias!
            call !zipalign_exe! 4 !tmpout!\%%~ni.apk !outdir!\%%~ni.apk
        )
        echo * %%~nxi signed/aligned

        REM Suppression du repertoire temporaire
        rd /s /q !tmpout!
    )

    echo *-* Fin du Repertoire %%k
)

echo *********** Fin du processus ***********

pause