W10 Licence Backup

Option Explicit

Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Ruta del registro
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Valor de llave de Registro
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'leer Nombre del producto, ID del Producto, Licencia del Producto
ProductName = "Nombre del Producto: " & objshell.RegRead(Path & "ProductName")
ProductID = "ID del Producto: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Licencia Instalada: " & ConvertToKey(DigitalID)
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Mostrar mensaje de Guardado
If vbYes = MsgBox(ProductData  & vblf & vblf & "Guardar a Archivo?", vbYesNo + vbQuestion, "Respaldo de Licencia de Windows") then
   Save ProductData
End If



'Convertir Binarios a Letras
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Verifica si el OS es Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
           Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0

    If (isWin8 = 1) Then
        keypart1 = Mid(KeyOutput, 2, Last)
        insert = "N"
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
        If Last = 0 Then KeyOutput = insert & KeyOutput
    End If


    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)


End Function
'Guardar a archivo
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Tomar Usuario Actual
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")
    'Crear archivo e escritorio
    fName = "C:\Users\" & UserName & "\Desktop\RespaldoLicencia.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
End Function