Move vertices. Shell. Skin Wrap.

macroscript move_vertices_shell_skin_wrap category:"_igorznag" buttontext:"Move Verts"
(
	global ro_move_vertices_shell_skin_wrap
	try destroydialog ro_move_vertices_shell_skin_wrap catch()
	rollout ro_move_vertices_shell_skin_wrap "Move Verts"
	(
		spinner spn_distance "Distance:" type:#worldunits range:[0,1e9,10] fieldwidth:55 pos:[5,5]
		button btn_move "Move" width:110 pos:[5,25]
		on btn_move pressed do
		(
			if classof $==Editable_Poly then
			(
				with redraw off
				(
					undo on
					(
						obj=$; max modify mode; fs_ba=polyop.getfaceselection obj
						if fs_ba.numberset>0 then
						(
							name_=uniquename obj.name; polyop.detachFaces obj fs_ba delete:false asNode:true name:name_
							obj_new=getnodebyname name_
							m=shell(); m.outerAmount=0; m.innerAmount=0; m.segments=1; m.selectEdgeFaces=true
							m.selectInnerFaces=true; m.selectOuterFaces=false; m.straightenCorners=true
							addmodifier obj_new m; addmodifier obj_new (deleteMesh())
							m=Skin_Wrap(); m.meshList=#(obj_new); m.engine=1; m.falloff=1; m.Distance =0.001; addmodifier obj m
							obj_new.modifiers[2].outerAmount=spn_distance.value
							converttopoly obj; delete obj_new; subobjectlevel=4
						)else messagebox "Select polygons!"
					)--undo on
				)--with redraw off
				completeredraw()
			)else messagebox "Select Editable Poly object without modifiers!"
		)--on btn_move pressed do
	); createdialog ro_move_vertices_shell_skin_wrap 120 50 style:#(#style_titlebar, #style_border, #style_sysmenu,#style_minimizebox)
)--macro