/*
做個npc 可以先選擇1.低階附魔 需要a物品           不管低階高階 只要是附魔一爆掉 可以花某種物品保住武器或防具 低階1個 高階需要兩個才可以
		  2.高階副魔  需要b物品
	然後再選擇武器跟防具 1.武器附魔 低階的話 可以附出 57%機會失敗 失敗以後可以用某種物品保住裝備
							  10%機會進入魔力1-5、
							  10%機會進入名弓1-5、
							  10%機會進入鬥志1-5、
							  10%機會進入尖銳1-3、
			                                  3%機會ASPD+2
								魔力、名弓、鬥志 1等:40%    尖銳 :1等50% 2等 40% 3等10%
							 			 2等:20%
							 			 3等:30%
							 			 4等:7%
							 			 5等:3%
								ASPD只要一進入就是+2
							---------------------------------------------
 							高階武器附魔 60%機率失敗
								     10%機會進入魔力6-10、
							             10%機會進入名弓6-10、
							             10%機會進入鬥志6-10、
							             2%機會進入尖銳4-5、
			                                            1%機會ASPD+4
											6等:50%			尖銳4:70%
											7等:30%                 尖銳5:30%
											8等10%
											9等5%
											10等1%
								ASPD只要一進入就是+4
2.防具附魔 低階的話 可以附出:每個能力最多+1~+5/進入各能力值統一20%進入60%爆炸////機率:+1:40%；+2:20%；+3:30%；+4:7%；+5:3%
									高階的防具附魔:每個能力+6~+10 進入各能力值都是10%    機率 +6:50% +7:30% +8:10% +9:7% +10:3%
*/
//==4S
//ask Item1
prontera,162,105,3	script	附魔	906,{
//==========================================================================設定
	set .@ReqItem1,6422;	//低階消耗物品
	set .@ReqItem2,6421;	//高階消耗物品

	set .@SafeItem,6797;	//保裝道具
	set .@SafeReq1,1;	//低階消耗數量
	set .@SafeReq2,3;	//高階消耗數量

	//以下注意設定 尤其是引號 ""
	set .@WaFailR1,63;	//低階武器失敗機率
	setarray .@WaBonus1$,	//低階武器附魔效果
		"4811:50,4810:30,4809:10,4808:8,4820:2","10",
		"4812:50,4813:30,4814:10,4815:8,4826:2","10",
		"4832:50,4833:30,4834:10,4835:8,4836:2","10",
		"4816:60,4817:35,4818:5","5",
		"4807","2";

	set .@WaFailR2,63;	//高階武器失敗機率
	setarray .@WaBonus2$,	//高階武器附魔效果
		"4827:54,4828:30,4829:10,4830:5,4831:1","11",
		"4821:54,4822:30,4823:10,4824:5,4825:1","11",
		"4837:54,4838:30,4839:10,4840:5,4841:1","11",
		"4843:80,4844:20","3",
		"4842","1";

	set .@ArFailR1,50;	//低階防具失敗機率
	setarray .@ArBonus1$,	//低階防具附魔效果
		"4700:20,4710:10,4720:20,4730:20,4740:20,4750:10","20",
		"4701:20,4711:10,4721:20,4731:20,4741:20,4751:10","10",
		"4702:20,4712:10,4722:20,4732:20,4742:20,4752:10","8",
		"4703:20,4713:10,4723:20,4733:20,4743:20,4753:10","8",
		"4704:20,4714:10,4724:20,4734:20,4744:20,4754:10","4";

	set .@ArFailR2,50;	//高階防具失敗機率
	setarray .@ArBonus2$,	//高階防具附魔效果
		"4705:20,4715:10,4725:20,4735:20,4745:20,4755:10","30",
		"4706:20,4716:10,4726:20,4736:20,4746:20,4756:10","10",
		"4707:20,4717:10,4727:20,4737:20,4747:20,4757:10","4",
		"4708:20,4718:10,4728:20,4738:20,4748:20,4758:10","4",
		"4709:20,4719:10,4729:20,4739:20,4749:20,4759:10","2";
	//==========================================================================設定結束
	mes "附魔專人";
	mes "選擇低階或高階附魔";
	mes "附魔失敗時裝備會消失";
	mes "^FF0000附魔會把第4洞的卡片吃掉請注意^000000";
	mes "附魔能力請看更新公告2/27";
	mes "可用11週年代幣保護裝備低階需要1個，高階需要3個";
	.@hd = select("低階附魔(需要1個E級代幣):高階附魔(需要1個D級代幣)");
	if(countitem(getd(".@ReqItem"+.@hd))<1) {
		mes "消耗物品不夠.";
		close;
	}
	.@fa = 0;
	if(countitem(.@SafeItem)>=getd(".@SafeReq"+.@hd)) {
		mes "持有 "+getitemname(.@SafeItem);
		mes "是否消耗用來保護裝備?";
		if(select("是:否")==1)
			.@fa = 1;
	}
	mes "選擇附魔裝備";
	set .@PrintList$,"";
	for(.@i=0;.@i<10;.@i++) {
		if(getequipid(.@i)>0)
			.@PrintList$+=getequipname(.@i);
		.@PrintList$+=":";
	}
	.@sel = select(.@PrintList$)-1;
	next;
	mes "消耗下列物品";

	if(.@fa)
		mes " "+getitemname(.@SafeItem);
	mes " "+getitemname(getd(".@ReqItem"+.@hd));
	mes "對 "+getequipname(.@sel)+" 進行附魔";
	mes "確認進行?";
	if(select("是:否")==2)
		close;
	delitem getd(".@ReqItem"+.@hd),1;
	if(.@fa)
		delitem .@SafeItem,getd(".@SafeReq"+.@hd);
	.@TypeStr$ = "Ar";
	if(getiteminfo(getequipid(.@sel),2)==5)
		.@TypeStr$ = "Wa";
	.@rv = rand(100);
	if(getd(".@"+.@TypeStr$+"FailR"+.@hd) > .@rv) goto Failed;
	.@itemid=getequipid(.@sel);
	.@itemrefine = getequiprefinerycnt(.@sel);
	.@itemc[1] = getequipcardid(.@sel,0);
	.@itemc[2] = getequipcardid(.@sel,1);
	.@itemc[3] = getequipcardid(.@sel,2);
	.@itemc[4] = getequipcardid(.@sel,3);
	delequip .@sel;
	.@st = getd(".@"+.@TypeStr$+"FailR"+.@hd);
	.@b$ = "";
	for(.@ij=1;.@ij<getarraysize(getd(".@"+.@TypeStr$+"Bonus"+.@hd+"$"));.@ij+=2) {
		.@tv = atoi(getd(".@"+.@TypeStr$+"Bonus"+.@hd+"$["+.@ij+"]"));
		if(.@rv>=.@st&&.@rv<.@st+.@tv) {
			.@b$ = getd(".@"+.@TypeStr$+"Bonus"+.@hd+"$["+(.@ij-1)+"]");
			break;
		}
		.@st+=.@tv;
	}
	.@rv = rand(100);
	.@st = 0;
	if(compare(.@b$,",")) {
		explode(.@tsr$,.@b$,",");
		for(.@ij=0;.@ij<getarraysize(.@tsr$);.@ij++) {
			explode(.@tsr2$,.@tsr$[.@ij],":");
			if(.@rv>=.@st&&.@rv<.@st+atoi(.@tsr2$[1])) {
				.@itemc[4]= atoi(.@tsr2$[0]);
				break;
			}
			.@st+=atoi(.@tsr2$[1]);
		}
	} else
		.@itemc[4]= atoi(.@b$);
	getitem2 .@itemid,1,1,.@itemrefine,0,.@itemc[1],.@itemc[2],.@itemc[3],.@itemc[4];
	mes "成功了!";
	close;
Failed:
	if(.@fa) {
		mes "物品失敗了，但是有裝備保護所以沒有消失.";
	} else {
		delequip .@sel;
		mes "物品失敗了，裝備消失.";
	}
	close;
}