renpy slide buttons

screen main_menu:
    # отключаем переход
    timer sec repeat False action SetVariable("moving", False)

    # Это заменяет другие меню.
    tag menu

    # Фон главного меню.
    window:
        style "mm_root"

    # Кнопки главного меню.
    style_group "mm"

    # если переход, то двигаем кнопки
    if moving:
        textbutton _("Назад ") align (0.0, 1.0) at alpha_out action Return()
        textbutton _("Меню  ") align (0.2, 1.0) at alpha_out action MainMenu()
        textbutton _("Играть") at align_to(0.4, 1.0, 1.0, 0.7) action Start()
        textbutton _("Загр. ") at align_to(0.6, 1.0, 1.0, 0.8) action [SetVariable("moving", True), ShowMenu("load")]
        textbutton _("Настр.") at align_to(0.8, 1.0, 1.0, 0.9) action [SetVariable("moving", True), ShowMenu("preferences")]
        textbutton _("Выход ") at align_to(1.0, 1.0, 1.0, 1.0) action Quit(confirm=False)
    # иначе они сразу стоят на месте
    else:
        textbutton _("Играть") align(1.0, 0.7) action Start()
        textbutton _("Загр. ") align(1.0, 0.8) action [SetVariable("moving", True), ShowMenu("load")]
        textbutton _("Настр.") align(1.0, 0.9) action [SetVariable("moving", True), ShowMenu("preferences")]
        textbutton _("Выход ") align(1.0, 1.0) action Quit(confirm=False)

init -2 python:

    # Сделать все кнопки главного меню одноразмерными.
    style.mm_button.size_group = "mm"

init:
    python:
        style.button.xminimum = 128
        style.mm_button.xminimum = 128
        style.gm_nav_button.xminimum = 128
        # переменная указывает, что осуществляется переход
        moving = False
        # длительность перехода
        sec = 0.5
    # переходы
    transform align_to(old_x, old_y, new_x, new_y):
        align(old_x, old_y)
        easein sec align(new_x, new_y)
    transform alpha_in:
        alpha 0.0
        easeout sec alpha 1.0
    transform alpha_out:
        alpha 1.0
        easein sec alpha 0.0

screen navigation:
    # отключаем переход
    timer sec repeat False action SetVariable("moving", False)
    # Фон игрового меню.
    window:
        style "gm_root"

    # Кнопки.
    style_group "gm_nav"

    # если переход, то двигаем кнопки
    if moving:
        textbutton _("Назад ") at alpha_in align(0.0, 1.0) action [SetVariable("moving", True), Return()]
        textbutton _("Меню  ") at alpha_in align(0.2, 1.0) action [SetVariable("moving", True), MainMenu()]
        textbutton _("Настр.") at align_to(1.0, 0.7, 0.4, 1.0) action ShowMenu("preferences")
        textbutton _("Сохр. ") at align_to(1.0, 0.8, 0.6, 1.0) action ShowMenu("save")
        textbutton _("Загр. ") at align_to(1.0, 0.9, 0.8, 1.0) action ShowMenu("load")
        textbutton _("Выход ") at align_to(1.0, 1.0, 1.0, 1.0) action Quit()
    # иначе они сразу стоят на месте
    else:
        textbutton _("Назад ") align (0.0, 1.0) action [SetVariable("moving", True), Return()]
        textbutton _("Меню  ") align (0.2, 1.0) action [SetVariable("moving", True), MainMenu()]
        textbutton _("Настр.") align (0.4, 1.0) action ShowMenu("preferences")
        textbutton _("Сохр. ") align (0.6, 1.0) action ShowMenu("save")
        textbutton _("Загр. ") align (0.8, 1.0) action ShowMenu("load")
        textbutton _("Выход ") align (1.0, 1.0) action Quit()