SetBatchLines, -1
FileSelectFolder, SelectedFolder
if SelectedFolder =
    ExitApp
Loop, %SelectedFolder%\*.XML, , 1
{
   n = 0
   marker := ""
   Fileread, Memo, %A_LoopFileFullPath%
   SplitPath, A_LoopFileFullPath,, dir,, name_no_ext
   loop
   {
      if RegExMatch(Memo, "MemoID=""" n """>\s+<Offset>(.*?)</Offset>\s+.*?\s+(?:<Text>)?(.*?)(?:\s+)?</?Text/?>", found)
      {
         timecode := found1
         name := found2
         id := GenerateRandomString(8) "-" GenerateRandomString(4) "-" GenerateRandomString(4) "-" GenerateRandomString(4) "-" GenerateRandomString(12)
         marker%n% =
(
        <rdf:li>
         <rdf:Description
          xmpDM:startTime="%timecode%"
          xmpDM:name="%name%">
         <xmpDM:cuePointParams>
          <rdf:Seq>
           <rdf:li
            xmpDM:key="marker_guid"
            xmpDM:value="%id%"/>
          </rdf:Seq>
         </xmpDM:cuePointParams>
         </rdf:Description>
        </rdf:li>

)
         marker .= marker%n%
         n++
      }
      else
         break
   }
   if n != 0
   {
      Filedelete, %dir%\%name_no_ext%.XMP
      Fileappend,
(
<x:xmpmeta xmlns:x="adobe:ns:meta/" x:xmptk="Adobe XMP Core 5.5-c021 79.155241, 2013/11/25-21:10:40        ">
 <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#">
  <rdf:Description rdf:about=""
    xmlns:dc="http://purl.org/dc/elements/1.1/"
    xmlns:xmpDM="http://ns.adobe.com/xmp/1.0/DynamicMedia/"
    xmlns:stDim="http://ns.adobe.com/xap/1.0/sType/Dimensions#"
    xmlns:xmp="http://ns.adobe.com/xap/1.0/"
    xmlns:xmpMM="http://ns.adobe.com/xap/1.0/mm/"
    xmlns:stEvt="http://ns.adobe.com/xap/1.0/sType/ResourceEvent#"
    xmlns:stRef="http://ns.adobe.com/xap/1.0/sType/ResourceRef#">
   <xmpDM:Tracks>
    <rdf:Bag>
     <rdf:li>
      <rdf:Description
       xmpDM:trackName="Comment"
       xmpDM:trackType="Comment"
       xmpDM:frameRate="f30000s1001">
      <xmpDM:markers>
       <rdf:Seq>%marker%        </rdf:Seq>
      </xmpDM:markers>
      </rdf:Description>
     </rdf:li>
    </rdf:Bag>
   </xmpDM:Tracks>
   </rdf:Description>
 </rdf:RDF>
</x:xmpmeta>
), %dir%\%name_no_ext%.XMP
   }
}
Msgbox, Done


GenerateRandomString(length)
{
   characters := "abcdefghijklmnopqurstuvwxyz0123456789"
   StringSplit, chars, characters
   Loop, %length%
   {
      Random, rand, 1, 36
      id .= chars%rand%
   }
   return id
}